Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: VPSMRAR7

VPSMRAR7.m

Go to the documentation of this file. 
  1. VPSMRAR7  ;DALOI/KML,WOIFO/BT - Cont. Update of VPS MRAR PDO file ;1/15/15 15:30
  1.  ;;1.0;VA POINT OF SERVICE (KIOSKS);**3**;Jan 15, 2015;Build 64
  1.  ;;Per VHA Directive 2004-038, this routine should not be modified.
  1.  ;
  1.  Q
  1.  ;
  1. SUB57(PTIEN,DTIEN,FLD,DIEFLAG,DATA,REQFLDS) ; file the ALLERGY REACTIONS multiple (853.57)
  1.  ; INPUTS
  1.  ;   PTIEN   : Patient DFN for 853.5 entry
  1.  ;   DTIEN   : transaction date/time ien for 853.51 sub-entry
  1.  ;   FLD     : Field # where the data will be filed
  1.  ;   DIEFLAG : Filing Type (I = Internal, E = External)
  1.  ;   DATA    : composite string assigned to a subscript in the local array passed in by Vecna for the specific field
  1.  ;   REQFLDS : Array of required fields by fieldname and entry number
  1.  ; OUTPUT
  1.  ;   success : RESULT = Field Name^IENS^Field Value^1
  1.  ;   failed  : RESULT = Field Name^IENS^Field Value^99^error text describing why data did not get filed
  1.  ;
  1.  N RESULT S RESULT=""
  1.  ;
  1.  ; -- Check required Allergy fields
  1.  S RESULT=$$CHKALR^VPSMRAR2(.REQFLDS,DATA)
  1.  Q:RESULT'="" RESULT
  1.  ;
  1.  ; -- Check required Allergy Reaction fields
  1.  S RESULT=$$CHKREACT(.REQFLDS,DATA)
  1.  Q:RESULT'="" RESULT
  1.  ;
  1.  ; -- retrieve the allergy ien
  1.  N ALLERID S ALLERID=$P($P(DATA,U,2),",",2)
  1.  N AIEN S AIEN=$O(^VPS(853.5,PTIEN,"MRAR",DTIEN,"ALLERGY","B",ALLERID,""))
  1.  Q:AIEN="" $$RESULT^VPSMRAR0(DATA,99,"Data was not filed into MRAR PDO")
  1.  ;
  1.  ; -- Add Allergy Reactions sub entry if it doesn't exist
  1.  N REACTID S REACTID=$P($P(DATA,U,2),",",3)
  1.  ;I $P(DATA,U,3)'=REACTID S RESULT=$$RESULT^VPSMRAR0(DATA,99,"Value does not match third index")
  1.  ;Q:RESULT'="" RESULT
  1.  I '$D(^VPS(853.5,PTIEN,"MRAR",DTIEN,"ALLERGY",AIEN,"REACTIONS","B",REACTID)) D  ; REACTIONS sub-entry not yet created for this allergy
  1.  . N ADDOK S ADDOK=$$ADDMRAR^VPSMRAR0(853.57,AIEN_","_DTIEN_","_PTIEN,REACTID,DIEFLAG)
  1.  . I 'ADDOK S RESULT=$$RESULT^VPSMRAR0(DATA,99,"Data was not filed into MRAR PDO. Failed to add Allergy Reactions entry")
  1.  Q:RESULT'="" RESULT
  1.  ;
  1.  ; -- Get Allergy Reactions IEN
  1.  N REACTIEN S REACTIEN=$O(^VPS(853.5,PTIEN,"MRAR",DTIEN,"ALLERGY",AIEN,"REACTIONS","B",REACTID,""))
  1.  Q:REACTIEN="" $$RESULT^VPSMRAR0(DATA,99,"Data was not filed into MRAR PDO")
  1.  ;
  1.  ; -- Store 853.57 field entries
  1.  N IENS S IENS=REACTIEN_","_AIEN_","_DTIEN_","_PTIEN_","
  1.  S RESULT=$$FILE^VPSMRAR0(853.57,0,IENS,FLD,DIEFLAG,DATA)
  1.  ;
  1.  Q RESULT
  1.  ;
  1. CHKREACT(REQFLDS,DATA) ;Check required Allergy Reaction fields
  1.  ; INPUTS 
  1.  ;   REQFLDS : Array of required fields by fieldname and entry number
  1.  ;   DATA    : Field Name^IENS^Field Value
  1.  ; 
  1.  ; OUTPUT
  1.  ;   success : RESULT = Field Name^IENS^Field Value^1
  1.  ;   failed  : RESULT = Field Name^IENS^Field Value^99^error text describing why data did not get filed
  1.  ;
  1.  N RESULT S RESULT=""
  1.  ; -- Allergy Reaction Entry # is required field
  1.  N ALLERID S ALLERID=$P($P(DATA,U,2),",",2)
  1.  N REACTID S REACTID=$P($P(DATA,U,2),",",3)
  1.  I 'REACTID S RESULT=$$RESULT^VPSMRAR0(DATA,99,"Allergy Reaction Entry # is required")
  1.  Q:RESULT'="" RESULT
  1.  ; 
  1.  ; -- For Local VistA, Local Reaction ID is required
  1.  ; -- For Remote (CDW), Remote Reaction ID and Remote Reaction Name are required
  1.  N ISLOCAL S ISLOCAL=$D(REQFLDS("LOCAL REACTION ID",ALLERID,REACTID))
  1.  N ISREMOTE S ISREMOTE=$D(REQFLDS("REMOTE REACTION ID",ALLERID,REACTID))&$D(REQFLDS("REMOTE REACTION NAME",ALLERID,REACTID))
  1.  I 'ISLOCAL&'ISREMOTE S RESULT=$$RESULT^VPSMRAR0(DATA,99,"Local Reaction ID or Remote Reaction ID and Remote Reaction Name are required")
  1.  Q RESULT