Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: VAFHLZCD

VAFHLZCD.m

Go to the documentation of this file. 
  1. VAFHLZCD ;ALB/KCL,Zoltan,JAN,TDM,TEJ,LMD - Create HL7 Catastrophic Disability (ZCD) segment ; 9/19/05 11:31am
  1.  ;;5.3;Registration;**122,232,387,653,894**;Aug 13, 1993;Build 48
  1.  ;
  1.  ;
  1.  ; This generic extrinsic function is designed to return the
  1.  ; HL7 Catastrophic Disability (ZCD) segment. This segment
  1.  ; contains VA-specific catastrophic disability information
  1.  ; for a patient.
  1.  ;
  1. EN(DFN,VAFSTR,VAFNUM,VAFHLQ,VAFHLFS) ; --
  1.  ; Entry point for creating HL7 Catastrophic Disability (ZCD) segment. 
  1.  ;     
  1.  ;  Input(s):
  1.  ;        DFN - internal entry number of Patient (#2) file
  1.  ;     VAFSTR - (optional) string of fields requested, separated by
  1.  ;              commas.  If not passed, return all data fields.
  1.  ;     VAFNUM - (optional) sequential number for SET ID (default=1)
  1.  ;     VAFHLQ - (optional) HL7 null variable
  1.  ;    VAFHLFS - (optional) HL7 field separator
  1.  ;
  1.  ;  Performance Note:
  1.  ;   VAFCDLST - Optional array (created by MAKELST subroutine below.)
  1.  ;              In cases involving multiple ZCD segments, performance
  1.  ;              is enhanced by calling MAKELST to create this array
  1.  ;              before invoking this function.  This may not apply
  1.  ;              in cases where BUILD is invoked to create multiple
  1.  ;              ZCD segments.  
  1.  ;
  1.  ;  Other optional input variables:
  1.  ;   HLQ      - HL7 default value to use when a sequence is empty.
  1.  ;   HLFS     - HL7 default primary delimiter (between sequences.)
  1.  ;
  1.  ; Output(s):
  1.  ;    String containing the desired components of the HL7 ZCD segment
  1.  ;
  1.  ; NOTE:
  1.  ;    In cases where multiple diagnoses, procedures, and/or conditions
  1.  ;    exist to support a status of CATASTROPHICALLY DISABLED, the
  1.  ;    MAKELST subroutine (see below) is invoked to serialize them
  1.  ;    (along with any related information) into separate ZCD
  1.  ;    segments.  This function will return the text of a single
  1.  ;    ZCD segment based on the segment number in VAFNUM.
  1.  ;
  1.  N VAFCAT,VAFY,X,SETID,VALOK,SUB
  1.  ;
  1.  ; if VAFHLQ or VAFHLFS not passed, use default HL7 variables
  1.  I $D(VAFHLQ)[0 S VAFHLQ=$G(HLQ)
  1.  I $G(VAFHLFS)="" S VAFHLFS=$G(HLFS,"^")
  1.  ;
  1.  ; if set id not passed, use default
  1.  S VAFNUM=$S($G(VAFNUM):VAFNUM,1:1)
  1.  ;
  1.  ; if DFN not passed, exit
  1.  I '$G(DFN) S VAFY=1 G ENQ
  1.  ;
  1.  ; get catastrophic disability info for a patient into VAFCAT
  1.  I '$$GET^DGENCDA(DFN,.VAFCAT) S VAFY=1 G ENQ
  1.  ; If sequence 13="Y" or "N", then sequences 2 through 6 are required.
  1.  ; If sequence 13="" then sequences 2 through 6 should not be sent.
  1.  S VALOK=1
  1.  I VAFCAT("VCD")'="" F SUB="REVDTE","BY","FACDET","DATE","METDET" I $G(VAFCAT(SUB))="" S VALOK=0
  1.  I 'VALOK F SUB="REVDTE","BY","FACDET","DATE","METDET","VCD" S VAFCAT(SUB)=""
  1.  ;
  1.  ; if VAFSTR not passed, return all data fields
  1.  I $G(VAFSTR)="" S VAFSTR="1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17"    ;DG*5.3*894
  1.  ;
  1.  ; initialize output string and requested data fields
  1.  S $P(VAFY,VAFHLFS,$L(VAFSTR,","))=""
  1.  S VAFSTR=","_VAFSTR_","
  1.  ;
  1.  ; Create a list to restrict multiple-valued fields to separate 
  1.  ; segments.  For example, if there are any DIAG, PROC and COND
  1.  ; entries, then no two of those values (or their associated sub-
  1.  ; fields) may occupy the same ZCD segment.  (See MAKELST below 
  1.  ; for implementation details.)
  1.  I '$D(VAFCDLST) N VAFCDLST D MAKELST(.VAFCDLST,.VAFCAT)
  1.  ;
  1.  ; set-up segment data fields
  1.  ; 1 - Set ID
  1.  S SETID=$S($G(VAFNUM):VAFNUM,1:1)
  1.  S $P(VAFY,VAFHLFS,1)=SETID
  1.  ; 2 - Review Date
  1.  I VAFSTR[",2," S $P(VAFY,VAFHLFS,2)=$S(VAFCAT("REVDTE")'="":$$HLDATE^HLFNC(VAFCAT("REVDTE")),1:VAFHLQ)
  1.  ; 3 - Decided By
  1.  I VAFSTR[",3," S $P(VAFY,VAFHLFS,3)=$S(VAFCAT("BY")'="":VAFCAT("BY"),1:VAFHLQ)
  1.  ; 4 - Facility Making Determination
  1.  I VAFSTR[",4," S X=$$STATION^VAFHLFNC(VAFCAT("FACDET")) S $P(VAFY,VAFHLFS,4)=$S(X'="":X,1:VAFHLQ)
  1.  ; 5 - Date of Decision
  1.  I VAFSTR[",5," S $P(VAFY,VAFHLFS,5)=$S(VAFCAT("DATE")'="":$$HLDATE^HLFNC(VAFCAT("DATE")),1:VAFHLQ)
  1.  ; 6 - Method of Determination
  1.  I VAFSTR[",6," S $P(VAFY,VAFHLFS,6)=$S(VAFCAT("METDET")'="":$$METH2HL7^DGENA5(VAFCAT("METDET")),1:VAFHLQ)
  1.  ; 17 - Catastrophic Disability Descriptor(s) - DG*5.3*894
  1.  K VANO S VANO=1 I VAFSTR[",17,",$D(VAFCAT("DESCR"))>0 S $P(VAFY,VAFHLFS,17)=$$DSCR2HL7^DGENA5(DFN) S:$P(VAFY,VAFHLFS,17)]"" VANO=0
  1.  ; 7 - Diagnosis (multiple), DG*5.3*894
  1.  I VANO,VAFSTR[",7," S $P(VAFY,VAFHLFS,7)=$S($G(VAFCDLST(SETID,"DIAG"))'="":$$RSNTOHL7^DGENA5(VAFCDLST(SETID,"DIAG")),1:VAFHLQ)
  1.  ; 8 - Procedure (multiple), DG*5.3*894
  1.  I VANO,VAFSTR[",8," S $P(VAFY,VAFHLFS,8)=$S($G(VAFCDLST(SETID,"PROC"))'="":$$RSNTOHL7^DGENA5(VAFCDLST(SETID,"PROC")),1:VAFHLQ)
  1.  ; 9 - Affected Extremity (Procedure sub-field)
  1.  I VAFSTR[",9," S $P(VAFY,VAFHLFS,9)=$S($G(VAFCDLST(SETID,"EXT"))'="":$$LIMBTOHL^DGENA5(VAFCDLST(SETID,"EXT")),1:VAFHLQ)
  1.  ; 10 - Condition (multiple), DG*5.3*894
  1.  I VANO,VAFSTR[",10," S $P(VAFY,VAFHLFS,10)=$S($G(VAFCDLST(SETID,"COND"))'="":$$RSNTOHL7^DGENA5(VAFCDLST(SETID,"COND")),1:VAFHLQ)
  1.  ; 11 - Score (Condition sub-field)
  1.  I VAFSTR[",11," S $P(VAFY,VAFHLFS,11)=$S($G(VAFCDLST(SETID,"SCORE"))'="":VAFCDLST(SETID,"SCORE"),1:VAFHLQ)
  1.  ; 12 - Veteran Catastrophically Disabled?
  1.  I VAFSTR[",12," S $P(VAFY,VAFHLFS,12)=$S(VAFCAT("VCD")'="":VAFCAT("VCD"),1:VAFHLQ)
  1.  ; 13 - Permanent Indicator (Condition sub-field)
  1.  I VAFSTR[",13," S $P(VAFY,VAFHLFS,13)=$S($G(VAFCDLST(SETID,"PERM"))'="":$$PERMTOHL^DGENA5(VAFCDLST(SETID,"PERM")),1:VAFHLQ)
  1.  ; 14 - Date Veteran Requested CD Evaluation
  1.  I VAFSTR[",14," S $P(VAFY,VAFHLFS,14)=$S(VAFCAT("VETREQDT")'="":$$HLDATE^HLFNC(VAFCAT("VETREQDT")),1:VAFHLQ)
  1.  ; 15 - Date Facility Initiated Review
  1.  I VAFSTR[",15," S $P(VAFY,VAFHLFS,15)=$S(VAFCAT("DTFACIRV")'="":$$HLDATE^HLFNC(VAFCAT("DTFACIRV")),1:VAFHLQ)
  1.  ; 16 - Date Veteran Was Notified
  1.  I VAFSTR[",16," S $P(VAFY,VAFHLFS,16)=$S(VAFCAT("DTVETNOT")'="":$$HLDATE^HLFNC(VAFCAT("DTVETNOT")),1:VAFHLQ)
  1.  ;  
  1.  S:$E(VAFSTR,1)="," VAFSTR=$E(VAFSTR,2,$L(VAFSTR))
  1.  S:$E(VAFSTR,$L(VAFSTR))="," VAFSTR=$E(VAFSTR,1,$L(VAFSTR)-1)
  1. ENQ Q "ZCD"_VAFHLFS_$G(VAFY)
  1.  ;
  1.  ; Subroutines follow...
  1. MAKELST(VAFCDLST,VAFCAT) ; Make list of ZCD Segments.
  1.  ; Inputs:
  1.  ;  VAFCDLST - By reference (used to hold output array.)
  1.  ;  VAFCAT   - By reference, an array containing the patient's CD
  1.  ;             data (as created in $$GET^DGENCDA).
  1.  ; Output:
  1.  ;  VAFCDLST(Segment#,"DIAG") = CD Diagnosis (pointer to #27.17).
  1.  ;  VAFCDLST(Segment#,"PROC")= CD Procedure(pointer to #27.17).
  1.  ;  VAFCDLST(Segment#,"EXT") = Affected Extremity (for procedure).
  1.  ;  VAFCDLST(Segment#,"COND")= CD Condition (pointer to #27.17).
  1.  ;  VAFCDLST(Segment#,"PERM") = Permanent Indicator (for condition).
  1.  ;  VAFCDLST(Segment#,"SCORE") = Test Score (for condition).
  1.  ;  VAFCDLST(Segment#,"DESCR") = CD Descriptor(for VCD="yes")         * DG*5.3*894
  1.  ;
  1.  ; Per Enrollment Phase II SRS (Section 4.2.4) no ZCD segment should
  1.  ; contain more than one CD Reason (Diagnosis, Procedure, Condition.)
  1.  ; So this procedure adds each one as a separate ZCD segment.
  1.  ;
  1.  N ITEM,SITEM,STR
  1.  K VAFCDLST
  1.  S VAFCDLST=0
  1.  S (ITEM,SITEM)=""
  1.  ; Add each Diagnosis as a separate ZCD segment.
  1.  F  S ITEM=$O(VAFCAT("DIAG",ITEM)) Q:ITEM=""  D
  1.  . D ADDNEW(.VAFCDLST,"DIAG",VAFCAT("DIAG",ITEM))
  1.  ; Add each Procedure as a separate ZCD segment.
  1.  F  S ITEM=$O(VAFCAT("PROC",ITEM)) Q:ITEM=""  D
  1.  . F  S SITEM=$O(VAFCAT("EXT",ITEM,SITEM)) Q:SITEM=""  D
  1.  .. D ADDNEW(.VAFCDLST,"PROC",VAFCAT("PROC",ITEM))
  1.  .. D INSERT(.VAFCDLST,"EXT",VAFCAT("EXT",ITEM,SITEM))
  1.  ; Add each Condition as a separate ZCD segment.
  1.  F  S ITEM=$O(VAFCAT("COND",ITEM)) Q:ITEM=""  D
  1.  . D ADDNEW(.VAFCDLST,"COND",VAFCAT("COND",ITEM))
  1.  . D INSERT(.VAFCDLST,"SCORE",VAFCAT("SCORE",ITEM))
  1.  . D INSERT(.VAFCDLST,"PERM",VAFCAT("PERM",ITEM))
  1.  I VAFCDLST=0 S VAFCDLST=1 ; At least one ZCD segment.
  1.  Q
  1. ADDNEW(LIST,NAME,ITEM) ; Add an item to the list (internal use only).
  1.  ; Inputs:
  1.  ;   LIST - By reference, a list of items.
  1.  ;   NAME - Name of one item to add.
  1.  ;   ITEM - Value of item to add.
  1.  ; Note: a new position is created in the list.
  1.  S LIST=LIST+1
  1.  S LIST(LIST,NAME)=ITEM
  1.  Q
  1. INSERT(LIST,NAME,ITEM) ; Insert item into existing list position (internal).
  1.  ;  LIST - By reference, a list of items.
  1.  ;  NAME - Name of one item to add.
  1.  ;  ITEM - Value of item to add.
  1.  ; Note: the list should already contain at least one item.
  1.  S LIST(LIST,NAME)=ITEM
  1.  Q
  1. BUILD(VAFSEGS,DFN,VAFSTR,VAFHLQ,VAFHLFS) ;
  1.  ; Entry point for creating HL7 Catastrophic Disability (ZCD) segments.
  1.  ; This is the preferred entry point for building ZCD segments.
  1.  ;     
  1.  ;  Input(s):
  1.  ;    VAFSEGS - Pass-by-reference array to contain all ZCD segments
  1.  ;              for this patient.
  1.  ;        DFN - internal entry number of Patient (#2) file
  1.  ;     VAFSTR - (optional) string of fields requested, separated by
  1.  ;              commas.  If not passed, return all data fields.
  1.  ;     VAFHLQ - (optional) HL7 null variable
  1.  ;    VAFHLFS - (optional) HL7 field separator
  1.  ;
  1.  ;  Output:
  1.  ;    VAFSEGS - By reference, an array containing all ZCD segments.
  1.  ;      Format:  VAFSEGS = Number of ZCD Segments
  1.  ;               VAFSEGS(1) = First ZCD Segment
  1.  ;               VAFSEGS(2) = Second ZCD Segment (if any)...
  1.  ;               etc.
  1.  ;
  1.  ; NOTE:
  1.  ;    Per Enrollment Phase II SRS (Section 4.2.4) no ZCD segment should
  1.  ;    contain more than one CD Reason (Diagnosis, Procedure, Condition.)
  1.  ;    As a result, multiple ZCD segments will be created if more than
  1.  ;    one of these fields has a value.  The MAKELST procedure contains
  1.  ;    logic to enforce this requirement.
  1.  ;
  1.  N VAFCDLST ; Temporary array of CD REASON info.
  1.  K VAFSEGS S VAFSEGS=0 ; Initialize array.
  1.  ; DFN is required.
  1.  I '$G(DFN) Q
  1.  ; get catastrophic disability info for a patient into VAFCAT
  1.  I '$$GET^DGENCDA(DFN,.VAFCAT) Q
  1.  ; Create a list VAFCDLST to enforce one CD REASON per segment.
  1.  D MAKELST(.VAFCDLST,.VAFCAT)
  1.  I 'VAFCDLST Q
  1.  ; Create an array of HL7 segments.
  1.  F VAFSEGS=1:1:VAFCDLST S VAFSEGS(VAFSEGS)=$$EN(DFN,.VAFSTR,VAFSEGS,.VAFHLQ,.VAFHLFS)
  1.  Q