Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: TIUFLF2

TIUFLF2.m

Go to the documentation of this file.
  1. TIUFLF2 ; SLC/MAM - Library; File 8925.1 Related: PERSOWNS(FILEDA,PERSON), SELNAME(DEFLT), NAMSCRN(PFILEDA) ;4/23/97 18:20
  1. ;;1.0;TEXT INTEGRATION UTILITIES;;Jun 20, 1997
  1. ;
  1. PERSOWNS(FILEDA,PERSON) ; Function determines if PERSON owns 8925.1
  1. ;Entry FILEDA.
  1. ; Returns 1^P if FILEDA is personally-owned by PERSON;
  1. ; 1^C if FILEDA is owned by a class and PERSON belongs to it;
  1. ; 0 if PERSON doesn't own Entry
  1. ; "" if Entry is not owned except if adding FILEDA as item,
  1. ; 1 if Entry is not owned and adding FILEDA as item. (Users are confused if they don't see the item, so let them add it even if it's missing things).
  1. ; Requires 8925.1 FILEDA;
  1. ; Requires PERSON = IFN in file 200
  1. N ANS,CLASS
  1. I $D(^TIU(8925.1,"AP",PERSON,FILEDA)) S ANS="1^P" G PERSX
  1. S CLASS=$P(^TIU(8925.1,FILEDA,0),U,6)
  1. I $D(^TIU(8925.1,"AC",+CLASS,FILEDA)) D G PERSX
  1. . I $$ISA^USRLM(PERSON,CLASS) S ANS="1^C" Q
  1. . S ANS=0
  1. . Q
  1. I 'CLASS,'$P(^TIU(8925.1,FILEDA,0),U,5) S ANS=$S($G(TIUFSTMP)="T"&($G(TIUFXNOD)["Add"):1,1:"") G PERSX
  1. S ANS=0
  1. PERSX Q ANS
  1. ;
  1. SELNAME(DEFLT) ; Function Prompts for Name, Returns Name or "" if nothing selected or @ entered.
  1. ; Optional DEFLT = present Name if editing name
  1. N DIR,X,Y,DA,NAME
  1. S DIR(0)="FA^3:60^S X=$$UPPER^TIULS(X) K:'(X'?1P.E) X",(DIR("?"),DIR("??"))="^D NAME^TIUFXHLX"
  1. I (TIUFXNOD["Create") S $P(DIR(0),U)="FAO"
  1. I $D(DEFLT) S DIR("B")=DEFLT
  1. S DIR("A")=$S(TIUFXNOD["Basics"!(TIUFXNOD["Name"):"NAME: ",TIUFTMPL'="J":"Enter Document Definition Name to add as New Entry: ",1:"Enter the Name of a new Object: ")
  1. D ^DIR I $D(DTOUT)!$D(DUOUT) S NAME="" G SELNX
  1. S NAME=Y,NAME=$$UPPER^TIULS(NAME)
  1. SELNX Q NAME
  1. ;
  1. NAMSCRN(PFILEDA) ; Function returns DIC("S") for File 8925.1 Lookups when
  1. ;looking up entries to add as items to parent entry. Used in Rtn TIUFT,
  1. ;NOT in file DD's.
  1. ; Adding items is done in 2 separate steps: 1) choosing a new or
  1. ;existing entry and adding it to the file if it is new, and 2) actually
  1. ;adding entry as an item to the parent. This screen is for the first
  1. ;step ONLY. The second step is done in ADDTEN^TIUFLF4 and uses the
  1. ;screen set on fld 10, subfld .01, which prevents lookup failure due to
  1. ;duplicate names by letting only IFN TIUFISCR past the screen.
  1. ; Allows items of appropriate Type or NO Type.
  1. ; Disallows items which already have a parent EXCEPT for Shared Components (field .1).
  1. ; Disallows items which user doesn't own, EXCEPT ownerless items,
  1. ;EXCEPT Shared Components.
  1. ; Disallows entry from being its own item.
  1. ; If PFILEDA is nonNat'l, disallows Nat'l entries except Shared Comp.
  1. ; If PFILEDA is a shared component, disallows nonshared entries.
  1. ; Requires PFILEDA = IFN of 8925.1 parent entry
  1. ; Returns SCRN = screen that allows appropriate items
  1. ; TIUFIMSG is set in DUP^TIUFLF7
  1. N SCRN,PTYPE,HASPRNT,TYPEIS,TYPEISCL,TYPEISDC,TYPISDOC,TYPISNUL,TYPEISCO
  1. N SHARED,USROWNS,RTTYPE,CL,NUL,DC,DOC,CO,POSSTYPE,GOODTYPE,SELFITEM
  1. N NATLOK,PNATL,PNODE0,PSHARED
  1. S SCRN="I 0"
  1. S SELFITEM="(Y="_PFILEDA_")"
  1. S HASPRNT="+$O(^TIU(8925.1,""""AD"""",Y,0))"
  1. S TYPEIS="($P(^(0),U,4)="
  1. S NUL="""""",CL="""CL""",DC="""DC""",DOC="""DOC""",CO="""CO"""
  1. S TYPISNUL=TYPEIS_NUL_")"
  1. S TYPEISCL=TYPEIS_CL_")"
  1. S TYPEISDC=TYPEIS_DC_")"
  1. S TYPISDOC=TYPEIS_DOC_")"
  1. S TYPEISCO=TYPEIS_CO_")"
  1. S POSSTYPE=$$POSSTYPE^TIUFLF7(PFILEDA) G:$D(DTOUT) NAMSX
  1. I POSSTYPE="" W !!," Parent has no Type/Bad Type",! G NAMSX
  1. S GOODTYPE=""
  1. I POSSTYPE["CL" S GOODTYPE=$S(GOODTYPE="":TYPEISCL,1:GOODTYPE_"!"_TYPEISCL)
  1. I POSSTYPE["DC" S GOODTYPE=$S(GOODTYPE="":TYPEISDC,1:GOODTYPE_"!"_TYPEISDC)
  1. I POSSTYPE["DOC" S GOODTYPE=$S(GOODTYPE="":TYPISDOC,1:GOODTYPE_"!"_TYPISDOC)
  1. I POSSTYPE["CO" S GOODTYPE=$S(GOODTYPE="":TYPEISCO,1:GOODTYPE_"!"_TYPEISCO)
  1. S USROWNS="+$$PERSOWNS^TIUFLF2(Y,DUZ)"
  1. S SHARED="+$P(^TIU(8925.1,Y,0),U,10)",PSHARED=+$P(^TIU(8925.1,PFILEDA,0),U,10)
  1. S SCRN="I "_GOODTYPE_",'"_SELFITEM_",'$$DUP^TIUFLF7($P(^(0),U),"_PFILEDA_",Y),$$NATLOK^TIUFLF2(^TIU(8925.1,Y,0),"_PFILEDA_"),'("_PSHARED_"&'"_SHARED_") X:'"_SHARED_" ""I "_USROWNS_"&'"_HASPRNT_""""
  1. NAMSX I $D(DTOUT) S SCRN="I 0"
  1. Q SCRN
  1. ;
  1. NATLOK(NODE0,PFILEDA) ; Function returns 1/0 if item OK/not OK to add as far
  1. ;as Natl goes. Considers if parent is Natl, if Item is Natl,
  1. ;if User has Natl menu.
  1. N NATL,PNODE0,PNATL,PTYPE,SHARED,NATLANS
  1. S NATL=+$P(NODE0,U,13),PNODE0=^TIU(8925.1,PFILEDA,0),PNATL=+$P(PNODE0,U,13),PTYPE=$P(PNODE0,U,4),SHARED=$P(NODE0,U,10),NATLANS=0
  1. I PTYPE="CL"!(PTYPE="DC") S NATLANS=$S(PNATL:$S(NATL:$S(TIUFWHO="N":1,1:0),1:1),1:$S(NATL:0,1:1))
  1. I PTYPE="DOC"!(PTYPE="CO") S NATLANS=$S(PNATL:$S(NATL:1,1:0),1:$S(NATL:$S(SHARED:1,1:0),1:1))
  1. Q NATLANS
  1. ;