Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: TIUELST

TIUELST.m

Go to the documentation of this file.
  1. TIUELST ; SLC/JER - Review Filer Events ;9/24/03
  1. ;;1.0;TEXT INTEGRATION UTILITIES;**81,113**;Jun 20, 1997
  1. EN ; Invoke List Manager
  1. D EN^VALM("TIU REVIEW FILING EVENTS")
  1. S VALMBCK="Q"
  1. Q
  1. MAKELIST ; Build review screen list
  1. ; For Types 1;FILING ERRORS and
  1. ; 2;MISSING FIELD ERRORS,
  1. ;status is 0;UNRESOLVED or
  1. ; 1;RESOLVED or
  1. ; 2;UNRESOLVED/RESOLVED.
  1. ; For Types 0;SUCCESSFUL FILING EVENTS and
  1. ; 3;FILING EVENTS,
  1. ;status is "".
  1. N TIUI,TIUTMP,TYPE,STATUS,TIUK
  1. DIVISION ; Select Division(s)
  1. D SELDIV^TIULA
  1. I SELDIV'>0 S VALMQUIT=1 Q
  1. I $D(TIUDI) D
  1. . S TIUK=0 F S TIUK=$O(TIUDI(TIUK)) Q:'TIUK D
  1. . . S TIUDI("ENTRIES")=$G(TIUDI("ENTRIES"))_TIUK_";"
  1. E D
  1. . S TIUDI("ENTRIES")="ALL DIVISIONS"
  1. S TYPE=$$SELTYPE("FILING ERRORS")
  1. I +TYPE=1 S STATUS=$$SELRES("UNRESOLVED") ; 1: Filing errors
  1. I +TYPE=2 S STATUS=$$SELRES("UNRESOLVED") ; 2: Missing Field errors
  1. I +TYPE=0 S STATUS="" ; 0: Successful filing events
  1. I +TYPE=3 S STATUS="" ; 3: All filing events
  1. I '$D(STATUS) S STATUS=""
  1. I +$G(DIRUT) S VALMQUIT=1 Q
  1. S TIUEDT=$$EDATE^TIULA("Event","T-30")
  1. I TIUEDT'>0 S VALMQUIT=1 Q
  1. S TIULDT=$$LDATE^TIULA("Event")
  1. I TIULDT'>0 S VALMQUIT=1 Q
  1. ; If TIUEDT is NOT earlier than TIULDT, then swap
  1. I TIUEDT>TIULDT S TIUTMP=TIUEDT,TIUEDT=TIULDT,TIULDT=TIUTMP
  1. W !,"Searching for the events."
  1. D BUILD(TYPE,STATUS,TIUEDT,TIULDT,.TIUDI)
  1. K TIUDI,SELDIV
  1. Q
  1. SELTYPE(DFLT) ; Select Event Type
  1. N PRMT,READTYPE,X,Y
  1. S PRMT="Select Event Type: "
  1. S READTYPE="SMA^F:Filing Errors;M:Missing Field Errors;S:Successes;A:All Events"
  1. S Y=$P($$READ^TIUU(READTYPE,PRMT,DFLT),U)
  1. S Y=$S(Y="S":"0;SUCCESSFUL FILING EVENTS",Y="F":"1;FILING ERRORS",Y="M":"2;MISSING FIELD ERRORS",1:"3;FILING EVENTS")
  1. Q Y
  1. SELRES(DFLT) ; Select Resolution status
  1. N PRMT,READTYPE,X,Y
  1. S PRMT="Select Resolution Status: "
  1. S READTYPE="SAM^U:Unresolved Errors;R:Resolved Errors;B:Both Unresolved and Resolved"
  1. S Y=$P($$READ^TIUU(READTYPE,PRMT,DFLT),U)
  1. S Y=$S(Y="U":"0;UNRESOLVED",Y="R":"1;RESOLVED",1:"2;UNRESOLVED/RESOLVED")
  1. Q Y
  1. ;
  1. BUILD(TIUTYP,STATUS,EARLY,LATE,DIVIFNS) ; Build List
  1. N TIUCNT,TIUI,TIUJ,TIUK,TIUP,TIUPICK,TIUREC,TIUSTAT,XREF
  1. S VALMCNT=0
  1. K ^TMP("TIUERR",$J),^TMP("TIUERRIDX",$J)
  1. S TIUPICK=+$O(^ORD(101,"B","TIU ACTION SELECT LIST ELEMENT",0))
  1. I '$D(TIUPRM0)!'$D(TIUPRM0) D SETPARM^TIULE
  1. ; For type 3 ALL events, get types 0 for SUCCESSFUL, 1 for FILING ERROR,
  1. ;& 2 for MISSING FIELD ERROR. For other types, just get that type:
  1. F TYPE=$S(+TIUTYP=3:0,1:+TIUTYP):1:$S(+TIUTYP=3:2,1:+TIUTYP) D
  1. . S TIUI=0 F S TIUI=$O(^TIU(8925.4,"D",TYPE,TIUI)) Q:+TIUI'>0 D
  1. . . I +$G(^TIU(8925.4,+TIUI,0))'<EARLY,(+$G(^(0))'>LATE) D
  1. . . . ; If status is UNRESOLVED or RESOLVED, get only matching status;
  1. . . . I STATUS'="",+STATUS'=2 Q:+STATUS'=$P($G(^TIU(8925.4,+TIUI,0)),U,6)
  1. . . . I +$G(DIVIFNS("ENTRIES")),'$$ININST(+TIUI,.DIVIFNS) Q
  1. . . . N DIC,DIQ,DA,DR,TIUERR,EDT,RDT,DTYPE,EDESC,USER,ETYPE,INST,INSTA,TIUSTN
  1. . . . S DIQ="TIUERR",DIC=8925.4,DIQ(0)="IE",DA=TIUI
  1. . . . S DR=".01:.09" D EN^DIQ1
  1. . . . S USER=$$NAME^TIULS(TIUERR(8925.4,DA,.02,"E"),"LAST, FIRST")
  1. . . . S EDT=$$DATE^TIULS(TIUERR(8925.4,DA,.01,"I"),"MM/DD/YY HR:MIN")
  1. . . . S RDT=$$DATE^TIULS(TIUERR(8925.4,DA,.07,"I"),"MM/DD/YY HR:MIN")
  1. . . . S DTYPE=TIUERR(8925.4,DA,.03,"E")
  1. . . . S ETYPE=TIUERR(8925.4,DA,.08,"E"),EDESC=TIUERR(8925.4,DA,.04,"E")
  1. . . . S INSTA="",INST=TIUERR(8925.4,DA,.09,"I")
  1. . . . I INST D
  1. . . . . S TIUSTN=$$NS^XUAF4(INST)
  1. . . . . I $P(TIUSTN,U,2)]"" S INSTA=$P(TIUSTN,U,2)
  1. . . . S INSTA=$E(INSTA,1,8)
  1. . . . S TIUCNT=+$G(TIUCNT)+1
  1. . . . S TIUREC=$$SETFLD^VALM1(TIUCNT,"","NUMBER")
  1. . . . S TIUREC=$$SETFLD^VALM1(DTYPE,TIUREC,"DOCUMENT TYPE")
  1. . . . S TIUREC=$$SETFLD^VALM1(ETYPE,TIUREC,"EVENT TYPE")
  1. . . . S TIUREC=$$SETFLD^VALM1(EDT,TIUREC,"EVENT DATE/TIME")
  1. . . . S TIUREC=$$SETFLD^VALM1(RDT,TIUREC,"RESOL DATE/TIME")
  1. . . . S TIUREC=$$SETFLD^VALM1(USER,TIUREC,"USER NAME")
  1. . . . S TIUREC=$$SETFLD^VALM1(INSTA,TIUREC,"DIVISION")
  1. . . . S VALMCNT=+$G(VALMCNT)+1
  1. . . . S ^TMP("TIUERR",$J,VALMCNT,0)=TIUREC
  1. . . . S ^TMP("TIUERR",$J,"IDX",VALMCNT,TIUCNT)=""
  1. . . . S ^TMP("TIUERR",$J,"PICK",TIUCNT,VALMCNT)=""
  1. . . . D FLDCTRL^VALM10(VALMCNT,"NUMBER",IOINHI,IOINORM)
  1. . . . S VALMCNT=+$G(VALMCNT)+1 W:VALMCNT#5'>0 "."
  1. . . . S ^TMP("TIUERR",$J,VALMCNT,0)=$$SETFLD^VALM1(EDESC,"","DESCRIPTION")
  1. . . . S ^TMP("TIUERR",$J,"IDX",VALMCNT,TIUCNT)=""
  1. . . . S ^TMP("TIUERR",$J,"PICK",TIUCNT,VALMCNT)=""
  1. . . . S ^TMP("TIUERRIDX",$J,TIUCNT)=VALMCNT_U_TIUI_U_$P(^TIU(8925.4,+TIUI,0),U,5)
  1. ;
  1. S ^TMP("TIUERR",$J,0)=+$G(TIUCNT)_U_TIUTYP_U_STATUS
  1. S ^TMP("TIUERR",$J,"#")=TIUPICK_"^1:"_+$G(TIUCNT)
  1. M ^TMP("TIUERR",$J,"DIV")=DIVIFNS
  1. I $D(VALMHDR)>9 D HDR
  1. I +$G(TIUCNT)'>0 D
  1. . S ^TMP("TIUERR",$J,1,0)="",VALMCNT=2
  1. . I +TIUTYP=1!(+TIUTYP=2) S STATUS=$$LOWER^TIULS($P(STATUS,";",2)),STATUS=STATUS_" "
  1. . S ^TMP("TIUERR",$J,2,0)="No "_STATUS_$$LOWER^TIULS($P(TIUTYP,";",2))_" found within date/time range"
  1. Q
  1. ININST(TIUI,TIUDI) ; Evaluates whether a TIU UPLOAD LOG record
  1. ; is among the selected division(s)
  1. ; Input -- TIUI TIU UPLOAD LOG file (#8925.4) IEN
  1. ; -- TIUDI( i.e. TIUDI(file #40.8 IEN)=Institution file
  1. ; pointer for file #40.8 entry
  1. ; Output - TIUY 0= record not in selected division
  1. ; 1= record in selected division
  1. N TIUIFP,TIUJ,TIUINST,TIUY S TIUY=0
  1. S TIUINST=+$P($G(^TIU(8925.4,+TIUI,0)),U,9)
  1. S TIUJ=0 F S TIUJ=$O(TIUDI(TIUJ)) Q:'TIUJ!TIUY D
  1. . S TIUIFP=$G(TIUDI(TIUJ))
  1. . I TIUIFP=TIUINST S TIUY=1
  1. Q TIUY
  1. HDR ; Initialize header for review screen
  1. N BY,TIUX,SCREEN,STATUS,TITLE
  1. S TIUX=$G(^TMP("TIUERR",$J,0))
  1. ;TIU*1*81 status = 3rd, not 2nd piece of TIUX; hdr wrote UNRESOLVED instead of SUCCESSFUL
  1. S TYPE=$P(TIUX,U,2),STATUS=$P(TIUX,U,3)
  1. I +TYPE=0 S TITLE=$P(TYPE,";",2)
  1. I +TYPE=1!(+TYPE=2) D
  1. . S TITLE=$P(STATUS,";",2)
  1. . S TITLE=TITLE_" "_$P(TYPE,";",2)
  1. I +TYPE=3 S TITLE="ALL FILING EVENTS"
  1. I '$D(TITLE) S TITLE=""
  1. I +TIUEDT>1 S TITLE=TITLE_" from "_$$DATE^TIULS(TIUEDT,"MM/DD/YY")_" to "_$$DATE^TIULS(TIULDT,"MM/DD/YY")
  1. S VALMHDR(1)=$$CENTER^TIULS(TITLE)
  1. Q
  1. CLEAN ; Clean up your mess!
  1. K ^TMP("TIUERR",$J),^TMP("TIUERRIDX",$J) D CLEAN^VALM10
  1. K VALMY
  1. Q