Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: TIURA2

TIURA2.m

Go to the documentation of this file. 
  1. TIURA2 ; SLC/JER - More review screen actions ; 6/29/12 9:02am
  1.  ;;1.0;TEXT INTEGRATION UTILITIES;**88,58,100,123,112,182,269**;Jun 20, 1997;Build 5
  1.  ; 6/20/00: Moved DISPLAY, BROWSE, & BROWS1 from TIURA to TIURA2
  1. DISPLAY ; Detailed Display
  1.  N TIUDA,TIUD,TIUDATA,TIUI,Y,DIROUT,TIUQUIT,RSTRCTD
  1.  I '$D(VALMY) D EN^VALM2(XQORNOD(0))
  1.  S TIUI=0
  1.  F  S TIUI=$O(VALMY(TIUI)) Q:+TIUI'>0  D  Q:$D(TIUQUIT)
  1.  . N TIUVIEW
  1.  . S TIUDATA=$G(^TMP("TIURIDX",$J,TIUI))
  1.  . D CLEAR^VALM1
  1.  . W !!,"Reviewing #",+TIUDATA
  1.  . S TIUDA=+$P(TIUDATA,U,2)
  1.  . S TIUVIEW=$$CANDO^TIULP(TIUDA,"VIEW")
  1.  . I +TIUVIEW'>0 D  Q
  1.  . . W !!,$C(7),$P(TIUVIEW,U,2),!
  1.  . . I $$READ^TIUU("EA","RETURN to continue...") ; pause
  1.  . . D RESTORE^VALM10(+TIUI)
  1.  . S RSTRCTD=$$DOCRES^TIULRR(TIUDA)
  1.  . I RSTRCTD D  Q
  1.  . . W !!,$C(7),"Ok, no harm done...",!
  1.  . . I $$READ^TIUU("EA","RETURN to continue...") ; pause
  1.  . . D RESTORE^VALM10(+TIUI)
  1.  . D EN^TIUAUDIT
  1.  . I +$G(TIUQUIT) D FIXLSTNW^TIULM Q
  1.  . I TIUI'=$P($G(TIUGLINK),U,2) D RESTORE^VALM10(+TIUI) ; See rtn TIURL
  1.  K VALMY S VALMBCK="R"
  1.  Q
  1. BROWSE(TIULTMP) ; Browse selected documents
  1.  ; TIULTMP is list template name
  1.  N TIUDA,DFN,TIU,TIUCHNG,TIUDATA,TIUI,Y,DIROUT,TIUQUIT
  1.  N TIUGDATA
  1.  I '$D(VALMY) D EN^VALM2(XQORNOD(0))
  1.  S TIUI=0
  1.  F  S TIUI=$O(VALMY(TIUI)) Q:+TIUI'>0  D  Q:$D(TIUQUIT)
  1.  . N TIUVIEW,TIUGACT,RSTRCTD
  1.  . S TIUDATA=$G(^TMP("TIURIDX",$J,TIUI))
  1.  . S TIUDA=+$P(TIUDATA,U,2)
  1.  . S TIUGDATA=$G(^TMP("TIUR",$J,"IDDATA",TIUDA)) ; ID note/entry
  1.  . D CLEAR^VALM1
  1.  . W !!,"Reviewing Item #",TIUI
  1.  . S RSTRCTD=$$DOCRES^TIULRR(TIUDA)
  1.  . I RSTRCTD D  Q
  1.  . . W !!,$C(7),"Ok, no harm done...",!
  1.  . . I $$READ^TIUU("EA","RETURN to continue...") ; pause
  1.  . D BROWS1(TIULTMP,TIUDA,TIUGDATA)
  1.  ; -- Update or Rebuild list: --
  1.  I $G(TIUCHNG("DELETE"))!$G(TIUCHNG("ADDM")) S TIUCHNG("RBLD")=1
  1.  S TIUCHNG("UPDATE")=1 ; default
  1.  D UPRBLD^TIURL(.TIUCHNG,.VALMY) K VALMY
  1.  S VALMBCK="R"
  1.  Q
  1. GETSORT(PRMSORT,EXPSORT) ; Get order for ID entries
  1.  Q $S($G(EXPSORT)'="":EXPSORT,1:PRMSORT)
  1.  ;
  1. BROWS1(TIULTMP,TIUDA,TIUGDATA) ; Browse single document
  1.  ;  Calls EN^VALM
  1.  N %DT,C,D0,DIQ2,FINISH,TIU,TIUVIEW
  1.  I '$D(TIUGDATA) S TIUGDATA=$$IDDATA^TIURECL1(TIUDA)
  1.  I TIULTMP="TIU COMPLETE NOTES",$P(TIUGDATA,U,2) W !!,"You are completing the PARENT ENTRY of this interdisciplinary note."
  1.  I '$P(TIUGDATA,U,2) D  Q:+TIUVIEW'>0  ;TIU*1*123
  1.  . S TIUVIEW=$$CANDO^TIULP(TIUDA,"VIEW")
  1.  . I +TIUVIEW'>0 D
  1.  . . W !!,$C(7),$P(TIUVIEW,U,2),!
  1.  . . I $$READ^TIUU("EA","RETURN to continue...") ; pause
  1.  I '$D(TIUPRM0)!'$D(TIUPRM1) D SETPARM^TIULE
  1.  D EN^VALM(TIULTMP)
  1.  K ^TMP("TIUVIEW",$J)
  1.  Q
  1.  ;
  1. EXPAND ; Expand/Collapse ID notes, Addenda in lists
  1.  N TIUDNM,TIULNM,TIUSTAT
  1.  D:'$D(VALMY) EN^VALM2(XQORNOD(0))
  1.  I $D(VALMY) D EC^TIURECL(.VALMY)
  1.  W !,"Refreshing the list."
  1.  K VALMY
  1.  S VALMCNT=+$G(@VALMAR@(0))
  1.  S VALMBCK="R"
  1.  Q
  1.  ;
  1. PRNTSCRN(VALMY) ; Evaluate whether a record may be printed
  1.  N TIUI S TIUI=""
  1.  F  S TIUI=$O(VALMY(TIUI)) Q:+TIUI'>0  D  Q:$D(DIROUT)
  1.  . N TIUPMTHD,TIUDTYP,TIUPFHDR,TIUPFNBR,TIUPGRP,TIUPRINT,TIUFLAG,RSTRCTD,TIUTYP
  1.  . S RSTRCTD=0,TIUDATA=$G(^TMP("TIURIDX",$J,TIUI))
  1.  . ; *269 vmp/djh - Check if file exists
  1.  . S TIUDA=+$P(TIUDATA,U,2),TIUTYP=+$G(^TIU(8925,TIUDA,0))
  1.  . Q:TIUTYP'>0
  1.  . ; Evaluate whether user can print record
  1.  . S TIUPRINT=$$CANDO^TIULP(TIUDA,"PRINT RECORD")
  1.  . I +TIUPRINT'>0 D  Q
  1.  . . W !!,"Item #",TIUI,": ",!,$P(TIUPRINT,U,2),!
  1.  . . K VALMY(TIUI)
  1.  . . I $$READ^TIUU("EA","RETURN to continue...")
  1.  . ;-- Add Check for restricted record when available --
  1.  . S DFN=+$P(^TIU(8925,TIUDA,0),U,2)
  1.  . S RSTRCTD=$$PTRES^TIULRR(DFN)
  1.  . I +RSTRCTD D  Q
  1.  . . W !!,"Item #",TIUI," Removed from print list.",!
  1.  . . K VALMY(TIUI)
  1.  . . I $$READ^TIUU("EA","Press RETURN to continue...")
  1.  . I +$G(TIUPFLG) S TIUFLAG=+$$CHARTONE^TIURA1(TIUDA)
  1.  Q
  1. DICTATED        ; Mark Document(s) "dictated"
  1.  N TIUCHNG,TIUI,TIUY,Y,DIROUT
  1.  I '$D(VALMY) D EN^VALM2(XQORNOD(0))
  1.  S TIUI=0
  1.  F  S TIUI=$O(VALMY(TIUI)) Q:+TIUI'>0  D  Q:$D(DIROUT)
  1.  . N TIU,DFN,TIUDA,TIUDATA,RSTRCTD
  1.  . S TIUDATA=$G(^TMP("TIURIDX",$J,TIUI))
  1.  . S TIUDA=+$P(TIUDATA,U,2) S RSTRCTD=$$DOCRES^TIULRR(TIUDA)
  1.  . I RSTRCTD D  Q
  1.  . . W !!,$C(7),"Ok, no harm done...",!
  1.  . . I $$READ^TIUU("EA","RETURN to continue...") ; pause
  1.  . D EN^VALM("TIU DOCUMENT DICTATED")
  1.  ; -- Update or Rebuild list: --
  1.  S TIUCHNG("UPDATE")=1
  1.  D UPRBLD^TIURL(.TIUCHNG,.VALMY) K VALMY
  1.  S VALMBCK="R"
  1.  Q
  1. DICTATE1(TIUDA) ; Single record sign on chart
  1.  N DICMSG D FULL^VALM1
  1.  D DICT(TIUDA,.DICMSG)
  1.  W !!,$G(DICMSG(1)),!,$G(DICMSG(2)),! H $S($D(DICMSG(0)):+DICMSG(0),1:3)
  1.  Q
  1. DICT(DA,MSG) ; Mark signed on chart. Edit on-chart signatures.
  1.  N AUTHOR,DIE,DR,Y,TIUSTAT,EXPCSNR,ATTNDNG,TIUDA,TIUPRMT,TIU0,TIU12,TIU13
  1.  S TIU0=$G(^TIU(8925,+DA,0)),TIU12=$G(^(12)),TIU13=$G(^(13))
  1.  S TIUSTAT=$P(TIU0,U,5)
  1.  S TIUPRMT=$S(TIUSTAT>1:"Edit Dictation Data? ",1:"Has this document been dictated? ")
  1.  W ! S MSG=$$READ^TIUU("YAO",TIUPRMT,"NO") W !
  1.  I 'MSG S TIUCHNG=0 G DICTX
  1.  S TIUCHNG=1
  1.  S AUTHOR=$$PERSNAME^TIULC1(+$P(TIU12,U,2))
  1.  S EXPCSNR=$$PERSNAME^TIULC1(+$P(TIU12,U,8))
  1.  S:+$P(TIU12,U,9) ATTNDNG=$$PERSNAME^TIULC1(+$P(TIU12,U,9))
  1.  S DR="1202//^S X=AUTHOR;1307//^S X=$S(+$P(TIU13,U,7)'>0:""NOW"",1:$$DATE^TIULS(+$P(TIU13,U,7),""MM/DD/CCYY@HR:MIN:SEC""))"
  1.  I $D(ATTNDNG) S DR=DR_";1209//^S X=ATTNDNG"
  1.  E  I $D(EXPCSNR) S DR=DR_";1208//^S X=EXPCSNR"
  1.  S DR=DR_";1204////^S X=$$WHOSIGNS^TIULC1(DA);1208////^S X=$$WHOCOSIG^TIULC1(DA)"
  1.  S DIE=8925 D ^DIE
  1.  S TIU0=$G(^TIU(8925,+DA,0)),TIU12=$G(^(12)),TIU13=$G(^(13))
  1.  ;Toggle status between undictated and untranscribed, depending on Dict Date
  1.  S DR=".05///^S X=$S(+$P(TIU13,U,7):""UNTRANSCRIBED"",1:""UNDICTATED"")",DIE=8925 D ^DIE
  1.  D UPDTIRT^TIUDIRT(.TIU,+DA)
  1. DICTX S MSG(1)="  Dictation data "_$S(TIUCHNG:"",1:"NOT ")_"changed."
  1.  Q