Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SDAMA200

SDAMA200.m

Go to the documentation of this file.
  1. SDAMA200 ;BPOIFO/ACS-Scheduling Replacement API Errors and Validation ; 12/13/04 3:13pm
  1. ;;5.3;Scheduling;**253,275,310,283,347**;13 Aug 1993
  1. ;
  1. ;*******************************************************************
  1. ; CHANGE LOG
  1. ;
  1. ; DATE PATCH DESCRIPTION
  1. ;-------- ---------- -------------------------------------
  1. ;09/20/02 SD*5.3*253 ROUTINE COMPLETED
  1. ;12/10/02 SD*5.3*275 ADDED PATIENT STATUS FILTER AND VALIDATION
  1. ;08/15/03 SD*5.3*310 ADD ERROR 114
  1. ;08/19/03 SD*5.3*283 ADDED 'NT' APPT STATUS MULTIPLE APPT STATUS
  1. ; VALUES ALLOWED, NULL FIELD LIST ALLOWED.
  1. ; REMOVED ERROR CODE 107.
  1. ;07/26/04 SD*5.3*347 NEW VARIABLES USED IN ^%DTC CALL.
  1. ; ALLOW FOR APPOINTMENT STATUSES R,NT OR
  1. ; R AND NT TO BE PASSED IF THE PATIENT STATUS
  1. ; IS SET TO O.
  1. ;
  1. ;*******************************************************************
  1. ;-------------------------------------------------------------------
  1. ; *** VALIDATE INPUT PARAMETERS ***
  1. ;INPUT
  1. ; SDIEN Patient, clinic, or facility IEN (required)
  1. ; SDFIELDS Fields requested (optional)
  1. ; SDAPSTAT Appointment status (optional)
  1. ; SDSTART Start date (optional)
  1. ; SDEND End date (optional)
  1. ; SDAPINAM The API that is calling this routine (required)
  1. ; SDRTNNAM The routine that is calling this routine (required)
  1. ; SDIOSTAT Patient status filter
  1. ;-------------------------------------------------------------------
  1. ;
  1. VALIDATE(SDIEN,SDFIELDS,SDAPSTAT,SDSTART,SDEND,SDAPINAM,SDRTNNAM,SDIOSTAT) ;
  1. ;
  1. N SDERRFLG
  1. S SDERRFLG=0
  1. ;Validate IEN
  1. I $G(SDIEN)="" D ERROR($S(SDAPINAM="GETPLIST":104,1:102),SDAPINAM,.SDERRFLG,SDRTNNAM)
  1. I $G(SDIEN)'="",+$G(SDIEN)'=$G(SDIEN) D ERROR(110,SDAPINAM,.SDERRFLG,SDRTNNAM)
  1. ;
  1. ;Validate Appointment Status Filter
  1. I $L($G(SDAPSTAT))>0 D
  1. . ;validate each status, build new status list if necessary
  1. . N SDNUM,SDPIECE,SDQUIT,SDAPVAL,SDNEWAP
  1. . S SDQUIT=0
  1. . ;get count of values passed in
  1. . S SDNUM=$L(SDAPSTAT,";")
  1. . S SDNEWAP=";"
  1. . ;check each value passed in
  1. . F SDPIECE=1:1:SDNUM S SDAPVAL=$P(SDAPSTAT,";",SDPIECE) D Q:SDQUIT=1
  1. .. I $G(SDAPVAL)="" D ERROR(109,SDAPINAM,.SDERRFLG,SDRTNNAM) S SDQUIT=1 Q
  1. .. I ";R;C;N;NT;"'[(";"_SDAPVAL_";") D ERROR(109,SDAPINAM,.SDERRFLG,SDRTNNAM) S SDQUIT=1 Q
  1. .. ;build status string
  1. .. S SDNEWAP=SDNEWAP_SDAPVAL_";"
  1. .S SDAPSTAT=SDNEWAP
  1. ;set appointment status filter to 'all' if null or undefined
  1. I $G(SDAPSTAT)="" S SDAPSTAT=";R;C;N;NT;"
  1. ;
  1. ;Validate start and end date/time variables if they are passed in
  1. N SDSTVAL,SDENDVAL,%H,%T,%Y,X
  1. S (SDSTVAL,SDENDVAL)=0
  1. I $G(SDSTART)'="" D
  1. . I +SDSTART'=SDSTART D ERROR(105,SDAPINAM,.SDERRFLG,SDRTNNAM) Q
  1. . S X=SDSTART D H^%DTC I %H=0 D ERROR(105,SDAPINAM,.SDERRFLG,SDRTNNAM) Q
  1. . S SDSTVAL=1
  1. I $G(SDEND)'="" D
  1. . I +SDEND'=SDEND D ERROR(106,SDAPINAM,.SDERRFLG,SDRTNNAM) Q
  1. . S X=SDEND D H^%DTC I %H=0 D ERROR(106,SDAPINAM,.SDERRFLG,SDRTNNAM) Q
  1. . S SDENDVAL=1
  1. ;If start and end dates are valid, make sure start date not > end date
  1. I SDSTVAL,SDENDVAL D
  1. . I SDSTART>SDEND D ERROR(111,SDAPINAM,.SDERRFLG,SDRTNNAM)
  1. ;
  1. ;Remove beginning and ending semi-colons from SDFIELDS list if present
  1. I $L($G(SDFIELDS))>0 D
  1. . I $E($G(SDFIELDS),1,1)=";" D
  1. .. S SDFIELDS=$E(SDFIELDS,2,$L(SDFIELDS))
  1. .. I $G(SDFIELDS)="" D ERROR(103,SDAPINAM,.SDERRFLG,SDRTNNAM)
  1. .I $L($G(SDFIELDS))>0 D
  1. .. I $E($G(SDFIELDS),$L($G(SDFIELDS)),$L($G(SDFIELDS)))=";" D
  1. ... S SDFIELDS=$E(SDFIELDS,1,$L(SDFIELDS)-1)
  1. ... I $G(SDFIELDS)="" D ERROR(103,SDAPINAM,.SDERRFLG,SDRTNNAM)
  1. ;
  1. ;Validate SDFIELDS list
  1. N SDI,SDFIELD,SDNUM,SDEND
  1. S (SDI,SDFIELD,SDNUM,SDEND)=0
  1. ;Check field list for valid numbers requested
  1. I $G(SDFIELDS)]"" D
  1. . ;get number of pieces
  1. . S SDNUM=$L(SDFIELDS,";")
  1. . ;validate each piece
  1. . F SDI=1:1:SDNUM S SDFIELD=$P(SDFIELDS,";",SDI) D Q:SDEND
  1. .. I $G(SDFIELD)="" D ERROR(103,SDAPINAM,.SDERRFLG,SDRTNNAM) S SDEND=1 Q
  1. .. I '$D(^SDAM(44.3,SDFIELD)) D ERROR(103,SDAPINAM,.SDERRFLG,SDRTNNAM) S SDEND=1 Q
  1. ;If field list is null and API is not NEXTAPPT, set up to include all
  1. I ($G(SDFIELDS)="")&(SDAPINAM'="NEXTAPPT") S SDI=0 D
  1. . F S SDI=$O(^SDAM(44.3,SDI)) Q:+$G(SDI)=0 D
  1. .. S SDFIELDS=$G(SDFIELDS)_SDI_";"
  1. . ;remove ending semi-colon
  1. . S SDFIELDS=$E(SDFIELDS,1,$L(SDFIELDS)-1)
  1. ;
  1. ;Validate Patient Status Filter
  1. I $L($G(SDIOSTAT))>0 D
  1. . I $L(SDIOSTAT)>1 D ERROR(112,SDAPINAM,.SDERRFLG,SDRTNNAM) Q
  1. . I "IO"'[SDIOSTAT D ERROR(112,SDAPINAM,.SDERRFLG,SDRTNNAM) Q
  1. ;set patient status filter to 'both' if null or undefined
  1. I $G(SDIOSTAT)="" S SDIOSTAT="IO"
  1. ;
  1. ;Validate Appt Status and Patient Status Filter Combination
  1. ;if they specify a patient status, they must specify scheduled/kept appt type "R"
  1. I $G(SDIOSTAT)="I",$G(SDAPSTAT)'=";R;" D ERROR(113,SDAPINAM,.SDERRFLG,SDRTNNAM)
  1. I $G(SDIOSTAT)="O",$S($G(SDAPSTAT)=";R;":0,$G(SDAPSTAT)=";NT;":0,$G(SDAPSTAT)=";R;NT;":0,$G(SDAPSTAT)=";NT;R;":0,1:1) D ERROR(113,SDAPINAM,.SDERRFLG,SDRTNNAM)
  1. ;
  1. I SDERRFLG>0 Q -1
  1. Q 1
  1. ;
  1. ERROR(SDERRNUM,SDAPINAM,SDERRFLG,SDRTNNAM) ;
  1. ;Put error message in ^TMP global
  1. S SDERRFLG=1
  1. S $P(^TMP($J,SDRTNNAM,SDAPINAM,"ERROR",SDERRNUM),"^",1)=$P($T(@SDERRNUM),";;",2)
  1. Q
  1. ;
  1. ;***************************************************************
  1. ; ERROR CODES AND MESSAGES USED FOR PARAMETER VALIDATION
  1. ;***************************************************************
  1. ;
  1. 101 ;;DATABASE IS UNAVAILABLE
  1. 102 ;;PATIENT ID IS REQUIRED
  1. 103 ;;INVALID FIELD LIST
  1. 104 ;;CLINIC ID IS REQUIRED
  1. 105 ;;INVALID START DATE
  1. 106 ;;INVALID END DATE
  1. 108 ;;FACILITY ID IS REQUIRED
  1. 109 ;;INVALID APPOINTMENT STATUS FILTER
  1. 110 ;;ID MUST BE NUMERIC
  1. 111 ;;START DATE CAN'T BE AFTER END DATE
  1. 112 ;;INVALID PATIENT STATUS FILTER
  1. 113 ;;APPT STATUS AND PATIENT STATUS FILTER COMBINATION UNSUPPORTED IN VISTA
  1. 114 ;;INVALID PATIENT ID
  1. 116 ;;DATA MISMATCH
  1. 117 ;;SDAPI ERROR
  1. ;
  1. ;------------------------------------------------------------------
  1. ;Additional APIs called from GETAPPT, GETPLIST, NEXTAPPT, GETALLCL
  1. ;------------------------------------------------------------------
  1. ;
  1. PATAPPT(SDPATIEN) ;For a patient IEN, return Boolean value for existence of appointments on ^DPT
  1. I $D(^DPT(SDPATIEN,"S")) Q 1
  1. Q 0
  1. ;
  1. CLNAPPT(SDCLIEN) ;For a clinic IEN, return Boolean value for existence of appointments on ^SC
  1. I $D(^SC($G(SDCLIEN),"S")) Q 1
  1. Q 0
  1. GETCLIEN(SDPATIEN,SDAPPTDT) ; For a patient and appt date, return the clinic IEN on ^DPT
  1. Q $P($G(^DPT($G(SDPATIEN),"S",$G(SDAPPTDT),0)),"^",1)
  1. ;
  1. GETPTIEN(SDCLIEN,SDAPPTDT,SDPATCNT) ; For a clinic, appt date, and node, return the patient IEN on ^SC
  1. Q $P($G(^SC($G(SDCLIEN),"S",$G(SDAPPTDT),1,$G(SDPATCNT),0)),"^",1)
  1. ;
  1. GETSDDA(SDCLIEN,SDAPPTDT,SDPATIEN) ; For a clinic, appt date, and patient, return the SDDA node number on ^SC
  1. N SDPATCNT,SDMATCH
  1. S SDPATCNT=0,SDMATCH=0
  1. F S SDPATCNT=$O(^SC($G(SDCLIEN),"S",$G(SDAPPTDT),1,SDPATCNT)) D Q:('SDPATCNT!SDMATCH)
  1. . I 'SDPATCNT Q
  1. . I $P($G(^SC(SDCLIEN,"S",SDAPPTDT,1,SDPATCNT,0)),"^",1)=SDPATIEN S SDMATCH=1
  1. Q $G(SDPATCNT)
  1. ;
  1. GETASTAT(SDPATIEN,SDAPPTDT) ;For a patient and appt date, return Appointment Status (N, C, R, or NT)
  1. N SDSTAT
  1. S SDSTAT=$P($G(^DPT(SDPATIEN,"S",SDAPPTDT,0)),"^",2)
  1. S SDSTAT=$S($G(SDSTAT)="NT":"NT",$G(SDSTAT)="I":"R",$G(SDSTAT)["N":"N",$G(SDSTAT)["C":"C",1:"R")
  1. Q SDSTAT
  1. ;
  1. GETPSTAT(SDPATIEN,SDAPPTDT) ;For a patient and appt date, return Patient Status (I or O)
  1. N SDSTAT
  1. S SDSTAT=$P($G(^DPT(SDPATIEN,"S",SDAPPTDT,0)),"^",2)
  1. S SDSTAT=$S($G(SDSTAT)="I":"I",1:"O")
  1. Q SDSTAT
  1. ;