Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SD53P495

SD53P495.m

Go to the documentation of this file. 
  1. SD53P495 ;ALB/RBS - ENV/POST-INSTALL FOR PATCH SD*5.3*495 ; 5/2/07 12:24pm
  1.  ;;5.3;Scheduling;**495**;Aug 13, 1993;Build 50
  1.  Q
  1. ENV ;Environment check
  1.  S XPDABORT=""
  1.  ;checks programmer variables
  1.  D PROGCHK(.XPDABORT)
  1.  ;check if install is running
  1.  D ISRUNING(.XPDABORT)
  1.  I XPDABORT="" K XPDABORT
  1.  Q
  1. POST ;Post-Install
  1.  D POST1
  1.  ;Check for SCOUT file
  1.  I '$D(^ANUSB(626140)) D  Q
  1.  . D NOFILE
  1.  D TASK
  1.  Q
  1. POST1 ;Set parameter value
  1.  N SDDAYS,SDERR,SDPARM
  1.  S SDPARM="SDSC SITE PARAMETER",SDDAYS=30
  1.  D EN^XPAR("DIV",SDPARM,1,SDDAYS,.SDERR)
  1.  D BMES^XPDUTL("******")
  1.  I '$G(SDERR) D
  1.  . D MES^XPDUTL(SDPARM_" parameter set to "_SDDAYS_" days SUCCESSFULLY.")
  1.  E  D
  1.  . D MES^XPDUTL(SDPARM_" parameter set FAILED.")
  1.  D MES^XPDUTL("******")
  1.  Q
  1. START ;Background job entry point
  1.  N SDAIEN,SDANUSB,SDX,SDFDAIEN,SDARAY,SDERAY,SDSAVE
  1.  N SDTOT,SDTOT1,SDTOT2,SDTOT3,SDENCPTR,SDCKCNT,SDSTOP,SDENT,SDFIL,DFN
  1.  D XTMP
  1.  ;seed var's if Re-Run
  1.  I $D(^XTMP("SD53P495","TOT")) D
  1.  . S SDTOT=+$G(^XTMP("SD53P495","TOT"))
  1.  . S SDTOT1=+$G(^XTMP("SD53P495","TOT1"))
  1.  . S SDTOT2=+$G(^XTMP("SD53P495","TOT2"))
  1.  . S SDTOT3=+$G(^XTMP("SD53P495","TOT3"))
  1.  . S (SDSAVE,SDENCPTR)=+$G(^XTMP("SD53P495","ENCOUNTER"))
  1.  E  D
  1.  . S (SDAIEN,SDENCPTR,SDSAVE,SDTOT,SDTOT1,SDTOT2,SDTOT3)=0
  1.  S SDCKCNT=100,SDSTOP=0
  1.  F  S SDENCPTR=$O(^ANUSB(626140,"B",SDENCPTR)) Q:'SDENCPTR  D  Q:SDSTOP
  1.  . S SDSAVE=SDENCPTR
  1.  . K SDANUSB,SDARAY,SDERAY,SDENT
  1.  . I +SDTOT#SDCKCNT=0,$$S^%ZTLOAD() S SDSTOP=1 Q
  1.  . S SDAIEN=$O(^ANUSB(626140,"B",SDENCPTR,""),-1)
  1.  . Q:'$G(SDAIEN)
  1.  . S SDANUSB=$G(^ANUSB(626140,SDAIEN,0))
  1.  . Q:'SDANUSB
  1.  . S SDTOT=SDTOT+1
  1.  . I $D(^SDSC(409.48,SDENCPTR,0)) S SDTOT3=SDTOT3+1 Q
  1.  . I '$$GETOE^SDOE(SDENCPTR) D  Q
  1.  . . S DFN=$P(SDANUSB,U,11) D DEM^VADPT S DFN=$E(VADM(1),1,15)
  1.  . . S SDENT=DFN_" "_$$FMTE^XLFDT($P(SDANUSB,U,7),2)
  1.  . . D UPXTMP(SDENCPTR,"NO (O/P) ENCOUNTER RECORD (#409.68)",SDENT) S SDTOT2=SDTOT2+1
  1.  . D GETS^DIQ(626140,SDAIEN_",","**","I","SDARAY","SDERAY")
  1.  . I $D(SDERAY) D  Q
  1.  . . S SDENT=$G(SDERAY("DIERR",1,"TEXT",1))
  1.  . . D UPXTMP(SDENCPTR,"NO (SCOUT) FILE DATA (#626140)",SDENT) S SDTOT2=SDTOT2+1
  1.  . S SDFIL=$$FILE(SDENCPTR,SDAIEN,.SDARAY)
  1.  . I '+SDFIL D  Q
  1.  . . D UPXTMP(SDENCPTR,"FILING ERROR TO (#409.48)",$P(SDFIL,"^",2)) S SDTOT2=SDTOT2+1
  1.  . E  D
  1.  . . S SDTOT1=SDTOT1+1
  1.  I SDSTOP D
  1.  . S ^XTMP("SD53P495","STOPPED")=$$NOW^XLFDT()
  1.  . S ZTSTOP=1
  1.  E  D
  1.  . S ^XTMP("SD53P495","COMPLETED")=$$NOW^XLFDT()
  1.  S ^XTMP("SD53P495","ENCOUNTER")=SDSAVE
  1.  S ^XTMP("SD53P495","TOT")=SDTOT,^XTMP("SD53P495","TOT1")=SDTOT1
  1.  S ^XTMP("SD53P495","TOT2")=SDTOT2,^XTMP("SD53P495","TOT3")=SDTOT3
  1.  K ^XTMP("SD53P495","RUNNING") D KVA^VADPT
  1.  D SENDMSG(SDSTOP)
  1.  Q
  1. FILE(SDENCPTR,SDAIEN,SDARAY) ;file new entry
  1.  ; create #409.48 file
  1.  ; Input:
  1.  ;   SDENCPTR - [required] O/P Encounter file pointer (#409.68)
  1.  ;     SDAIEN - [required] IEN of (#626140) record to convert
  1.  ;     SDARAY - [required] Array of Internal values of all fields
  1.  ; Output:
  1.  ;   Function Value - returns 1 on success, 0 on failure and error msg
  1.  I '+$G(SDENCPTR)!'+$G(SDAIEN)!('$D(SDARAY)) Q 0
  1.  N SDERR,SDFDA,SDFLD,SDFDAIEN,SDI,SDIENS,SDNUM,SDSTR,SDSTR1,SDSUB
  1.  N DIC,DICR,DIE,DIERR,DD,DG,DO,DR,DA
  1.  ; DINUM=X setup so new file IEN = O/P Encounter IEN
  1.  S SDFDAIEN(1)=SDENCPTR
  1.  ; setup main fields
  1.  S SDIENS="+1,",SDAIEN=SDAIEN_","
  1.  S SDSTR=".01^.02^.03^.04^.05^.06^.07^.08^.09^.1^.11^.12"
  1.  F SDI=1:1:12 D
  1.  . S SDFLD=$P(SDSTR,U,SDI)
  1.  . S SDFDA(409.48,SDIENS,SDFLD)=$G(SDARAY(626140,SDAIEN,SDFLD,"I"))
  1.  S SDFDA(409.48,SDIENS,.13)=1  ;SCOUT was always a 1 (SC)
  1.  ; setup fields of (#409.481) multiple
  1.  I $D(SDARAY(626140.01)) D
  1.  . S SDSTR1=".01^.02^.03^.04^.05^.06",SDNUM=1,(SDSUB,SDIENS)=""
  1.  . F  S SDSUB=$O(SDARAY(626140.01,SDSUB)) Q:SDSUB=""  D
  1.  . . S SDNUM=SDNUM+1
  1.  . . F SDI=1:1:6 S SDFLD=$P(SDSTR1,U,SDI) D
  1.  . . . S SDIENS="+"_SDNUM_",+1,"
  1.  . . . S SDFDA(409.481,SDIENS,SDFLD)=$G(SDARAY(626140.01,SDSUB,SDFLD,"I"))
  1.  D UPDATE^DIE("","SDFDA","SDFDAIEN","SDERR")
  1.  Q $S($D(SDERR):0,1:1)_"^"_$S($D(SDERR):$G(SDERR("DIERR",1,"TEXT",1)),1:"")
  1. SENDMSG(SDSTOP) ;send MailMan msg to patch installer
  1.  N DIFROM,SDMSG,SDTXT,SDLN,XMY,XMDUZ,XMSUB,XMTEXT,XMDUN,XMZ
  1.  K ^TMP("SD53P495",$J)
  1.  S XMSUB="SD*5.3*495 (SCOUT) FILE CONVERSION REPORT"
  1.  S XMTEXT="^TMP(""SD53P495"",$J,",XMDUZ=.5,(XMY(DUZ),XMY(XMDUZ))=""
  1.  S SDLN=0
  1.  D ADD(.SDLN,"Patch:  SD*5.3*495 Automated Service Connected Designation")
  1.  D ADD(.SDLN," "),ADD(.SDLN,"************")
  1.  D ADD(.SDLN,"The existing Class III (SCOUT) file, ANU SERVICE CONNECTED CHANGES (#626140),")
  1.  D ADD(.SDLN,"which contains O/P Encounter records that have been compiled for additional")
  1.  D ADD(.SDLN,"Service Connected (SC) review, has been used to create a new Class I file")
  1.  D ADD(.SDLN,"which will provide the same functionality.")
  1.  D ADD(.SDLN," ")
  1.  D ADD(.SDLN,"Only valid O/P Encounter records from the Class III (SCOUT) file,")
  1.  D ADD(.SDLN,"ANU SERVICE CONNECTED CHANGES (#626140), have been filed into")
  1.  D ADD(.SDLN,"the new SDSC SERVICE CONNECTED CHANGES (#409.48) file.")
  1.  D ADD(.SDLN," ")
  1.  D ADD(.SDLN,"The new Automated Service Connected Designation (ASCD) Menu Options")
  1.  D ADD(.SDLN,"enable user access to the O/P Encounter records in the (#409.48) file.")
  1.  D ADD(.SDLN,"************"),ADD(.SDLN," "),ADD(.SDLN," ")
  1.  D ADD(.SDLN,"SUMMARY OF PROCESSING RESULTS:")
  1.  D ADD(.SDLN,"==============================")
  1.  D ADD(.SDLN," ")
  1.  D ADD(.SDLN,"<<< The Class III (SCOUT) File Conversion has "_$S(+$G(SDSTOP):"NOT ",1:"")_"Completed. >>>")
  1.  I +$G(SDSTOP) D
  1.  . D ADD(.SDLN,"    Please restart the post-install process from the following")
  1.  . D ADD(.SDLN,"    programmer's prompt:")
  1.  . D ADD(.SDLN,"                          D POST^SD53P495")
  1.  D ADD(.SDLN," "),ADD(.SDLN," ")
  1.  D ADD(.SDLN,"  DATE/TIME TASK STARTED: "_$$FMTE^XLFDT(+$G(^XTMP("SD53P495","START")),"P"))
  1.  I $G(SDSTOP) D
  1.  . D ADD(.SDLN,"  DATE/TIME TASK STOPPED: "_$$FMTE^XLFDT(+$G(^XTMP("SD53P495","STOPPED")),"P"))
  1.  E  D
  1.  . D ADD(.SDLN,"DATE/TIME TASK COMPLETED: "_$$FMTE^XLFDT(+$G(^XTMP("SD53P495","COMPLETED")),"P"))
  1.  I $D(^XTMP("SD53P495","LAST RUN")) D
  1.  . D ADD(.SDLN,"      DATE/TIME LAST RUN: "_$$FMTE^XLFDT(+$G(^XTMP("SD53P495","LAST RUN")),"P"))
  1.  D ADD(.SDLN," "),ADD(.SDLN," ")
  1.  D ADD(.SDLN,"        TOTAL O/P ENCOUNTER RECORDS FOUND: "_+$G(^XTMP("SD53P495","TOT")))
  1.  I +$G(^XTMP("SD53P495","TOT3")) D
  1.  . D ADD(.SDLN,"       TOTAL RECORDS PREVIOUSLY CONVERTED: "_+$G(^XTMP("SD53P495","TOT3")))
  1.  D ADD(.SDLN,"    TOTAL O/P ENCOUNTER RECORDS CONVERTED: "_+$G(^XTMP("SD53P495","TOT1")))
  1.  D ADD(.SDLN,"TOTAL O/P ENCOUNTER RECORDS NOT CONVERTED: "_+$G(^XTMP("SD53P495","TOT2")))
  1.  I +$G(^XTMP("SD53P495","TOT2")) D
  1.  . D ADD(.SDLN,"                                         :")
  1.  . N SDSUB,SDIEN,SDENT
  1.  . S (SDSUB,SDIEN)=""
  1.  . F  S SDSUB=$O(^XTMP("SD53P495","TOT2",SDSUB)) Q:SDSUB=""  D
  1.  . . D ADD(.SDLN,"                     REASON NOT CONVERTED: "_SDSUB)
  1.  . . D ADD(.SDLN,"                        O/P ENCOUNTER IEN:")
  1.  . . F  S SDIEN=$O(^XTMP("SD53P495","TOT2",SDSUB,SDIEN)) Q:'SDIEN  D
  1.  . . . S SDENT=$E(^XTMP("SD53P495","TOT2",SDSUB,SDIEN),1,30)
  1.  . . . D ADD(.SDLN,"                                         : "_SDIEN_"-"_SDENT)
  1.  . . D ADD(.SDLN,"                                         :")
  1.  D ADD(.SDLN,"                         <END OF REPORT> :")
  1.  D ^XMD
  1.  K ^TMP("SD53P495",$J)
  1.  Q
  1. ADD(SDLN,SDTXT) ;add line
  1.  Q:$L(SDTXT)'>0
  1.  S SDLN=$G(SDLN)+1
  1.  S ^TMP("SD53P495",$J,SDLN)=SDTXT
  1.  Q
  1. PROGCHK(XPDABORT) ;checks programmer variables
  1.  I '$G(DUZ)!($G(DUZ(0))'="@")!('$G(DT))!($G(U)'="^") D
  1.  . D BMES^XPDUTL("******")
  1.  . D MES^XPDUTL("Your programming variables are not set up properly.")
  1.  . D MES^XPDUTL("Installation aborted.")
  1.  . D MES^XPDUTL("******")
  1.  . S XPDABORT=2
  1.  Q
  1. ISRUNING(XPDABORT) ;check if running
  1.  I +$G(^XTMP("SD53P495","RUNNING")) D
  1.  . D BMES^XPDUTL("******")
  1.  . D MES^XPDUTL("This patch is currently being Installed.  Try later.")
  1.  . D MES^XPDUTL("Installation aborted...")
  1.  . D MES^XPDUTL("******")
  1.  . S XPDABORT=2
  1.  Q
  1. NOFILE ;no File
  1.  D BMES^XPDUTL("******")
  1.  D MES^XPDUTL("The Class III (SCOUT) File Conversion is NOT necessary because")
  1.  D MES^XPDUTL("the ANU SERVICE CONNECTED CHANGES (#626140) file does not exist")
  1.  D MES^XPDUTL("on this system.")
  1.  D MES^XPDUTL("Post-Install process terminated...")
  1.  D MES^XPDUTL("******")
  1.  Q
  1. TASK ;run TaskMan
  1.  N ZTSK,ZTDTH,ZTRTN,ZTDESC,ZTIO,ZTSAVE,ZTREQ,ZTSTOP,SDSTOP
  1.  S SDSTOP=+$G(^XTMP("SD53P495","STOPPED"))
  1.  S ZTRTN="START^SD53P495"
  1.  S ZTDESC="SD*5.3*495 (SCOUT) FILE CONVERSION PROCESSING"
  1.  S ZTIO="",ZTDTH=$H,ZTREQ="@",ZTSAVE("ZTREQ")=""
  1.  D ^%ZTLOAD
  1.  D BMES^XPDUTL("******")
  1.  I '$D(ZTSK) D
  1.  . D MES^XPDUTL("Unable to schedule TaskMan task to run the Class III (SCOUT) File")
  1.  . D MES^XPDUTL("Conversion.")
  1.  . D BMES^XPDUTL("Please re-run Post-Install routine POST^SD53P495 from")
  1.  . D MES^XPDUTL("the programmer prompt.")
  1.  . ;
  1.  E  D
  1.  . D MES^XPDUTL("Task "_ZTSK_" has been "_$S(+SDSTOP:"Re-",1:"")_"started to run the Class III (SCOUT) File")
  1.  . D MES^XPDUTL("Conversion.")
  1.  . I SDSTOP D
  1.  . . D MES^XPDUTL("  <<< The last task run was STOPPED on "_$$FMTE^XLFDT(SDSTOP,"P")_". >>>")
  1.  . D BMES^XPDUTL("You will receive a MailMan message when this task is completed")
  1.  . D MES^XPDUTL("or if it has been manually stopped.")
  1.  D MES^XPDUTL("******")
  1.  Q
  1. XTMP ;setup ^XTMP to control output for 90 days
  1.  I $D(^XTMP("SD53P495",0)) D
  1.  . S ^XTMP("SD53P495","LAST RUN")=$G(^XTMP("SD53P495","START"))
  1.  E  D
  1.  . N SDX
  1.  . S SDX=$$FMADD^XLFDT($$NOW^XLFDT(),90)_U_$$NOW^XLFDT()
  1.  . S SDX=SDX_"^SD*5.3*495 (SCOUT) FILE CONVERSION PROCESSING"
  1.  . S ^XTMP("SD53P495",0)=SDX
  1.  S ^XTMP("SD53P495","START")=$$NOW^XLFDT()
  1.  S ^XTMP("SD53P495","RUNNING")="1"
  1.  Q
  1. UPXTMP(SDENCPTR,NODE,SDENT) ;add to ^XTMP
  1.  ; Input:
  1.  ;   SDENCPTR - Encounter IEN
  1.  ;       NODE - Unique subscript
  1.  ; Output: none
  1.  Q:'$G(SDENCPTR)
  1.  I $G(NODE)="" S NODE="UNKNOWN"
  1.  S ^XTMP("SD53P495","TOT2",NODE,SDENCPTR)=$G(SDENT)
  1.  Q