Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: VBECDC01

VBECDC01.m

Go to the documentation of this file. 
  1. VBECDC01 ;hoifo/gjc-data conversion & pre-implementation;Nov 21, 2002
  1.  ;;2.0;VBEC;;Jun 05, 2015;Build 4
  1.  ;
  1.  ;Medical Device #:
  1.  ;Note: The food and Drug Administration classifies this software as a
  1.  ;medical device.  As such, it may not be changed in any way.
  1.  ;Modifications to this software may result in an adulterated medical
  1.  ;device under 21CFR820, the use of which is considered to be a
  1.  ;violation of US Federal Statutes.  Acquiring and implementing this
  1.  ;software through the Freedom of Information Act requires the
  1.  ;implementer to assume total responsibility for the software, and
  1.  ;become a registered manufacturer of a medical device, subject to FDA
  1.  ;regulations.
  1.  ;
  1.  ;Call to $$NEWERR^%ZTER is supported by IA: 1621
  1.  ;Call to $$GOTLOCAL^XMXAPIG is supported by IA: 3006
  1.  ;Call to $$GET1^DIQ is supported by IA: 2056
  1.  ;Call to $$FMTE^XLFDT is supported by IA: 10103
  1.  ;Call to $$NOW^XLFDT is supported by IA: 10103
  1.  ;
  1. EN(VBECCNV) ; entry point for both the pre-implementation and data
  1.  ; conversion.
  1.  ; Input: if VBECCNV evaluates to one, then the software
  1.  ;        executes data conversion logic.  If VBECCNV evaluates
  1.  ;        to zero, then the pre-implementation logic is executed.
  1.  ;
  1.  I $S($D(DUZ)[0:1,$D(DUZ(0))[0:1,'DUZ:1,DUZ=.5:1,1:0) W !!?3,$C(7),"DUZ & DUZ(0) must be defined to an active user (not POSTMASTER) in order to",!?3,"proceed." Q
  1.  ;
  1.  ; initialize error trap
  1.  I $$NEWERR^%ZTER N $ETRAP,$ESTACK S $ETRAP="D ERR^VBECDCU1"
  1.  E  S X="D ERR^VBECDCU1",@^%ZOSF("TRAP")
  1.  ;
  1.  ;If the data conversion process is selected to run, check the following
  1.  ;conditions:
  1.  ;
  1.  ; a) If none of the VistA data been mapped prior to the data conversion
  1.  ;    convey that information to the user and exit the data conversion
  1.  ; b) check if mapped data remains consistent with data from the parent
  1.  ;    (61.3 & 65.4) files.  If not, do not proceed with the
  1.  ;    conversion
  1.  ; c) check if the exported mail group has active local members (users
  1.  ;    checked for activity within the last seven days)
  1.  ; d) is there a process running that has not yet finished? If so, do
  1.  ;    not allow another process to start (data conv. or anomaly check)
  1.  ;
  1.  I VBECCNV,$$NOMAP^VBECDCU2() Q  ;condition a
  1.  I VBECCNV,$$EN^VBECDCHX() D  Q  ;condition b
  1.  .W !!?3,"Mapping errors were identified; data conversion terminated."
  1.  .Q
  1.  I '$$GOTLOCAL^XMXAPIG("VBECS DATA CONVERSION",7) D  Q  ;condition c
  1.  .W !!?3,"There must be at least one local user assigned to the VBECS"
  1.  .W !?3,"DATA CONVERSION Mail Group.  This user must have been actively"
  1.  .W !?3,"using VistA MailMan within the last seven (7) days.",$C(7)
  1.  .Q
  1.  ;
  1.  I +$O(^VBEC(6001,0)) S VBECST=$$INPROC()
  1.  I $L($G(VBECST)) D  K VBECST Q
  1.  .W !!,"The "_$S($P(VBECST,U,2)=1:"data conversion",1:"pre-implementation")_" has been started on: "_$$FMTE^XLFDT($P(VBECST,U,3),"1P")
  1.  .W !,"by: "_$$GET1^DIQ(200,+$P(VBECST,U),.01)_". This process must first complete"
  1.  .W !,"before the "_$S(VBECCNV=1:"data conversion",1:"pre-implementation")_" can be run."
  1.  .Q
  1.  I VBECCNV D  I $D(VBECSTP) K VBECSTP Q  ;Only ask for database on conversion
  1.   . W !!?3,"You must enter the name of the database "
  1.   . W !?3,"where the converted data will be loaded."
  1.   . W !!?3,"An invalid database name will cause a failure"
  1.   . W !?3,"when loading the data into VBECS."
  1.   . F  D  I $D(VBECSTP)!(VBECDBN]"") Q
  1.   . . W !!!,?3 R "VBECS Database Name: ",VBECDBN  I VBECDBN=""!(VBECDBN["^") S VBECDBN="^",VBECSTP="" W !!?3,"Invalid database name. Conversion stopped." Q
  1.   . . I VBECDBN?.E1C.E W !?4,"The database name cannot contain control characters.",!?4,"Please re-enter it." S VBECDBN=""
  1.   . . I VBECDBN?1N.E W !?4,"The database name cannot begin with a number.",!?4,"Please re-enter it." S VBECDBN=""
  1.   . . I $TR(VBECDBN,"_","")?.E1P.E W !?4,"The database name cannot contain punctuation except for an underscore.",!?4,"Please re-enter it." S VBECDBN=""
  1.  ;
  1.  I VBECCNV D  I $D(VBECSTP) K VBECSTP Q  ;Only ask for server on conversion
  1.   . W !!?3,"You must enter the name of the server "
  1.   . W !?3,"where the converted data will be loaded."
  1.   . W !!?3,"An invalid server name will cause a failure"
  1.   . W !?3,"when loading the data into VBECS."
  1.   . F  D  I $D(VBECSTP)!(VBECDBN1]"") Q
  1.   . . W !!!,?3 R "VBECS Server Name: ",VBECDBN1  I VBECDBN1=""!(VBECDBN1["^") S VBECDBN1="^",VBECSTP="" W !!?3,"Invalid server name. Conversion stopped." Q
  1.   . . I VBECDBN1?.E1C.E W !?4,"The server name cannot contain control characters.",!?4,"Please re-enter it." S VBECDBN1=""
  1.   . . I VBECDBN1?1N.E W !?4,"The server name cannot begin with a number.",!?4,"Please re-enter it." S VBECDBN1=""
  1.   . . I $TR(VBECDBN1,"_-","")?.E1P.E W !?4,"The server name cannot contain punctuation except for an underscore (_) or dash (-).",!?4,"Please re-enter it." S VBECDBN1=""
  1.  ;
  1.  K VBECST W @IOF ;clear screen of past dialogue
  1.  S (VBECDESC,ZTDESC)="VBECS "_$S(VBECCNV=1:"data conversion",1:"pre-implementation")
  1.  W !?3,"The "_ZTDESC_" process will take some time to complete.",!?3,"It would be best if this process was run in the background.",!
  1.  ;
  1.  ; file the start time, process type, & user information into file 6001
  1.  S VBECIEN=$$UP6001S^VBECDC02(+$E($$NOW^XLFDT(),1,12),VBECCNV,DUZ)
  1.  I VBECIEN'>0 D  Q
  1.  .W !!?3,"Error filing "_ZTDESC_" statistics.",$C(7) K ZTDESC,VBECIEN
  1.  .Q
  1.  ; kick off the task, queued or real-time
  1.  S ZTRTN="START^VBECDC00",ZTSAVE("DUZ")="",ZTSAVE("VBECCNV")="",ZTSAVE("VBECDBN")="",ZTSAVE("VBECDBN1")=""
  1.  S ZTSAVE("VBECIEN")="",ZTIO="" D ^%ZTLOAD
  1.  ; display task number for user reference
  1.  I +$G(ZTSK) W !!,VBECDESC_" task number: "_ZTSK,!
  1.  E  D UP6001P^VBECDC02(VBECIEN) ;user exits prematurely
  1.  K VBEC,VBECDESC,VBECIEN,ZTDESC,ZTIO,ZTRTN,ZTSAVE,ZTSK
  1.  Q
  1.  ;
  1. STOPPED ; entry point executed when the user stops a task with TaskMan
  1.  ; if the user stopped the process:
  1.  ; 1-DATA CONVERSION ONLY delete all data in all related ^TMP globals
  1.  ; 2-DATA CONVERSION ONLY set options back 'in-order'
  1.  ; 3-alert the user to the stoppage
  1.  ; 4-delete the record from the VBECS DATA
  1.  ; INTEGRITY/CONVERSION STATISTICS (#6001) file.
  1.  ;
  1.  ; Variables used within this function:
  1.  ;  VBECCNV-indicates if the data conversion (1) or data anomalies check
  1.  ;          (0) is running
  1.  ;      DUZ-the internal entry number of the person resposible for this
  1.  ;          task
  1.  ;  VBECIEN-is the IEN of the record in the VBECS DATA
  1.  ;          INTEGRITY/CONVERSION STATISTICS (#6001) file
  1.  ; VBECANOM-flag to indicate if anomalies exist (zero if no anomalies,
  1.  ;          some number greater than zero if anomalies exist.)
  1.  ;
  1.  I VBECCNV D
  1.  .D DELTMP($J) ;delete data in temporary globals ^TMP(,$J
  1.  .D EN^VBECDC19(0) ;set options back in order, clear write nodes
  1.  .Q
  1.  ;next line performed for the anomaly check & data conversion
  1.  D ALERT^VBECDCU(DUZ,VBECCNV,VBECANOM,"S"),UP6001P^VBECDC02(VBECIEN)
  1.  Q
  1.  ;
  1. INPROC() ;is there a current data conversion or anomaly process on
  1.  ;file that has not completed? If so, prevent this current request
  1.  ;from starting (collision errors)
  1.  N VBECI,VBEC0,VBECSTOP,VBECX
  1.  S VBECI=$C(32),VBECSTOP=0,VBECX=""
  1.  F  S VBECI=$O(^VBEC(6001,VBECI),-1) Q:'VBECI  D  Q:VBECSTOP
  1.  .S VBEC0=$G(^VBEC(6001,VBECI,0))
  1.  .I $P(VBEC0,U,3)="" S VBECX=$P(VBEC0,U,4)_U_$P(VBEC0,U,2)_U_$P(VBEC0,U)
  1.  .I  S VBECSTOP=1
  1.  .Q
  1.  Q VBECX
  1.  ;
  1. DELTMP(DOLLARJ) ;Delete all Blood Bank Data in Temporary Globals
  1.  ;
  1.  N X S X="VBEC FINI"
  1.  F  S VBECX=$O(^TMP(VBECX)) Q:VBECX=""!(VBECX]"VBEC63 zzz")  D
  1.  .K ^TMP(VBECX,DOLLARJ)
  1.  .Q
  1.  Q
  1.  ;