Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: VPSRPC15

VPSRPC15.m

Go to the documentation of this file. 
  1. VPSRPC15  ;BPOIFO/KG - Patient Problems;07/31/14 13:07
  1.  ;;1.0;VA POINT OF SERVICE (KIOSKS);**4,14**;Jul 31, 2014;Build 26
  1.  ;;Per VHA Directive 2004-038, this routine should not be modified.
  1.  ;
  1.  ; External Reference DBIA#
  1.  ; ------------------------
  1.  ; #2741 - DETAIL^GMPLUTL2   (Controlled Sub)
  1.  ; #2741 - LIST^GMPLUTL2     (Controlled Sub)
  1.  ; #2977 - GETFLDS^GMPLEDT3  (Controlled Sub)
  1.  QUIT
  1.  ;
  1. GETPRBLM(VPSARR,DFN) ;given DFN, returns the patient problems
  1.  N ICDIEN,PRBIEN,PRBIENS,PRBINFO,GMPL
  1.  ;
  1.  ;--- Load a list of active problems
  1.  N PLST D LIST^GMPLUTL2(.PLST,DFN,"A",0) ; Returns list of Prob for Pt.
  1.  ;
  1.  ;--- Browse through the problems
  1.  N CNT S CNT=0
  1.  N FILE S FILE=9000011
  1.  N EXIST S EXIST=0
  1.  ;
  1.  F  S CNT=$O(PLST(CNT)) Q:CNT=""  D
  1.  . S PRBIEN=$P(PLST(CNT),U)
  1.  . Q:PRBIEN'>0
  1.  . S EXIST=1
  1.  . K GMPL D DETAIL^GMPLUTL2(PRBIEN,.GMPL)
  1.  . D SET(.VPSARR,FILE,DFN_";"_PRBIEN,.01,$G(GMPL("DIAGNOSIS")),"DIAGNOSIS")
  1.  . D SET(.VPSARR,FILE,DFN_";"_PRBIEN,.03,$G(GMPL("MODIFIED")),"DATE LAST MODIFIED")
  1.  . D SET(.VPSARR,FILE,DFN_";"_PRBIEN,.05,$G(GMPL("NARRATIVE")),"PROVIDER NARRATIVE")
  1.  . D SET(.VPSARR,FILE,DFN_";"_PRBIEN,.06,$P($G(GMPL("FACILITY")),U,2),"FACILITY")
  1.  . D SET(.VPSARR,FILE,DFN_";"_PRBIEN,.08,$P($G(GMPL("ENTERED")),U),"DATE ENTERED")
  1.  . D SET(.VPSARR,FILE,DFN_";"_PRBIEN,.12,$G(GMPL("STATUS")),"STATUS")
  1.  . D SET(.VPSARR,FILE,DFN_";"_PRBIEN,1.02,$G(GMPL("CONDITION")),"CONDITION")
  1.  . D SET(.VPSARR,FILE,DFN_";"_PRBIEN,1.03,$P($G(GMPL("ENTERED")),U,2),"ENTERED BY")
  1.  . D SET(.VPSARR,FILE,DFN_";"_PRBIEN,1.04,$P($G(GMPL("RECORDED")),U,2),"RECORDING PROVIDER")
  1.  . D SET(.VPSARR,FILE,DFN_";"_PRBIEN,1.05,$G(GMPL("PROVIDER")),"RESPONSIBLE PROVIDER")
  1.  . D SETEXP(.VPSARR,FILE,DFN,PRBIEN) ;set expression
  1.  ;
  1.  I 'EXIST D SET(.VPSARR,"E",DFN,"","NO PROBLEM RECORDS FOUND FOR PATIENT","PROBLEM NOT FOUND")
  1.  QUIT
  1.  ;
  1. SETEXP(VPSARR,FILE,DFN,PRBIEN) ;set expression
  1.  N GMPVAMC S GMPVAMC=0
  1.  N GMPROV S GMPROV=0
  1.  N GMPORIG,GMPFLD
  1.  D GETFLDS^GMPLEDT3(PRBIEN)
  1.  D SET(.VPSARR,FILE,DFN_";"_PRBIEN,1.01,$P($G(GMPFLD(1.01)),U,2),"EXPRESSIONS")
  1.  QUIT
  1.  ;
  1. SET(VPSARR,VPSFL,VPSIEN,VPSFLD,VPSDA,VPSDS) ;Set line item to output array
  1.  I VPSDA'="" D SET^VPSRPC1(.VPSARR,VPSFL,VPSIEN,VPSFLD,VPSDA,$G(VPSDS),5) ;Set line item to output array
  1.  QUIT
  1.  ;
  1. GETHF(VPSARR,DFN) ;given DFN, returns the patient health factors
  1.  N IEN,DAT
  1.  S IEN=""
  1.  ; Look up health factors for the patient
  1.  F  S IEN=$O(^AUPNVHF("C",DFN,IEN)) Q:'IEN  D
  1.  . S DAT=$$GET1^DIQ(9000010.23,IEN_",",.01) ; retrieve the patient's health factor
  1.  . D SET^VPSRPC1(.VPSARR,9000010.23,DFN_";"_IEN,.01,DAT,"HEALTH FACTOR",9)
  1.  QUIT
  1.  ;
  1. GETADEM(VPSARR,DFN) ;given DFN, returns the patient demographics, insurance, and up-coming appointments.
  1.  ; OUTPUT
  1.  ;   VPSARR - passed in by reference; this is the output array to store patient demographics
  1.  ; INPUT
  1.  ;   DFN    - patient DFN (This value must be validated before calling this procedure)
  1.  ;
  1.  D ENR^VPSRPC16(.VPSARR,DFN) ; Store Patient Enrollment
  1.  D OTH^VPSRPC26(.VPSARR,DFN) ; Store Other information not in KNOWN API
  1.  D POW^VPSRPC26(.VPSARR,DFN) ; Store POW
  1.  D PH^VPSRPC26(.VPSARR,DFN) ; Store Purple Heart
  1.  D MP^VPSRPC26(.VPSARR,DFN) ; Store Missing Person
  1.  D SVC^VPSRPC26(.VPSARR,DFN) ; Store Service Connected and Rated Disabilities
  1.  D CHG^VPSRPC26(.VPSARR,DFN) ; Store Change DT/TM
  1.  D BLPAT^VPSRPC26(.VPSARR,DFN) ; Store Billing Patient
  1.  D PCT^VPSRPC26(.VPSARR,DFN) ; Primary Care Team
  1.  Q