Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: TIURTIT1

TIURTIT1.m

Go to the documentation of this file.
  1. TIURTIT1 ; SLC/JER - Review Documents by TITLE ;4/18/03
  1. ;;1.0;TEXT INTEGRATION UTILITIES;**100,113**;Jun 20, 1997
  1. ; New rtn, created 12/6/00 when splitting TIURTITL
  1. GATHER(TIUI,TIUPREF,CLASS,STATIFNS,EARLY,LATE,XREF) ; Find/sort records for the list
  1. N TIUT,TIUTP,TIUS,TIUSTAT,TIUSFLD,TIUJ,TIUIFN,TIUQ
  1. S TIUSFLD=$P(TIUPREF,U,3)
  1. S TIUSFLD=$S(TIUSFLD="P":".02",TIUSFLD="D":".01",TIUSFLD="S":".05",TIUSFLD="C":"1507",TIUSFLD="A":"1202",TIUSFLD="E":"1208",1:"1301")
  1. S TIUT=0 F S TIUT=$O(TYPES(TIUT)) Q:+TIUT'>0 D
  1. . S TIUTP=+$P($G(TYPES(TIUT)),U,2) Q:TIUTP'>0
  1. . S TIUS=1 F S TIUSTAT=$P(STATIFNS,";",TIUS) Q:'TIUSTAT D
  1. . . S TIUS=TIUS+1
  1. . . S TIUJ=LATE F S TIUJ=$O(^TIU(8925,XREF,TIUI,TIUTP,TIUSTAT,TIUJ)) Q:+TIUJ'>0!(+TIUJ>EARLY) D
  1. . . . S TIUIFN=0
  1. . . . F S TIUIFN=$O(^TIU(8925,XREF,TIUI,TIUTP,TIUSTAT,TIUJ,TIUIFN)) Q:+TIUIFN'>0 D
  1. . . . . ;Consider adding view check here
  1. . . . . I TIUTP=81,(+TYPES>1),($P(TYPES(TIUT),U,4)="NOT PICKED"),'+$$DADINTYP(TIUIFN,.TYPES) Q
  1. . . . . S TIUQ=$$RESOLVE^TIUR1(TIUIFN,TIUSFLD)
  1. . . . . S ^TMP("TIUI",$J,TIUQ,TIUJ,TIUIFN)=""
  1. Q
  1. DADINTYP(TIUDA,TYPES) ; Evaluates whether addendum's parent is among
  1. ; the selected types
  1. N TIUI,TIUDTYP,TIUY S (TIUI,TIUY)=0
  1. S TIUDTYP=+$G(^TIU(8925,+$P($G(^TIU(8925,+TIUDA,0)),U,6),0))
  1. F S TIUI=$O(TYPES(TIUI)) Q:+TIUI'>0!+TIUY D
  1. . I +$P(TYPES(TIUI),U,2)=TIUDTYP S TIUY=1
  1. Q TIUY
  1. PUTLIST(TIUPREF,TIUCLASS,STATUS,SCREEN) ; Adds list elements to LM Template
  1. ;array
  1. N TIUJ,TIUQ,TIUDA,TIUPICK,TIUORDER,TIUSFLD
  1. N TIUEXPKD,FORGETAD
  1. S VALMCNT=0
  1. S TIUSFLD=$P(TIUPREF,U,3)
  1. S TIUSFLD=$S(TIUSFLD="P":".02",TIUSFLD="D":".01",TIUSFLD="S":".05",TIUSFLD="C":"1507",TIUSFLD="A":"1202",TIUSFLD="E":"1208",1:"1301")
  1. S TIUORDER=$S($P(TIUPREF,U,4)="D":-1,1:1)
  1. S TIUPICK=+$O(^ORD(101,"B","TIU ACTION SELECT LIST ELEMENT",0))
  1. S TIUQ="" F S TIUQ=$O(^TMP("TIUI",$J,TIUQ)) Q:TIUQ']"" D
  1. . S TIUJ=0 F S TIUJ=$O(^TMP("TIUI",$J,TIUQ,TIUJ)) Q:+TIUJ'>0 D
  1. . . S TIUDA=0
  1. . . F S TIUDA=$O(^TMP("TIUI",$J,TIUQ,TIUJ,TIUDA)) Q:+TIUDA'>0 D
  1. . . . S FORGETAD=1
  1. . . . ; Replace ID kids/addenda in ^TMP("TIUI",$J) with
  1. . . . ;their parents. Don't expand parent for sake of addm:
  1. . . . D REPLACE^TIUR2(TIUDA,TIUQ,TIUSFLD,TIUJ,.TIUEXPKD,FORGETAD)
  1. D SETLIST(TIUORDER,.VALMCNT)
  1. S ^TMP("TIUR",$J,0)=+$G(VALMCNT)_U_STATUS("WORDS")
  1. S TIUJ=0,SCREEN="" F S TIUJ=$O(SCREEN(TIUJ)) Q:+TIUJ'>0 D
  1. . S SCREEN=$G(SCREEN)_$S(TIUJ>1:";",1:U)_SCREEN(TIUJ)
  1. S ^TMP("TIUR",$J,0)=^TMP("TIUR",$J,0)_$G(SCREEN)
  1. S ^TMP("TIUR",$J,"CLASS")=TIUCLASS
  1. S ^TMP("TIUR",$J,"#")=TIUPICK_"^1:"_+$G(VALMCNT)
  1. I $D(VALMHDR)>9 D HDR^TIURTITH
  1. I +$G(VALMCNT)'>0 D
  1. . S ^TMP("TIUR",$J,1,0)="",VALMCNT=2
  1. . S ^TMP("TIUR",$J,2,0)=" No records found to satisfy search criteria."
  1. ; -- Expand to show kids that fit:
  1. I '$G(TIURBLD),$D(TIUEXPKD) D EXPANDKD^TIUR2(.STATUS,.TIUEXPKD)
  1. Q
  1. ;
  1. SETLIST(TIUORDER,VALMCNT) ; Set items from ^TMP("TIUI",$J) into
  1. ;List Template list
  1. N TIUSVAL,TIUDTM,TIUDA
  1. S TIUSVAL=""
  1. F S TIUSVAL=$O(^TMP("TIUI",$J,TIUSVAL),TIUORDER) Q:TIUSVAL="" D
  1. . S TIUDTM=0
  1. . F S TIUDTM=$O(^TMP("TIUI",$J,TIUSVAL,TIUDTM)) Q:'TIUDTM D
  1. . . S TIUDA=0
  1. . . F S TIUDA=$O(^TMP("TIUI",$J,TIUSVAL,TIUDTM,TIUDA)) Q:'TIUDA D
  1. . . . D ADDELMNT(TIUDA,.VALMCNT)
  1. Q
  1. ;
  1. ADDELMNT(DA,TIUCNT,APPEND) ; Add each element to the list
  1. N PT,ADT,DDT,AUT,AMD,EDT,SDT,TIULST4
  1. N TIUREC,TIUD0,TIUD12,TIUD13,TIUD15,TIULI,STATX,DOC
  1. N PREFIX,TIUGDATA
  1. I '$D(^TIU(8925,DA,0)) Q
  1. I $G(^TMP("TIUR",$J,2,0))=" No records found to satisfy search criteria." D
  1. . K ^TMP("TIUR",$J,2),^TMP("TIUR",$J,"IDX",2),^TMP("TIUR",$J,"IDX",1) S TIUCNT=0
  1. S TIUD0=$G(^TIU(8925,+DA,0)),TIUD12=$G(^TIU(8925,+DA,12))
  1. S TIUD13=$G(^TIU(8925,+DA,13)),TIUD15=$G(^TIU(8925,+DA,15))
  1. S DOC=$$PNAME^TIULC1(+TIUD0)
  1. I DOC="Addendum" S DOC=DOC_" to "_$$PNAME^TIULC1(+$G(^TIU(8925,+$P(TIUD0,U,6),0)))
  1. S PREFIX=$$PREFIX^TIULA2(DA,0)
  1. S PT=$$NAME^TIULS($$PTNAME^TIULC1($P(TIUD0,U,2)),"LAST,FI MI")
  1. S TIULI=$E(PT)
  1. S PT=PREFIX_PT
  1. S TIULST4=$E($P($G(^DPT(+$P(TIUD0,U,2),0)),U,9),6,9)
  1. S TIULST4="("_TIULI_TIULST4_")"
  1. S ADT=$$DATE^TIULS($P(TIUD0,U,7),"MM/DD/YY")
  1. S DDT=$$DATE^TIULS($P(TIUD0,U,8),"MM/DD/YY")
  1. S AMD=$$PERSNAME^TIULC1($P(TIUD12,U,8)) S:AMD="UNKNOWN" AMD=""
  1. S AUT=$$PERSNAME^TIULC1($P(TIUD12,U,2)) S:AUT="UNKNOWN" AUT=""
  1. S AMD=$$NAME^TIULS(AMD,"LAST, FI MI")
  1. S AUT=$$NAME^TIULS(AUT,"LAST, FI MI")
  1. S EDT=$$DATE^TIULS($P(TIUD13,U),"MM/DD/YY")
  1. S SDT=$S(+$P(TIUD15,U,7):+$P(TIUD15,U,7),+$P(TIUD0,U,5)'<7:+$P(TIUD15,U),1:"")
  1. S SDT=$$DATE^TIULS(SDT,"MM/DD/YY")
  1. S STATX=$P($G(^TIU(8925.6,+$P(TIUD0,U,5),0)),U)
  1. S TIUCNT=+$G(TIUCNT)+1
  1. S TIUREC=$$SETFLD^VALM1(TIUCNT,"","NUMBER")
  1. S TIUREC=$$SETFLD^VALM1(PT,TIUREC,"PATIENT NAME")
  1. S TIUREC=$$SETFLD^VALM1(TIULST4,TIUREC,"LAST I/LAST 4")
  1. S TIUREC=$$SETFLD^VALM1(DOC,TIUREC,"DOCUMENT TYPE")
  1. S TIUREC=$$SETFLD^VALM1(EDT,TIUREC,"REF DATE")
  1. S TIUREC=$$SETFLD^VALM1($$LOWER^TIULS(STATX),TIUREC,"STATUS")
  1. S TIUREC=$$SETFLD^VALM1(SDT,TIUREC,"SIG DATE")
  1. S TIUREC=$$SETFLD^VALM1(AUT,TIUREC,"AUTHOR")
  1. S TIUREC=$$SETFLD^VALM1(AMD,TIUREC,"EXPECTED COSIGNER")
  1. S ^TMP("TIUR",$J,TIUCNT,0)=TIUREC
  1. S ^TMP("TIUR",$J,"IDX",TIUCNT,TIUCNT)="" W "."
  1. S ^TMP("TIURIDX",$J,TIUCNT)=TIUCNT_U_DA_U_PREFIX
  1. S ^TMP("TIUR",$J,"IEN",DA,TIUCNT)="" ;MARGY 11/11/00
  1. S TIUGDATA=$$IDDATA^TIURECL1(DA,TIUD0)
  1. I TIUGDATA S ^TMP("TIUR",$J,"IDDATA",DA)=TIUGDATA
  1. S VALMCNT=TIUCNT
  1. I +$G(APPEND) D
  1. . D RESTORE^VALM10(TIUCNT)
  1. . D CNTRL^VALM10(TIUCNT,1,$G(VALM("RM")),IOINHI,IOINORM),HDR^TIURTITH
  1. . S VALMSG="** Item #"_TIUCNT_" Added **"
  1. . S $P(^TMP("TIUR",$J,0),U)=TIUCNT
  1. . S $P(^TMP("TIUR",$J,"#"),":",2)=TIUCNT
  1. . S VALMCNT=TIUCNT
  1. . I $D(VALMHDR)>9 D HDR^TIURTITH
  1. Q