Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SDOEQ

SDOEQ.m

Go to the documentation of this file. 
  1. SDOEQ ;ALB/MJK - Encounter Query Object Methods ;8/12/96
  1.  ;;5.3;Scheduling;**131,132**;Aug 13, 1993
  1.  ;
  1.  ;
  1. OE0(SDOE) ; -- get only supported 0th node fields
  1.  N X
  1.  S X=$G(^SCE(SDOE,0))
  1.  ; -- null EXTENDED REFERENCE field (piece 9)
  1.  IF X]"" S $P(X,"^",9)=""
  1.  Q X
  1.  ;
  1. SDOE(SDOE,SDFIL,SDCB,SDSTOP) ; -- do filter and callback
  1.  N Y,Y0,SDOE0
  1.  S SDOE0=$$OE0(.SDOE)
  1.  ;
  1.  ; -- exit if null record
  1.  IF SDOE0="" G SDOEXQ
  1.  ;
  1.  ; -- execute filter
  1.  S Y=SDOE,Y0=SDOE0
  1.  X:SDFIL]"" SDFIL
  1.  ;
  1.  ; -- execute callback if passes filter
  1.  S Y=SDOE,Y0=SDOE0
  1.  IF $T X SDCB
  1. SDOEXQ Q
  1.  ;
  1. SCAN(SDQ,SDIR,SDERR) ; -- full scan of all needed records
  1.  N SDCB,SDSTOP,SDIDX,SDFIL,X,SDQDIR
  1.  S SDSTOP=0
  1.  S X=$G(SDIR),SDQDIR=$S(X="":"FORWARD",1:X)
  1.  D INDEX^SDQ(.SDQ,.SDIDX,"GET",$G(SDERR))
  1.  IF '$$ERRCHK^SDQUT($G(SDERR)) D SCANCB^SDQ(.SDQ,.SDCB,"GET",$G(SDERR))
  1.  IF '$$ERRCHK^SDQUT($G(SDERR)) D FILTER^SDQ(.SDQ,.SDFIL,"GET",$G(SDERR))
  1.  IF $$ERRCHK^SDQUT($G(SDERR)) G SCANQ
  1.  ;
  1.  IF SDIDX="PATIENT/DATE" D SCANPDT
  1.  IF SDIDX="VISIT" D SCANVST
  1.  IF SDIDX="PATIENT" D SCANPAT
  1.  IF SDIDX="DATE/TIME" D SCANDT
  1.  ;
  1. SCANQ Q
  1.  ;
  1. SCANPDT ; -- scan by patient and date
  1.  N SDFN,SDBEG,SDEND,SDDT,SDOE
  1.  D PAT^SDQ(.SDQ,.SDFN,"GET",$G(SDERR))
  1.  IF '$$ERRCHK^SDQUT($G(SDERR)) D DATE^SDQ(.SDQ,.SDBEG,.SDEND,"GET",$G(SDERR))
  1.  IF $$ERRCHK^SDQUT($G(SDERR)) G SCANPDTQ
  1.  ;
  1.  IF SDQDIR="FORWARD" D
  1.  . S SDDT=SDBEG-.000001
  1.  . F  S SDDT=$O(^SCE("ADFN",SDFN,SDDT)) Q:'SDDT!(SDDT>SDEND)  D  Q:SDSTOP
  1.  . . S SDOE=""
  1.  . . F  S SDOE=$O(^SCE("ADFN",SDFN,SDDT,SDOE)) Q:SDOE=""  D SDOE(.SDOE,.SDFIL,.SDCB,.SDSTOP) Q:SDSTOP
  1.  . ;
  1.  ELSE  D
  1.  . S SDDT=SDEND+.000001
  1.  . F  S SDDT=$O(^SCE("ADFN",SDFN,SDDT),-1) Q:'SDDT!(SDDT<SDBEG)  D  Q:SDSTOP
  1.  . . S SDOE=""
  1.  . . F  S SDOE=$O(^SCE("ADFN",SDFN,SDDT,SDOE),-1) Q:SDOE=""  D SDOE(.SDOE,.SDFIL,.SDCB,.SDSTOP) Q:SDSTOP
  1.  ;
  1. SCANPDTQ Q
  1.  ;
  1. SCANVST ; -- scan by visit
  1.  N SDVSIT,SDOE
  1.  S SDSTOP=0
  1.  D VISIT^SDQ(.SDQ,.SDVSIT,"GET",$G(SDERR))
  1.  IF $$ERRCHK^SDQUT($G(SDERR)) G SCANVSTQ
  1.  ;
  1.  IF SDQDIR="FORWARD" D
  1.  . S SDOE=""
  1.  . F  S SDOE=$O(^SCE("AVSIT",SDVSIT,SDOE)) Q:SDOE=""  D SDOE(.SDOE,.SDFIL,.SDCB,.SDSTOP) Q:SDSTOP
  1.  . ;
  1.  ELSE  D
  1.  . S SDOE=""
  1.  . F  S SDOE=$O(^SCE("AVSIT",SDVSIT,SDOE),-1) Q:SDOE=""  D SDOE(.SDOE,.SDFIL,.SDCB,.SDSTOP) Q:SDSTOP
  1.  ;
  1. SCANVSTQ Q
  1.  ;
  1. SCANDT ; -- date only scan
  1.  N SDDT,SDBEG,SDEND,SDOE
  1.  D DATE^SDQ(.SDQ,.SDBEG,.SDEND,"GET",$G(SDERR))
  1.  IF $$ERRCHK^SDQUT($G(SDERR)) G SCANDTQ
  1.  ;
  1.  IF SDQDIR="FORWARD" D
  1.  . S SDDT=SDBEG-.000001
  1.  . F  S SDDT=$O(^SCE("B",SDDT)) Q:SDDT=""!(SDDT>SDEND)  D  Q:SDSTOP
  1.  . . S SDOE=""
  1.  . . F  S SDOE=$O(^SCE("B",SDDT,SDOE)) Q:SDOE=""  D SDOE(.SDOE,.SDFIL,.SDCB,.SDSTOP) Q:SDSTOP
  1.  ;
  1.  ELSE  D
  1.  . S SDDT=SDEND+.000001
  1.  . F  S SDDT=$O(^SCE("B",SDDT),-1) Q:SDDT=""!(SDDT<SDBEG)  D  Q:SDSTOP
  1.  . . S SDOE=""
  1.  . . F  S SDOE=$O(^SCE("B",SDDT,SDOE),-1) Q:SDOE=""  D SDOE(.SDOE,.SDFIL,.SDCB,.SDSTOP) Q:SDSTOP
  1.  ;
  1. SCANDTQ Q
  1.  ;
  1. SCANPAT ; -- patient only scan
  1.  N SDFN,SDOE
  1.  S SDSTOP=0
  1.  D PAT^SDQ(.SDQ,.SDFN,"GET",$G(SDERR))
  1.  IF $$ERRCHK^SDQUT($G(SDERR)) G SCANPATQ
  1.  ;
  1.  IF SDQDIR="FORWARD" D
  1.  . S SDOE=""
  1.  . F  S SDOE=$O(^SCE("C",SDFN,SDOE)) Q:SDOE=""  D SDOE(.SDOE,.SDFIL,.SDCB,.SDSTOP) Q:SDSTOP
  1.  . ;
  1.  ELSE  D
  1.  . S SDOE=""
  1.  . F  S SDOE=$O(^SCE("C",SDFN,SDOE),-1) Q:SDOE=""  D SDOE(.SDOE,.SDFIL,.SDCB,.SDSTOP) Q:SDSTOP
  1.  ;
  1. SCANPATQ Q
  1.  ;
  1. PAT(SDQ,SDFN,SDACT,SDERR) ; -- SDQ PATIENT
  1.  ;   API ID: 81
  1.  ;
  1.  ;
  1. PATG ; -- goto entry point
  1.  ; -- do validation checks
  1.  IF '$$QRY^SDQVAL(.SDQ,$G(SDERR)) G PATQ
  1.  IF '$$ACTION^SDQVAL(.SDACT,$G(SDERR)) G PATQ
  1.  IF SDACT="SET",'$$QRYINACT^SDQVAL(.SDQ,$G(SDERR)) G PATQ
  1.  IF SDACT="SET",'$$PAT^SDQVAL(.SDFN,$G(SDERR)) G PATQ
  1.  ;
  1.  IF SDACT="SET" S @SDQUERY@(SDQ,"MASTER VALUE")=SDFN
  1.  IF SDACT="GET" S SDFN=$G(@SDQUERY@(SDQ,"MASTER VALUE"))
  1. PATQ Q
  1.  ;
  1. VISIT(SDQ,SDVST,SDACT,SDERR) ; -- SDQ VISIT
  1.  ;   API ID: 84
  1.  ;
  1.  ;
  1. VISITG ; -- goto entry point
  1.  ; -- do validation checks
  1.  IF '$$QRY^SDQVAL(.SDQ,$G(SDERR)) G VISITQ
  1.  IF '$$ACTION^SDQVAL(.SDACT,$G(SDERR)) G VISITQ
  1.  IF SDACT="SET",'$$QRYINACT^SDQVAL(.SDQ,$G(SDERR)) G VISITQ
  1.  IF SDACT="SET",'$$VALVST^PXAPIOE(.SDVST,$G(SDERR)) G VISITQ
  1.  ;
  1.  IF SDACT="SET" S @SDQUERY@(SDQ,"MASTER VALUE")=SDVST
  1.  IF SDACT="GET" S SDVST=$G(@SDQUERY@(SDQ,"MASTER VALUE"))
  1.  ;
  1. VISITQ Q
  1.  ;