Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SDSCRPT2

SDSCRPT2.m

Go to the documentation of this file.
  1. SDSCRPT2 ;ALB/JAM/RBS - ASCD SB/Reports for Service Connected Automated Monitor ;3/5/07 12:11pm
  1. ;;5.3;Scheduling;**495,586**;Aug 13, 1993;Build 28
  1. ;;MODIFIED FOR NATIONAL RELEASE from a Class III software product
  1. ;;known as Service Connected Automated Monitoring (SCAM).
  1. ;
  1. ; Routine should be called at specified tags only.
  1. ; Reference to $$ICDDX^ICDEX supported by ICR #5747
  1. Q
  1. ; Do standard header setup
  1. D STDHDR Q:$G(SDABRT)=1
  1. W "O/P ENCOUNTERS THAT ARE "_$S('SDOPT:"NOT ",1:"")_"SERVICE CONNECTED" W:SDOPT=2 " & NON SERVICE CONNECTED" W ?67,"PAGE: ",P
  1. W !,?5,"ENCOUNTERS DATED ",$$FMTE^XLFDT(SDSCTDT,2)," THRU ",$$FMTE^XLFDT(SDEDT,2)
  1. I $G(SDSCDNM)'="" W " By Division: "_SDSCDNM
  1. W !,"DATE",?18,"PATIENT",?50,"ENCOUNTER",?65,"SC VALUE",!,!
  1. Q
  1. ;
  1. ENCBDDT ; Detailed Body of the Disability/POV Encounter report
  1. I L+3+$S(SDDET:$$CTPOV(),1:0)>IOSL D HEADER Q:$G(SDABRT)=1
  1. ; Display the Encounter date
  1. W $$FMTE^XLFDT(SDOEDT,"5MZ")
  1. N DFN,VADM S DFN=SDPAT D DEM^VADPT
  1. ; Display the patient name and last 4 SSN.
  1. W ?18,$E(VADM(1),1,25)_" ("_$E($P(VADM(2),U),6,9)_")"
  1. D KVA^VADPT
  1. ; Display the ENCOUNTER Number
  1. W ?50,SDOE,?65,$S(SCVAL:"YES",SCVAL=0:"NO",1:"TBD"),! S L=L+1
  1. ; If summary report, quit.
  1. Q:SDDET=0
  1. ; Display all ICD CODES and DIAGNOSES for the specified encounter.
  1. I L+2+$$CTPOV()>IOSL D HEADER Q:$G(SDABRT)=1
  1. D POV2S
  1. I L+2+$$CTDIS()>IOSL D HEADER Q:$G(SDABRT)=1
  1. D DIS2S
  1. I L+4>IOSL D HEADER Q:$G(SDABRT)=1
  1. W !,! S L=L+2
  1. Q
  1. ;
  1. NBILLHD ; Display an appropriate header for this report.
  1. ; Do standard header setup
  1. D STDHDR Q:$G(SDABRT)=1
  1. W SDHDR,?67,"PAGE: ",P
  1. W !,?5,"FOR ENCOUNTERS DATED ",$$FMTE^XLFDT(SDSCTDT,2)," THRU ",$$FMTE^XLFDT(SDEDT,2)
  1. I $G(SDSCDNM)'="" W " By Division: "_SDSCDNM
  1. W !,"DATE",?18,"PATIENT",?50,"ENCOUNTER",!,!
  1. Q
  1. ;
  1. NBILLBD ; Body of the Non Service Connected Billable Encounter reports
  1. I L+2>IOSL D NBILLHD Q:$G(SDABRT)=1
  1. ; Display the Encounter date
  1. W $$FMTE^XLFDT(SDOEDT,"5MZ")
  1. ; Display the patient name and last 4 SSN.
  1. N DFN,VADM S DFN=SDPAT D DEM^VADPT
  1. W ?18,$E(VADM(1),1,25)_" ("_$E($P(VADM(2),U),6,9)_")"
  1. ; Display the ENCOUNTER Number
  1. W ?50,SDOE,! S L=L+1
  1. I L+5>IOSL D NBILLHD Q:$G(SDABRT)=1
  1. Q
  1. ;
  1. PRVHD ; Display the header for the Provider Service Connected Review Report.
  1. ; Do standard header setup
  1. D STDHDR Q:$G(SDABRT)=1
  1. S SDNWPV=1
  1. W SDHDR,?67,"PAGE: ",P
  1. W !,?5,"FOR ENCOUNTERS DATED ",$$FMTE^XLFDT(SDSCTDT,2)," THRU ",$$FMTE^XLFDT(SDEDT,2)
  1. I $G(SDSCDNM)'="" W " By Division: "_SDSCDNM
  1. W !,?5,"ENCOUNTER DATE",?23,"PATIENT NAME",?56,"ENC #",?65,"VBA SC",?73,"USER SC",!,!
  1. Q
  1. ;
  1. PRVBD ; Body of the Provider Service Connected Review Report
  1. ; This routine will display the Activity during a review
  1. ; Start a new page for every provider.
  1. N SDSCCVB,SDSCCUB,DFN,VADM
  1. I L+3+$S(SDDET:$$CTPOV(),1:0)>IOSL D PRVHD Q:$G(SDABRT)=1 S SDPVCN=1
  1. ; Display the Provider, reset new provider print flag
  1. I SDNWPV=1 D
  1. . W $$UP^XLFSTR($$NAME^XUSER(SDPROV,"F"))
  1. . S SDNWPV=0
  1. . I SDPVCN=1 W " (cont'd)" S SDPVCN=0
  1. . W ! S L=L+1
  1. . Q
  1. ; Display the Encounter date
  1. W ?5,$$FMTE^XLFDT(SDOEDT,"5MZ")
  1. ; Display the Patient Name
  1. S DFN=SDPAT D DEM^VADPT
  1. W ?23,$E(VADM(1),1,25)_" ("_$E($P(VADM(2),U),6,9)_")"
  1. D KVA^VADPT
  1. ; Display the ENCOUNTER Number,VBA/ICD Connected,VBA by User. Increment Line Count.
  1. S SDSCCVB=$$GET1^DIQ(409.48,SDOE,.09,"E")
  1. S SDSCCUB=$$GET1^DIQ(409.48,SDOE,.06,"E")
  1. I SDSCCUB="" S SDSCCUB="TBD"
  1. W ?56,SDOE,?65,SDSCCVB,?73,SDSCCUB
  1. I 'SDDET W ! S L=L+1
  1. I SDDET D Q:$G(SDABRT)=1
  1. . ; check for enough room for return prompt and data.
  1. . I L+2+$$CTPOV()>IOSL D RVWHD Q:$G(SDABRT)=1 S SDPVCN=1
  1. . D POV2S
  1. . I L+2+$$CTDIS()>IOSL D RVWHD Q:$G(SDABRT)=1 S SDPVCN=1
  1. . D DIS2S
  1. . I L+4>IOSL D RVWHD Q:$G(SDABRT)=1 S SDPVCN=1
  1. . W !,! S L=L+2
  1. . Q
  1. I L+3>IOSL D PRVHD Q:$G(SDABRT)=1 S SDPVCN=1
  1. Q
  1. ;
  1. RVWHD ; Display the header for the User Service Connected Review Report.
  1. ; Do standard header setup
  1. D STDHDR Q:$G(SDABRT)=1
  1. S SDNWPV=1
  1. W SDHDR,?67,"PAGE: ",P
  1. W !,?5,"FOR ENCOUNTERS DATED ",$$FMTE^XLFDT(SDSCTDT,2)," THRU ",$$FMTE^XLFDT(SDEDT,2)
  1. I $G(SDSCDNM)'="" W " By Division: "_SDSCDNM
  1. W !,?5,"ENCOUNTER DATE",?23,"ENC #",?33,"VBA SC",?40,"USER SC",?50,"STATUS",?60,"DATE LAST EDITED",!,!
  1. Q
  1. ;
  1. RVWBD ; Body of the User Service Connected Review Report
  1. ; This routine will display the Activity during a review
  1. ; Start a new page for every user.
  1. N SDSCCVB,SDSCCUB
  1. I L+3+$S(SDDET:$$CTPOV(),1:0)>IOSL D RVWHD Q:$G(SDABRT)=1 S SDPVCN=1
  1. ; Display the Encounter date
  1. I SDNWPV=1 D
  1. . W $$UP^XLFSTR($$NAME^XUSER(SDLEB,"F"))
  1. . S SDNWPV=0
  1. . I SDPVCN=1 W " (cont'd)" S SDPVCN=0
  1. . W ! S L=L+1
  1. ; Display the Encounter date
  1. W ?5,$$FMTE^XLFDT(SDOEDT,"5MZ")
  1. ; Display the ENCOUNTER Number,VBA/ICD Connected,VBA by User, and Status. Increment Line Count.
  1. S SDSCCVB=$$GET1^DIQ(409.48,SDOE,.09,"E")
  1. S SDSCCUB=$$GET1^DIQ(409.48,SDOE,.06,"E")
  1. I SDSCCUB="" S SDSCCUB="TBD"
  1. W ?23,SDOE,?33,SDSCCVB,?40,SDSCCUB
  1. W ?48,$$GET1^DIQ(409.48,SDOE,.05,"E")
  1. W ?60,$$FMTE^XLFDT($$GET1^DIQ(409.48,SDOE,.02,"E"),"5MZ")
  1. I 'SDDET W ! S L=L+1
  1. I SDDET D Q:$G(SDABRT)=1
  1. . ; check for enough room for return prompt and data.
  1. . I L+2+$$CTPOV()>IOSL D RVWHD Q:$G(SDABRT)=1 S SDPVCN=1
  1. . D POV2S
  1. . I L+2+$$CTDIS()>IOSL D RVWHD Q:$G(SDABRT)=1 S SDPVCN=1
  1. . D DIS2S
  1. . I L+4>IOSL D RVWHD Q:$G(SDABRT)=1 S SDPVCN=1
  1. . W !,! S L=L+2
  1. I L+3>IOSL D RVWHD Q:$G(SDABRT)=1 S SDPVCN=1
  1. Q
  1. ;
  1. CTPOV() ; Count all POV entries for the specified visit.
  1. N SDCT,SDVPOV0
  1. S SDCT=2
  1. S SDVPOV0=0 F S SDVPOV0=$O(^AUPNVPOV("AD",SDV0,SDVPOV0)) Q:'SDVPOV0 S SDCT=SDCT+1
  1. Q SDCT
  1. ;
  1. CTDIS() ; Count all rated disabilities for this patient.
  1. N I,I3,SCRD
  1. S I3=2,I=0
  1. D RDIS^DGRPDB(SDPAT,.SCRD)
  1. F S I=$O(SCRD(I)) Q:'I S I3=I3+1
  1. Q I3
  1. ;
  1. POV2S ; Loop through and display all POV entries for the specified visit.
  1. N SDICD,SDVPOV0
  1. W !!,?10,"POVs/ICDs:" S L=L+2
  1. S SDVPOV0=0 F S SDVPOV0=$O(^AUPNVPOV("AD",SDV0,SDVPOV0)) Q:'SDVPOV0 D
  1. . S SDPOV=$P($G(^AUPNVPOV(SDVPOV0,0)),U),SDICD=$$ICDDX^ICDEX(SDPOV,SDOEDT,+$$SYS^ICDEX("DIAG",SDOEDT,"I"),"I") ;SD*5.3*586
  1. . W !?15,$P(SDICD,U,2),?23,$P(SDICD,U,4) S L=L+1
  1. . Q
  1. Q
  1. ;
  1. DIS2S ; Loop through and display all rated disabilities for this patient.
  1. W !!,?10,"Rated Disabilities:" S L=L+2
  1. N I,I1,I2,I3,SCRD
  1. D RDIS^DGRPDB(SDPAT,.SCRD)
  1. S I3=0,I=0 F S I=$O(SCRD(I)) Q:'I D
  1. . S I1=SCRD(I)
  1. . S I2=$S($D(^DIC(31,+I1,0)):$P(^(0),U,3)_" "_$P(^(0),"^",1)_" ("_+$P(I1,"^",2)_"%-"_$S($P(I1,"^",3):"SC",$P(I1,"^",3)']"":"not specified",1:"NSC")_")",1:""),I3=I3+1
  1. . W !,?15,I2 S L=L+1
  1. . Q
  1. Q
  1. ;
  1. STDHDR ; tag for all of the standard report header calls
  1. ; Do not ask 'RETURN' before first page on CRT.
  1. I $E(IOST,1,2)="C-",P N DIR,Y S DIR(0)="E" D ^DIR I 'Y S SDABRT=1 Q
  1. ; Do not print a form feed before first page on printer. Top of form is set at end of previous report.
  1. I $E(IOST,1,2)="C-"!P W @IOF
  1. S P=P+1,L=5
  1. Q