Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: TIUPUTPF

TIUPUTPF.m

Go to the documentation of this file. 
  1. TIUPUTPF ; SLC/JER - PRF Look-up Method - ;10/9/05
  1.  ;;1.0;TEXT INTEGRATION UTILITIES;**184**;Jun 20, 1997
  1.  ; COPIED FROM TIUPUTPN AND THEN EDITED
  1. LOOKUP ; Look-up code used by router/filer
  1.  ; Required: TIUSSN, TIUVDT
  1.  ; -- Selected flag action is set in LOOKUP & in GETCHECK^TIUPFFIX;
  1.  ;    Action is used in post-file code to link note.
  1.  ;    Kill it before setting it:
  1.  K ^TMP("TIUPRFUP",$J)
  1.  N DA,DFN,TIU,TIUDAD,TIUEDIT,TIUEDT,TIULDT,TIUXCRP,TIUTYPE
  1.  N TIUNEW,TIUEXIST,TIUDPRM,TIUASACT
  1.  S TIUEXIST=1
  1.  I $S('$D(TIUSSN):1,'$D(TIUVDT):1,$G(TIUSSN)?4N:1,$G(TIUSSN)']"":1,1:0) S Y=-1 G LOOKUPX
  1.  I TIUSSN?3N1P2N1P4N.E S TIUSSN=$TR(TIUSSN,"-/","")
  1.  I TIUSSN["?" S Y=-1 G LOOKUPX
  1.  S TIULOC=+$$ILOC(TIULOC)
  1.  I '$D(^SC(+$G(TIULOC),0)) S Y=-1 G LOOKUPX
  1.  S TIUINST=+$$DIVISION^TIULC1(TIULOC)
  1.  S TIUEDT=$$IDATE^TIULC(TIUVDT),TIULDT=$$FMADD^XLFDT(TIUEDT,1)
  1.  I +TIUEDT'>0 S Y=-1 Q
  1.  S TIUTYPE=$$WHATITLE(TIUTITLE)
  1.  I +TIUTYPE'>0 S Y=-1 Q
  1.  ; -- Abort upload if title is not a PRF title:
  1.  I '$$ISPFTTL^TIUPRFL(+TIUTYPE) S Y=-1 Q
  1.  D DOCPRM^TIULC1(+TIUTYPE,.TIUDPRM)
  1.  I $P($G(^SC(+TIULOC,0)),U,3)="W" D  I 1
  1.  . D MAIN^TIUMOVE(.TIU,.DFN,TIUSSN,TIUEDT,TIULDT,1,"LAST",0,TIULOC)
  1.  E  D MAIN^TIUVSIT(.TIU,.DFN,TIUSSN,TIUEDT,TIULDT,"LAST",0,TIULOC)
  1.  I $S($D(TIU)'>9:1,+$G(DFN)'>0:1,1:0) S Y=-1 G LOOKUPX
  1.  I $P(+$G(TIU("EDT")),".")'=$P($$IDATE^TIULC(TIUVDT),".") S Y=-1 G LOOKUPX
  1.  I '+$$EXIST^TIUEDI3(DFN,+TIUTYPE,TIU("VSTR"),1,DUZ) S TIUEXIST=0 D
  1.  . ; -- If refiling after filing error, get flag assignment^action
  1.  . ;    from user:
  1.  . I $G(PRFILERR) S TIUASACT=$$SELECT^TIUPRF1(+TIUTYPE,DFN)
  1.  . ; -- If not, try for one available action:
  1.  . I '$G(PRFILERR) K ^TMP("TIUPRF",$J) S TIUASACT=$$ONEACT(DFN,+TIUTYPE) K ^TMP("TIUPRF",$J)
  1.  . I TIUASACT S ^TMP("TIUPRFUP",$J)=TIUASACT
  1.  I 'TIUEXIST,'$G(^TMP("TIUPRFUP",$J)) S Y=-1 G LOOKUPX
  1.  S TIUTYP(1)=1_U_TIUTYPE_U_$$PNAME^TIULC1(TIUTYPE)
  1.  S Y=$$GETRECNW^TIUEDI3(DFN,.TIU,TIUTYP(1),.TIUNEW,.TIUDPRM)
  1.  I +Y'>0 G LOOKUPX
  1.  ; If record is not new, has text and can be edited, then replace
  1.  ; existing text
  1.  I +$G(TIUNEW)'>0 D
  1.  . S TIUEDIT=$$CANEDIT(+Y)
  1.  . I +TIUEDIT>0,$D(^TIU(8925,+Y,"TEXT")) D DELTEXT(+Y)
  1.  . I +TIUEDIT'>0 S TIUDAD=+Y,Y=$$MAKEADD
  1.  I +Y'>0 Q
  1.  D STUFREC(Y,+$G(TIUDAD))
  1.  I +$G(TIUDAD) D SENDADD^TIUALRT(+Y)
  1.  K TIUHDR(.01),TIUHDR(.07),TIUHDR(1301)
  1. LOOKUPX Q
  1.  ;
  1. ONEACT(DFN,TIUTYPE) ; If there is exactly one Assigment History Action
  1.  ; available for pat DFN & Title TIUTYPE, return ASSGNIEN^ACTIEN;
  1.  ; else return 0
  1.  ;Count only unlinked, linkable actions
  1.  ;An action is LINKABLE if it is not ENTERED IN ERROR (EIE) and
  1.  ; is not taken prior to an EIE action.
  1.  N TIUDG,TIUASSGN,ONEIEN,RESULT,ARRAYNM
  1.  S RESULT=0,ARRAYNM="^TMP(""TIUPRFH"",$J)"
  1.  S TIUDG=$$GETHTIU^DGPFAPI1(DFN,+TIUTYPE,ARRAYNM)
  1.  I 'TIUDG G ONEACTX
  1.  S TIUASSGN=+$G(@ARRAYNM@("ASSIGNIEN"))
  1.  I $$AVAILACT^TIUPRFL(ARRAYNM,,,.ONEIEN)=1 S RESULT=TIUASSGN_U_ONEIEN
  1. ONEACTX ;
  1.  K ^TMP("TIUPRFH",$J)
  1.  Q RESULT
  1.  ;
  1. ILOC(LOCATION) ; Get pointer to file 44
  1.  N DIC,X,Y
  1.  S DIC=44,DIC(0)="M",X=LOCATION D ^DIC
  1.  Q Y
  1. CANEDIT(DA) ; Check whether or not document is released
  1.  Q $S(+$P($G(^TIU(8925,+DA,0)),U,5)<4:1,1:0)
  1. MAKEADD() ; Create an addendum record
  1.  N DIE,DR,DA,DIC,X,Y,DLAYGO,TIUATYP,TIUFPRIV S TIUFPRIV=1
  1.  S TIUATYP=+$$WHATITLE("ADDENDUM")
  1.  S (DIC,DLAYGO)=8925,DIC(0)="L",X=""""_"`"_TIUATYP_""""
  1.  D ^DIC
  1.  S DA=+Y
  1.  I +DA>0 S DIE=DIC,DR=".04////"_$$DOCCLASS^TIULC1(TIUATYP) D ^DIE
  1.  K TIUHDR(.01)
  1.  Q +DA
  1. STUFREC(DA,PARENT) ; Stuff fixed field data
  1.  N FDA,FDARR,IENS,FLAGS,TIUMSG
  1.  S IENS=""""_DA_",""",FDARR="FDA(8925,"_IENS_")",FLAGS="K"
  1.  I +$G(PARENT)'>0 D
  1.  . S @FDARR@(.02)=$G(DFN),@FDARR@(.03)=$P($G(TIU("VISIT")),U)
  1.  . S @FDARR@(.05)=3
  1.  . S @FDARR@(.07)=$P($G(TIU("EDT")),U)
  1.  . S @FDARR@(.08)=$P($G(TIU("LDT")),U)
  1.  . S @FDARR@(1201)=$$NOW^TIULC
  1.  . S @FDARR@(1205)=$S(+$P($G(TIU("LOC")),U):$P($G(TIU("LOC")),U),1:$P($G(TIU("VLOC")),U))
  1.  . ;S @FDARR@(1211)=$P($G(TIU("VLOC")),U)
  1.  . S @FDARR@(1404)=$P($G(TIU("SVC")),U)
  1.  I +$G(PARENT)>0 D
  1.  . S @FDARR@(.02)=+$P($G(^TIU(8925,+PARENT,0)),U,2)
  1.  . S @FDARR@(.03)=+$P($G(^TIU(8925,+PARENT,0)),U,3),@FDARR@(.05)=3
  1.  . S @FDARR@(.06)=PARENT
  1.  . S @FDARR@(.07)=$P($G(^TIU(8925,+PARENT,0)),U,7)
  1.  . S @FDARR@(.08)=$P($G(^TIU(8925,+PARENT,0)),U,8)
  1.  . S @FDARR@(1205)=$P($G(^TIU(8925,+PARENT,12)),U,5)
  1.  . S @FDARR@(1404)=$P($G(^TIU(8925,+PARENT,14)),U,4)
  1.  . S @FDARR@(1201)=$$NOW^TIULC
  1.  S @FDARR@(1205)=$P($G(TIU("LOC")),U)
  1.  S @FDARR@(1212)=$P($G(TIU("INST")),U)
  1.  S @FDARR@(1301)=$S($G(TIUDDT)]"":$$IDATE^TIULC($G(TIUDDT)),1:"")
  1.  I $S(@FDARR@(1301)'>0:1,$P(@FDARR@(1301),".",2)']"":1,1:0) D
  1.  . S @FDARR@(1301)=$S($P($G(TIU("VSTR")),";",3)="H":$$NOW^XLFDT,1:$G(@FDARR@(.07)))
  1.  S @FDARR@(1303)="U"
  1.  D FILE^DIE(FLAGS,"FDA","TIUMSG") ; File record
  1.  Q
  1. DELTEXT(DA) ; Delete existing text in preparation for replacement
  1.  N DIE,DR,X,Y
  1.  S DIE=8925,DR="2///@" D ^DIE
  1.  Q
  1. WHATYPE(X) ; Identify document type
  1.  ; Receives: X=Document Definition Name
  1.  ;  Returns: Y=Document Definition IFN
  1.  N DIC,Y,TIUFPRIV S TIUFPRIV=1
  1.  S DIC=8925.1,DIC(0)="M"
  1.  S DIC("S")="I $D(^TIU(8925.1,+Y,""HEAD""))!$D(^TIU(8295.1,+Y,""ITEM""))"
  1.  D ^DIC K DIC("S")
  1. WHATYPX Q Y
  1. WHATITLE(X) ; Identify document title
  1.  ; Receives: X=Document Definition Name
  1.  ;  Returns: Y=Document Definition IFN
  1.  N DIC,Y,TIUFPRIV S TIUFPRIV=1
  1.  S DIC=8925.1,DIC(0)="M"
  1.  S DIC("S")="I $P(^TIU(8925.1,+Y,0),U,4)=""DOC"""
  1.  D ^DIC K DIC("S")
  1. WHATITX Q Y
  1. FOLLOWUP(TIUDA) ; Post-filing code for PRF
  1.  N FDA,FDARR,IENS,FLAGS,TIUMSG,TIU,DFN,TIUTEMP
  1.  S IENS=""""_TIUDA_",""",FDARR="FDA(8925,"_IENS_")",FLAGS="K"
  1.  S @FDARR@(1204)=$$WHOSIGNS^TIULC1(TIUDA)
  1.  I +$P($G(^TIU(8925,TIUDA,12)),U,9),'+$P($G(^(12)),U,8) D
  1.  . S @FDARR@(1208)=$$WHOCOSIG^TIULC1(TIUDA)
  1.  D FILE^DIE(FLAGS,"FDA","TIUMSG")
  1.  I +$P($G(^TIU(8925,+TIUDA,12)),U,8),(+$P($G(^TIU(8925,+TIUDA,12)),U,4)'=+$P($G(^(12)),U,8)) D
  1.  . S @FDARR@(1506)=1 D FILE^DIE(FLAGS,"FDA","TIUMSG")
  1.  D RELEASE^TIUT(TIUDA,1)
  1.  D AUDIT^TIUEDI1(TIUDA,0,$$CHKSUM^TIULC("^TIU(8925,"_+TIUDA_",""TEXT"")"))
  1.  I $G(^TMP("TIUPRFUP",$J)) D
  1.  . N TIUDFN S TIUDFN=$P($G(^TIU(8925,TIUDA,0)),U,2)
  1.  . S TIUTEMP=$$LINK^TIUPRF1(TIUDA,$P($G(^TMP("TIUPRFUP",$J)),U),$P($G(^TMP("TIUPRFUP",$J)),U,2),TIUDFN)
  1.  . K ^TMP("TIUPRFUP",$J)
  1.  I '$D(TIU("VSTR")) D
  1.  . N TIUD0,TIUD12,TIUVLOC,TIUHLOC,TIUEDT,TIULDT
  1.  . S TIUD0=$G(^TIU(8925,+TIUDA,0)),TIUD12=$G(^(12))
  1.  . S DFN=+$P(TIUD0,U,2),TIUEDT=+$P(TIUD0,U,7)
  1.  . S TIULDT=$$FMADD^XLFDT(TIUEDT,1),TIUHLOC=+$P(TIUD12,U,5)
  1.  . S TIUVLOC=$S(+$P(TIUD12,U,11):+$P(TIUD12,U,11),1:+TIUHLOC)
  1.  . I $S(+DFN'>0:1,+TIUEDT'>0:1,+TIULDT'>0:1,+TIUVLOC'>0:1,1:0) Q
  1.  . D MAIN^TIUVSIT(.TIU,DFN,"",TIUEDT,TIULDT,"LAST",0,+TIUVLOC)
  1.  Q:'$D(TIU("VSTR"))
  1.  D ENQ^TIUPXAP1 ; Get/file VISIT
  1.  Q