Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: TIURD4

TIURD4.m

Go to the documentation of this file.
  1. TIURD4 ; SLC/JER - Reassign actions ;13-APR-2001 14:29:02
  1. ;;1.0;TEXT INTEGRATION UTILITIES;**61,100**;Jun 20, 1997
  1. FROMTO(TIUDA,TIUDAT) ; Display the from/to information
  1. N TIUF,TIUT,TIUDAD,TIUFEDT,TIUFLDT,TIUTEDT,TIUTLDT
  1. S TIUDAD=$P($G(^TIU(8925,+TIUDA,0)),U,6)
  1. D GETTIU^TIULD(.TIUF,+TIUDAD)
  1. D GETTIU^TIULD(.TIUT,+TIUDAT)
  1. S TIUFEDT=$$DATE^TIULS($P(TIUF("EDT"),U),"MM/DD/YY")
  1. S TIUFLDT=$$DATE^TIULS($P(TIUF("LDT"),U),"MM/DD/YY")
  1. S TIUTEDT=$$DATE^TIULS($P(TIUT("EDT"),U),"MM/DD/YY")
  1. S TIUTLDT=$$DATE^TIULS($P(TIUT("LDT"),U),"MM/DD/YY")
  1. W !!,"You are about to move the addendum as follows:",!
  1. W !,?5,"From",?45,"To",!
  1. W !,$P(TIUF("DOCTYP"),U,2),?35," --> ",?40,$P(TIUT("DOCTYP"),U,2)
  1. W !,TIUF("PNM")," ",TIUF("PID"),?35," --> ",?40,TIUT("PNM")," ",TIUT("PID")
  1. W !,TIUFEDT,$S($L(TIUFLDT):" - "_TIUFLDT,1:""),?35," --> "
  1. W ?40,TIUTEDT,$S($L(TIUTLDT):" - "_TIUTLDT,1:""),!
  1. Q
  1. UPDSTAT(DA) ; Update the status of the named record
  1. N DIE,DR
  1. S DIE=8925,DR=".05///^S X=$$STATUS^TIULC(DA)"
  1. D ^DIE
  1. Q
  1. LOADSB(TIUODA,TIUADA,TIUOS,TIUAS) ; Load arrays w/Sig Blocks
  1. N TIUOD15,TIUAD15
  1. S TIUOD15=$G(^TIU(8925,TIUODA,15))
  1. S TIUOS("SBN")=$S($P(TIUOD15,U,3)]"":$$DECRYPT(TIUODA,$P(TIUOD15,U,3)),1:"@")
  1. S TIUOS("SBT")=$S($P(TIUOD15,U,4)]"":$$DECRYPT(TIUODA,$P(TIUOD15,U,4)),1:"@")
  1. S TIUOS("CSBN")=$S($P(TIUOD15,U,9)]"":$$DECRYPT(TIUODA,$P(TIUOD15,U,9)),1:"@")
  1. S TIUOS("CSBT")=$S($P(TIUOD15,U,10)]"":$$DECRYPT(TIUODA,$P(TIUOD15,U,10)),1:"@")
  1. S TIUAD15=$G(^TIU(8925,TIUADA,15))
  1. S TIUAS("SBN")=$S($P(TIUAD15,U,3)]"":$$DECRYPT(TIUADA,$P(TIUAD15,U,3)),1:"@")
  1. S TIUAS("SBT")=$S($P(TIUAD15,U,4)]"":$$DECRYPT(TIUADA,$P(TIUAD15,U,4)),1:"@")
  1. S TIUAS("CSBN")=$S($P(TIUAD15,U,9)]"":$$DECRYPT(TIUADA,$P(TIUAD15,U,9)),1:"@")
  1. S TIUAS("CSBT")=$S($P(TIUAD15,U,10)]"":$$DECRYPT(TIUADA,$P(TIUAD15,U,10)),1:"@")
  1. Q
  1. SWAPSB(TIUODA,TIUADA,TIUOS,TIUAS) ; Swap Signature blocks
  1. N DA,DIE,DR
  1. S DR="1503///^S X=TIUAS(""SBN"");1504///^S X=TIUAS(""SBT"")"
  1. S DR=DR_";1509///^S X=TIUAS(""CSBN"");1510///^S X=TIUAS(""CSBT"")"
  1. S DA=TIUODA,DIE="^TIU(8925," D ^DIE K DR
  1. S DR="1503///^S X=TIUOS(""SBN"");1504///^S X=TIUOS(""SBT"")"
  1. S DR=DR_";1509///^S X=TIUOS(""CSBN"");1510///^S X=TIUOS(""CSBT"")"
  1. S DA=TIUADA,DIE="^TIU(8925," D ^DIE K DR
  1. Q
  1. DECRYPT(TIUDA,TIUX) ; Decrypt signature blocks
  1. N TIUY
  1. S TIUY=$$DECRYPT^TIULC1(TIUX,1,$$CHKSUM^TIULC("^TIU(8925,"_+TIUDA_",""TEXT"")"))
  1. Q TIUY
  1. RECOVER(TIUODA,TIUDA,TIUD0) ; Restore original state on abort
  1. N DIE,DR,DA,DIDEL,TIUI
  1. W $C(7),$C(7),!!,"Transaction aborted. Restoring records to original state..."
  1. ; Loop thru ^TMP("TIURTRCT",$J,DA) and restore prior state
  1. I '$D(^TMP("TIURTRCT",$J,TIUODA)) D
  1. . W !!,"** Can't Restore to Prior State...'$D(^TMP(""TIURTRCT"",$J,TIUODA)) **"
  1. S TIUI=0 F S TIUI=$O(^TMP("TIURTRCT",$J,TIUI)) Q:+TIUI'>0 D
  1. . N DIE,DR,X,Y,TIUD0,DA
  1. . S DA=TIUI,TIUD0=^TMP("TIURTRCT",$J,DA,0)
  1. . S DIE=8925
  1. . S DR=".03////^S X=$P(TIUD0,U,3);.05////^S X=$P(TIUD0,U,5);.06////^S X=$P(TIUD0,U,6)"
  1. . D ^DIE
  1. ; Loop thru ^TMP("TIURTRCT",$J,"NEW",DA) and delete duplicate notes
  1. I '$D(^TMP("TIURTRCT",$J,"NEW",TIUDA)) D
  1. . W !!,"** Can't Restore to Prior State...'$D(^TMP(""TIURTRCT"",$J,""NEW"",TIUDA)) **"
  1. S TIUI=0 F S TIUI=$O(^TMP("TIURTRCT",$J,"NEW",TIUI)) Q:+TIUI'>0 D
  1. . D DELDOC(TIUI)
  1. H 3
  1. Q
  1. DELDOC(DA) ; Delete document and components--NOT its addenda
  1. N DIE,DIDEL,DR,X,Y,TIUDA,TIUI
  1. S TIUDA=DA
  1. ; First, delete audit trail entries
  1. D DELAUDIT^TIUEDI1(TIUDA)
  1. D DELSGNRS(TIUDA)
  1. ; Next, delete the document's components
  1. S TIUI=0 F S TIUI=$O(^TIU(8925,"DAD",TIUDA,TIUI)) Q:+TIUI'>0 D
  1. . I +$$ISADDNDM^TIULC1(TIUI) Q
  1. . D DELDOC(TIUI)
  1. S (DIDEL,DIE)=8925,DR=".01///@"
  1. D ^DIE ; Delete duplicate note
  1. Q
  1. DELSGNRS(TIUDA,UNSIGN) ; Remove Additional signers
  1. N DA S DA=0
  1. F S DA=$O(^TIU(8925.7,"B",TIUDA,DA)) Q:+DA'>0 D
  1. . N DIK,DIDEL
  1. . I +$G(UNSIGN),(+$P(^TIU(8925.7,DA,0),U,4)>0) Q
  1. . S DIK="^TIU(8925.7,",DIDEL=8925.7 D ^DIK
  1. Q