Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SCRPW24

SCRPW24.m

Go to the documentation of this file. 
  1. SCRPW24 ;RENO/KEITH - ACRP Ad Hoc Report (cont.) ;06/19/99
  1.  ;;5.3;Scheduling;**144,163,180,254,243,295,329,351,510,530,562,576,593**;AUG 13, 1993;Build 13
  1.  ;06/19/99 ACS - Added CPT modifier API calls
  1.  ;11/26/03 RLC - 329 fixes primary/secondary dx problem with report
  1.  ;
  1. APAC(SDX) ;Get all procedure codes
  1.  D APAC^SCRPW241(.SDX)
  1.  D NX Q
  1.  ;
  1. APOTR ;Transform procedure external value
  1.  D APOTR^SCRPW241(.SDX)
  1.  Q
  1.  ;
  1. APAP(SDX) ;Get ambulatory procedures (no E&M codes)
  1.  D APAP^SCRPW241(.SDX)
  1.  D NX Q
  1.  ;
  1. APEM(SDX) ;Get evaluation and management codes
  1.  D APEM^SCRPW241(.SDX)
  1.  D NX Q
  1.  ;
  1. CLCG(SDX) ;Get clinic group
  1.  K SDX S SDX=$P(SDOE0,U,4) I SDX S SDX=$P($G(^SC(SDX,0)),U,31) I SDX,$D(^SD(409.67,SDX)) S SDX=SDX_U_$P(^SD(409.67,SDX,0),U) S:$L($P(SDX,U,2)) SDX(1)=SDX
  1.  D NX Q
  1.  ;
  1. CLCN(SDX) ;Get clinic name
  1.  K SDX S SDX=$P(SDOE0,U,4) I SDX S SDX=SDX_U_$P($G(^SC(SDX,0)),U) I $L($P(SDX,U,2)) S SDX(1)=SDX
  1.  D NX Q
  1.  ;
  1. CLCS(SDX) ;Get clinic service
  1.  K SDX S SDX=$P(SDOE0,U,4) I SDX S SDX=$P($G(^SC(SDX,0)),U,8) D FST(.SDX,44,9) S:$L($P(SDX,U,2)) SDX(1)=SDX
  1.  D NX Q
  1.  ;
  1. DXAD(SDX) ;Get all diagnoses
  1.  K SDX N SDY,SDI D GETDX^SDOE(SDOE,"SDY") S SDI=0
  1.  F  S SDI=$O(SDY(SDI)) Q:'SDI  S SDX=$P(SDY(SDI),U) I SDX S SDX=SDX_U_$P($$ICDDX^SCRPWICD(+SDX,+SDOE0),U,2) I $L($P(SDX,U,2)) D DXOTR S SDX(SDI)=SDX
  1.  D NX Q
  1.  ;
  1. DXOTR ;Transform diagnosis external value
  1.  N ENCDT
  1.  S ENCDT=+$G(SDOE0)
  1.  I 'ENCDT D
  1.  .I '$G(SDOE) S ENCDT=$$NOW^XLFDT() Q
  1.  .N SDY
  1.  .D GETGEN^SDOE(SDOE,"SDY")
  1.  .S ENCDT=+$G(SDY(0))
  1.  .K SDY
  1.  S SDX=SDX_" "_$P($$ICDDX^SCRPWICD(+SDX,ENCDT),U,4) Q
  1.  ;
  1. DXGS(SDX,SDZ) ;Get GAF score
  1.  K SDX N SDI,SDY S SDY=$S(SDZ="H":$P($P(SDOE0,U),"."),1:DT)_.9999,SDY=9999999-SDY,SDY=$O(^YSD(627.8,"AX5",$P(SDOE0,U,2),SDY))
  1.  I SDY S SDI=$O(^YSD(627.8,"AX5",$P(SDOE0,U,2),SDY,""),-1) I SDI S SDX=+$P($G(^YSD(627.8,SDI,60)),U,3) I SDX S SDX(1)=SDX_U_SDX
  1.  D NX Q
  1.  ;
  1. DXGSQ(SDI) ;Set up GAF help text
  1.  S SDIRQ("?",1)="Specify a value representing the Global Assessment of Functioning (GAF) score."
  1.  I SDI="H" S SDIRQ("?")="Status as of the encounter date/time is used to determine 'historical' values."
  1.  I SDI="C" S SDIRQ("?")="Status as of the report run date is used to determine 'current' values."
  1.  Q
  1.  ;
  1. DXPD(SDX) ;Get primary diagnosis
  1.  ;SD*5.3*329 fixes problem of report not working for primary dx
  1.  K SDX N SDY,SDI D GETDX^SDOE(SDOE,"SDY") S SDI=0
  1.  F  S SDI=$O(SDY(SDI)) Q:'SDI  S SDX=$P(SDY(SDI),U) I SDX,$P(SDY(SDI),U,12)="P" S SDX=SDX_U_$P($$ICDDX^SCRPWICD(+SDX,+SDOE0),U,2) I $L($P(SDX,U,2)) D DXOTR S SDX(SDI)=SDX
  1.  D NX Q
  1.  ;
  1. DXSD(SDX) ;Get secondary diagnoses
  1.  ;SD*5.3*329 fixes problem of report not working for secondary dx
  1.  K SDX N SDY,SDI D GETDX^SDOE(SDOE,"SDY") S SDI=0
  1.  F  S SDI=$O(SDY(SDI)) Q:'SDI  S SDX=$P(SDY(SDI),U) I SDX,$P(SDY(SDI),U,12)'="P" S SDX=SDX_U_$P($$ICDDX^SCRPWICD(+SDX,+SDOE0),U,2) I $L($P(SDX,U,2)) D DXOTR S SDX(SDI)=SDX
  1.  D NX Q
  1.  ;
  1. ENED(SDX,SDZ) ;Get enrollment date
  1.  K SDX N SDY S SDY=$$ENROL($S(SDZ="H":+SDOE0,1:DT)) I SDY S (SDX,Y)=$P(SDY,U) X ^DD("DD") S SDX(1)=SDX_U_Y
  1.  D NX Q
  1.  ;
  1. ENEF(SDX,SDZ) ;Get enrollment effective date
  1.  K SDX N SDY S SDY=$$ENROL($S(SDZ="H":+SDOE0,1:DT)) I SDY S (SDX,Y)=$P(SDY,U,8) X ^DD("DD") S SDX(1)=SDX_U_Y
  1.  D NX Q
  1.  ;
  1. ENEP(SDX,SDZ) ;Get enrollment priority
  1.  K SDX N SDY S SDY=$$ENROL($S(SDZ="H":+SDOE0,1:DT)) I SDY S SDX=$P(SDY,U,7) D FST(.SDX,27.11,.07) S:$L($P(SDX,U,2)) SDX(1)=SDX
  1.  D NX Q
  1.  ;
  1. ENES(SDX,SDZ) ;Get enrollment status
  1.  K SDX N SDY S SDY=$$ENROL($S(SDZ="H":+SDOE0,1:DT)) I SDY S SDX=$P(SDY,U,4),SDX=SDX_U_$$EXTERNAL^DILFD(27.11,.04,"F",SDX) S:$L($P(SDX,U,2)) SDX(1)=SDX
  1.  D NX Q
  1.  ;
  1. ENFR(SDX,SDZ) ;Get enrollment facility received
  1.  K SDX N SDY S SDY=$$ENROL($S(SDZ="H":+SDOE0,1:DT)) I SDY S SDX=$P(SDY,U,6) I SDX S SDX=SDX_U_$P($G(^DIC(4,SDX,0)),U) S:$L($P(SDX,U,2)) SDX(1)=SDX
  1.  D NX Q
  1.  ;
  1. ENSE(SDX,SDZ) ;Get enrollment source of enrollment
  1.  K SDX N SDY S SDY=$$ENROL($S(SDZ="H":+SDOE0,1:DT)) I SDY S SDX=$P(SDY,U,3) D FST(.SDX,27.11,.03) S:$L($P(SDX,U,2)) SDX(1)=SDX
  1.  D NX Q
  1.  ;
  1. ENQ(SDZ) ;Set up help text for enrollment
  1.  I SDZ="H" S SDIRQ("?")="Enrollment status as of the encounter date/time is used for 'historical' values."
  1.  I SDZ="C" S SDIRQ("?")="Enrollment status as of the report run date is used for 'current' values."
  1.  Q
  1.  ;
  1. OEAT(SDX) ;Get encounter appointment type
  1.  K SDX S SDX=$P(SDOE0,U,10) I SDX S SDX=SDX_U_$P($G(^SD(409.1,SDX,0)),U) S:$L($P(SDX,U,2)) SDX(1)=SDX
  1.  D NX Q
  1.  ;
  1. OEDV(SDX) ;Get encounter division
  1.  K SDX S SDX=$P(SDOE0,U,11) I SDX S SDX=SDX_U_$P($G(^DG(40.8,SDX,0)),U) S:$L($P(SDX,U,2)) SDX(1)=SDX
  1.  D NX Q
  1.  ;
  1. OEEE(SDX) ;Get encounter eligibility
  1.  K SDX S SDX=$P(SDOE0,U,13) I SDX S SDX=SDX_U_$P($G(^DIC(8,SDX,0)),U) S:$L($P(SDX,U,2)) SDX(1)=SDX
  1.  D NX Q
  1.  ;
  1. OEOP(SDX) ;Get encounter originating process type
  1.  K SDX S SDX=$P(SDOE0,U,8) D FST(.SDX,409.68,.08) S:$L($P(SDX,U,2)) SDX(1)=SDX
  1.  D NX Q
  1.  ;
  1. OEPA(SDX) ;Get encounter patient
  1.  K SDX S DFN=$P(SDOE0,U,2) I DFN D DEM^VADPT I $L(VADM(1)) S SDX(1)=DFN_U_VADM(1)
  1.  D NX Q
  1.  ;
  1. OEES(SDX) ;Get encounter status
  1.  K SDX S SDX=$P(SDOE0,U,12) I SDX S SDX=SDX_U_$P($G(^SD(409.63,SDX,0)),U) S:$L($P(SDX,U,2)) SDX(1)=SDX
  1.  D NX Q
  1.  ;
  1. OETS(SDX) ;Get transmission status
  1.  K SDX S SDX(1)=$$STX^SCRPW8(SDOE,SDOE0) Q
  1.  ;
  1. TSQ(DIR) ;Set up DIR array for transmission status question
  1.  K DIR S DIR("A")="Select transmission status",DIR("?")="This value represents the transmission status of the encounter record."
  1.  S DIR(0)="SO^0:Not checked-out;1:No transmission record;2:Not required, not transmitted;3:Rejected for transmission;4:Awaiting transmission;5:Transmitted, no acknowledgment;6:Transmitted, rejected;7:Transmitted, error;8:Transmitted, accepted"
  1.  Q
  1.  ;
  1. CLQ(DIR,SDZ) ;Set up DIR array for classification questions
  1.  K DIR S SDZ=$S(SDZ="A":"Agent Orange exposure",SDZ="I":"ionizing radiation exposure",SDZ="S":"service connected condition",1:"environmental contaminants exposure")
  1.  S DIR(0)="SO^1:YES;0:NO",DIR("A")="Treatment related to "_SDZ,DIR("?")="Indicates if treatment was related to "_SDZ Q
  1.  ;
  1. OECL(SDX,SDZ) ;Get classification values
  1.  K SDX N SDY S SDZ=$S(SDZ="A":1,SDZ="I":2,SDZ="S":3,SDZ="E":4,1:"") I SDZ D CLASK^SDCO2(SDOE,.SDY) S SDX=$P($G(SDY(SDZ)),U,2) I $L(SDX) S SDX(1)=$S(SDX=1:"1^YES",1:"0^NO")
  1.  D NX Q
  1.  ;
  1. OEOU(SDX) ;Get option used to create
  1.  K SDX S SDX=+$P(SDOE0,U,5),SDX=+$P($G(^AUPNVSIT(SDX,0)),U,24)
  1.  N SDY D GETS^DIQ(19,SDX,.01,"","SDY")
  1.  I 'SDX S SDX="0^UNKNOWN",SDX(1)=SDX    ;SD*576
  1.  I +SDX S SDX=SDX_U_SDY(19,SDX_",",.01) S:$L($P(SDX,U,2)) SDX(1)=SDX
  1.  D NX Q
  1.  ;
  1. SUQ(DIR) ;Set up DIR() array for Scheduled/unscheduled question
  1.  K DIR S DIR("A")="Select outpatient activity type",DIR("?",1)="Only pre-scheduled appointments will be reflected as SCHEDULED.  All other",DIR("?",2)="types of activity (add/edits, registrations, walkins or unscheduled activity)"
  1.  S DIR("?")="will be reflected as UNSCHEDULED.",DIR(0)="SO^S:SCHEDULED;U:UNSCHEDULED" Q
  1.  ;
  1. OESU(SDX) ;Get scheduled/unscheduled status
  1.  N SDAP0 K SDX S SDX(1)=""
  1.  I $P(SDOE0,U,8)=1 D  Q:$L(SDX(1))
  1.  .S SDAP0=$G(^DPT(+$P(SDOE0,U,2),"S",+SDOE0,0))
  1.  .Q:$P(SDAP0,U,20)'=SDOE  Q:$P(SDAP0,U,7)=4
  1.  .S SDX(1)="S^SCHEDULED" Q
  1.  S SDX(1)="U^UNSCHEDULED" Q
  1.  ;
  1. PCPR(SDX,SDZ) ;Get primary care provider
  1.  ;Required input: SDZ="C" for current, "H" for historical
  1.  K SDX S SDX=$S(SDZ="C":$$OUTPTPR^SDUTL3(+$P(SDOE0,U,2)),1:$$OUTPTPR^SDUTL3(+$P(SDOE0,U,2),+$P(SDOE0,U))) S:$L($P(SDX,U,2)) SDX(1)=SDX
  1.  D NX Q
  1.  ;
  1. PCTM(SDX,SDZ) ;Get priamry care team
  1.  ;Required input: SDZ="C" for current, "H" for historical
  1.  K SDX S SDX=$S(SDZ="C":$$OUTPTTM^SDUTL3(+$P(SDOE0,U,2)),1:$$OUTPTTM^SDUTL3(+$P(SDOE0,U,2),+$P(SDOE0,U))) S:$L($P(SDX,U,2)) SDX(1)=SDX
  1.  D NX Q
  1.  ;
  1. PDPA(SDX) ;Get patient age
  1.  K SDX S DFN=$P(SDOE0,U,2) I DFN D DEM^VADPT I VADM(4)=+VADM(4) S SDX(1)=VADM(4)_U_VADM(4)
  1.  D NX Q
  1.  ;
  1. PDPS(SDX) ;Get patient sex
  1.  K SDX S DFN=$P(SDOE0,U,2) I DFN D DEM^VADPT I $L($P(VADM(5),U,2)) S SDX(1)=VADM(5)
  1.  D NX Q
  1.  ;
  1. PDSC(SDX) ;Get patient state/county
  1.  K SDX S DFN=$P(SDOE0,U,2) I DFN D ADD^VADPT I $L($P(VAPA(7),U,2)) S SDX(1)=$P(VAPA(5),U)_";"_$P(VAPA(7),U)_U_$P(VAPA(5),U,2)_" / "_$P(VAPA(7),U,2)
  1.  D NX Q
  1.  ;
  1. PDZC(SDX) ;Get patient zip code
  1.  K SDX S DFN=$P(SDOE0,U,2) I DFN D ADD^VADPT I $L(VAPA(6)) S SDX(1)=VAPA(6)_U_VAPA(6)
  1.  D NX Q
  1.  ;
  1. ENROL(SDATE)  ;Get enrollment record (most recent to encounter date)
  1.  ;SD/530 changed For loop and added check for zero node to eliminate undefined error
  1.  N SDY,SDI,X1,X2,X,%Y
  1.  S:SDATE#1=0 SDATE=SDATE+.9999 S SDI=0 F  S SDI=$O(^DGEN(27.11,"C",+$P(SDOE0,U,2),SDI)) Q:'SDI  D
  1.  .Q:'$D(^DGEN(27.11,SDI,0))
  1.  .I '$D(^DGEN(27.11,SDI,"U")) S SDY=$G(^DGEN(27.11,SDI,0)),SDY(+SDY)=SDY Q   ;SD*562
  1.  .S SDY=$G(^DGEN(27.11,SDI,0)),SDY($P($P(^DGEN(27.11,SDI,"U"),U,1),".",1))=SDY  ;SD/510 changed logic to use date/time entered
  1.  S SDI=$O(SDY(SDATE),-1) Q:'SDI ""  S X1=$P($P(SDOE0,U),"."),X2=SDI D ^%DTC Q SDY(SDI)
  1.  ;
  1. NX S:$D(SDX)<10 SDX(1)="~~~NONE~~~^~~~NONE~~~" Q
  1.  ;
  1. FST(SDX,SDFI,SDFE) ;Field set transform
  1.  Q:'$L(SDX)  N SDY,SDI D FIELD^DID(SDFI,SDFE,"","POINTER","SDY") S SDY=SDY("POINTER") F SDI=1:1:$L(SDY,";") I SDX=$P($P(SDY,";",SDI),":") S SDX=SDX_U_$P($P(SDY,";",SDI),":",2) Q
  1.  Q