Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: TIULAB

TIULAB.m

Go to the documentation of this file.
  1. TIULAB ; SLC/JER - Lab objects ;7/7/95 15:22
  1. ;;1.0;TEXT INTEGRATION UTILITIES;;Jun 20, 1997
  1. MAIN(DFN,EARLY,LATE,DISPLAY,NORM,TARGET,LINE) ; Control branching
  1. N GMTS1,GMTS2,GMTSAGE,GMTSDOB,GMTSPNM,GMTSRB,GMTSSN,GMTSWARD,SEX
  1. N LRDFN,MAX,I,J,SMPL,TIUY,VADPT,VAIN
  1. K ^TMP("LRC",$J)
  1. I $G(NORM)']"" S NORM="ALL"
  1. I '$D(^DPT(DFN,"LR")) D NOLABS G LABX
  1. S LRDFN=+^DPT(DFN,"LR") I '$D(^LR(LRDFN)) D NOLABS G LABX
  1. S MAX=999,GMTS1=9999999-LATE,GMTS2=9999999-EARLY
  1. I +$G(DISPLAY) W !,"Gathering Laboratory Data."
  1. D ^GMTSLRCE
  1. I '$D(^TMP("LRC",$J)) D NOLABS G LABX
  1. D SORT($G(NORM))
  1. S (TIUY,SMPL)="" F S SMPL=$O(^TMP("LRC",$J,NORM,SMPL)) Q:SMPL="" D
  1. . S I=GMTS1 F S I=$O(^TMP("LRC",$J,NORM,SMPL,I)) Q:+I'>0!(I>GMTS2) D
  1. . . S J=0 F S J=$O(^TMP("LRC",$J,NORM,SMPL,I,J)) Q:+J'>0 D LINE
  1. K ^TMP("LRC",$J)
  1. LABX Q "~@"_$NA(@TARGET)
  1. NOLABS ; Handles Case Where no Labs are found to satisfy criteria
  1. S LINE=$S(+$G(LINE):+$G(LINE),1:1),@TARGET@(LINE,0)="No data available"
  1. S LINE=+$G(LINE)+1,@TARGET@(LINE,0)=" "
  1. S @TARGET@(0)="^^"_LINE_"^"_LINE_"^"_DT_"^^"
  1. Q
  1. SORT(NFLAG) ; Sort ^TMP("LRC",$J, by reference flag
  1. N I,J,K,L I $G(NFLAG)']"" S NFLAG="ALL"
  1. S I=GMTS1 F S I=$O(^TMP("LRC",$J,I)) Q:+I'>0!(I>GMTS2) D
  1. . S J=0 F S J=$O(^TMP("LRC",$J,I,J)) Q:+J'>0 D
  1. . . I NFLAG="ALL" S K="ALL"
  1. . . E I $P(^TMP("LRC",$J,I,J),U,5)']"" S K="NORM"
  1. . . E S K="ABNORM"
  1. . . S L=$P(^TMP("LRC",$J,I,J),U,2)
  1. . . I NFLAG="ALL"!(K=NFLAG) S ^TMP("LRC",$J,K,L,I,J)=^TMP("LRC",$J,I,J)
  1. . . K ^TMP("LRC",$J,I,J)
  1. Q
  1. LINE ; Line-wrap with comma-dimited data
  1. N X,Y,TIUX
  1. S TIUX=$P($G(^TMP("LRC",$J,NORM,SMPL,I,J)),U,3,4)
  1. I $S($$HASNUM^TIULS($P(TIUX,U)):0,$L($P(TIUX,U))>5:1,$L($P(TIUX,U)," ")>1:1,1:0) D
  1. . S $P(TIUX,U)=$$MIXED^TIULS($P(TIUX,U))
  1. S $P(TIUX,U,2)=$TR($P(TIUX,U,2)," ",""),TIUX=$TR(TIUX,U," ")
  1. S TIUY=$$FILL^TIULS(TIUX,TIUY,79)
  1. I TIUY=TIUX S LINE=+$G(LINE)+1
  1. S @TARGET@(LINE,0)=TIUY
  1. S @TARGET@(0)="^^"_LINE_"^"_LINE_"^"_DT_"^^"
  1. I +$G(DISPLAY) W "."
  1. Q