Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SD53P256

SD53P256.m

Go to the documentation of this file. 
  1. SD53P256 ;ALB/RPM - Pre/Post-Install;15-Nov-2001
  1.  ;;5.3;Scheduling;**256**;Aug 13, 1993
  1.  ;
  1.  ;
  1. ENV ;Main entry point for Environment check point.
  1.  ;
  1.  S XPDABORT=""
  1.  D PROGCHK(.XPDABORT) ;checks programmer variables
  1.  I XPDABORT="" K XPDABORT
  1.  Q
  1.  ;
  1.  ;
  1. PRE ;Main entry point for Pre-init items.
  1.  ;
  1.  Q
  1.  ;
  1.  ;
  1. POST ;Main entry point for Post-init items.
  1.  ;
  1.  D POST1
  1.  Q
  1.  ;
  1.  ;
  1. PROGCHK(XPDABORT) ;checks for necessary programmer variables
  1.  ;
  1.  I '$G(DUZ)!($G(DUZ(0))'="@")!('$G(DT))!($G(U)'="^") DO
  1.  .D BMES^XPDUTL("*****")
  1.  .D MES^XPDUTL("Your programming variables are not set up properly.")
  1.  .D MES^XPDUTL("Installation aborted.")
  1.  .D MES^XPDUTL("*****")
  1.  .S XPDABORT=2
  1.  Q
  1.  ;
  1. POST1 ;Set up TaskMan to re-queue AmbCare records in the background
  1.  N ZTDESC,ZTDTH,ZTIO,ZTRTN,ZTSK
  1.  S ZTRTN="SCAN^SD53P256"
  1.  S ZTDESC="Re-queue AmbCare records for SD*5.3*256"
  1.  ;Queue Task to start in 60 seconds
  1.  S ZTDTH=$$SCH^XLFDT("60S",$$NOW^XLFDT)
  1.  S ZTIO=""
  1.  D ^%ZTLOAD
  1.  D BMES^XPDUTL("*****")
  1.  D
  1.  . I $D(ZTSK)[0 D  Q
  1.  . . D MES^XPDUTL("TaskMan task to requeue AmbCare records for SD*5.3*256 did not start.")
  1.  . . D MES^XPDUTL("Re-run post-install routine POST^SD53P256.")
  1.  . D MES^XPDUTL("Task "_ZTSK_" started to re-queue AmbCare records.")
  1.  . I $D(ZTSK("D")) D
  1.  . . D MES^XPDUTL("Task will start at "_$$HTE^XLFDT(ZTSK("D")))
  1.  D MES^XPDUTL("*****")
  1.  Q
  1.  ;
  1. SCAN ;Scan the OUTPATIENT CLASSIFICATION file (#409.42) for patients
  1.  ;who have an Outpatient Classification Type of 6 - "HEAD AND/OR NECK
  1.  ;CANCER".  Use $$FINDXMIT^SCDXFU01 to find corresponding entry in
  1.  ;TRANSMITTED OUTPATIENT ENCOUNTER file (#409.73).
  1.  ;
  1.  N SDIEN    ;Outpatient Classification file IEN
  1.  N SDTIEN   ;Transmitted Outpatient Encounter file IEN
  1.  N SDENCPTR ;Outpatient Encounter file pointer
  1.  N SDTYPE6  ;Count of encounters w/Type 6
  1.  N SDREQUE  ;Count of messages re-queued
  1.  N SDSTART  ;start date/time
  1.  ;
  1.  S SDSTART=$$NOW^XLFDT
  1.  S (SDIEN,SDREQUE,SDTYPE6)=0
  1.  F  S SDIEN=$O(^SDD(409.42,"B",6,SDIEN)) Q:'SDIEN  D
  1.  . S SDTYPE6=SDTYPE6+1
  1.  . S SDENCPTR=$P($G(^SDD(409.42,SDIEN,0)),U,2)
  1.  . Q:'SDENCPTR
  1.  . ;locate last transmitted message
  1.  . S SDTIEN=$$FINDXMIT^SCDXFU01(SDENCPTR)
  1.  . Q:'SDTIEN
  1.  . ;store event information
  1.  . D STREEVNT^SCDXFU01(SDTIEN,0)
  1.  . ;set transmission flag to 'YES'
  1.  . D XMITFLAG^SCDXFU01(SDTIEN)
  1.  . S SDREQUE=SDREQUE+1
  1.  ;send completion MailMan message
  1.  D NOTIFY(SDSTART,SDREQUE,SDTYPE6)
  1.  ;delete the task entry
  1.  S ZTREQ="@"
  1.  Q
  1.  ;
  1. NOTIFY(SDSTIME,SDREQ,SDTYP6) ;send job completion msg
  1.  ;
  1.  ;  Input
  1.  ;    SDSTIME - job start date/time
  1.  ;    SDREQ - count of AmbCare messages re-queued
  1.  ;    SDTYP6 - count of Type 6 encounters
  1.  ;
  1.  ;  Output
  1.  ;    none
  1.  ;
  1.  N DIFROM,XMDUZ,XMSUB,XMTEXT,XMY,XMZ
  1.  N SDSITE,SDETIME,SDTEXT
  1.  S SDSITE=$$SITE^VASITE
  1.  S SDETIME=$$NOW^XLFDT
  1.  S XMDUZ="AmbCare Re-queue"
  1.  S XMSUB="Patch SD*5.3*256 Mill Bill Co-Pay Enhancements"
  1.  S XMTEXT="SDTEXT("
  1.  S XMY(DUZ)=""
  1.  S SDTEXT(1)=""
  1.  S SDTEXT(2)="          Facility Name:  "_$P(SDSITE,U,2)
  1.  S SDTEXT(3)="         Station Number:  "_$P(SDSITE,U,3)
  1.  S SDTEXT(4)=""
  1.  S SDTEXT(5)="  Date/Time job started:  "_$$FMTE^XLFDT(SDSTIME)
  1.  S SDTEXT(6)="  Date/Time job stopped:  "_$$FMTE^XLFDT(SDETIME)
  1.  S SDTEXT(7)=""
  1.  S SDTEXT(8)="Total Head/Neck Cancer Encounters: "_SDTYP6
  1.  S SDTEXT(9)="Total AmbCare records re-queued  : "_SDREQ
  1.  D ^XMD
  1.  Q