Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: WIIGATD

WIIGATD.m

Go to the documentation of this file. 
  1. WIIGATD ;VISN20/WDE/WHN WII-EXTRACT DATA ; [6/26/08 07:21am]
  1.  ;;1.0;Wounded Injured and Ill Warriors;**1**;06/26/2008;Build 28;
  1.  ;API used see Appendix A Message Server Protocol
  1.  ;http://www.domain.ext/vdl/documents/Infrastructure/Mailman/xm_8_0_developerguide.pdf
  1.  ; INTEGRATION REFERENCE #3041  All fields can be accessed/edited using FileMan tools.
  1.  ;      ACCESS TO FILE 20 NAME COMPONENTS     VA(20
  1.  ;Once the data is approved at the local facility this routine is called from the exit action of option
  1.  ;WII REVIEW ADT EVENTS.  The function is to send the data off to the single collection point.
  1.  ;
  1.  ;Data is sent to the server that is entered in file WII PARAMETERS (#987.6) field 1.
  1.  ;  The otion to review the data is the series of WIILM* routines. 
  1. EN ;Entry Point
  1.  D CLEAN
  1.  S (WIICNT,WIIENT)=0 F  S WIIENT=$O(^WII(987.5,"C",2,WIIENT)) Q:(WIIENT="")!('+WIIENT)  D
  1.  . D BUILD
  1.  . Q
  1.  I $D(^TMP($J))>0 D XMB
  1.  D CLEAN
  1.  Q
  1. BUILD ;
  1.  S WIIDATA=$G(^WII(987.5,WIIENT,0)) Q:WIIDATA=""
  1.  S WIIP2=$P(WIIDATA,U,2)  ;PATIENT
  1.  S WIIP3=$P(WIIDATA,U,3)  ;SSN
  1.  S WIIP5=$P(WIIDATA,U,5)  ;FACILITY
  1.  S WIIP6=$P(WIIDATA,U,6)  ;ADMISSION DATE
  1.  S WIIP7=$P(WIIDATA,U,7)  ;DISCHARGE DATE
  1.  S WIIP8=$P(WIIDATA,U,8)  ;ICN
  1.  S WIIP10=$P(WIIDATA,U,10)  ;DATE COLLECTED AT THE FACILITY
  1.  S WIIDATA=$G(^WII(987.5,WIIENT,1))  ;SUBSCRIPT 1
  1.  S WIIP11=$P(WIIDATA,U,1)  ;PATIENTS ZIP CODE
  1.  S WIIP12=$P(WIIDATA,U,2)  ;DATE OF BIRTH
  1.  S WIIP13=$P(WIIDATA,U,3)  ;GENDER
  1.  S WIIP14=$P(WIIDATA,U,4)  ;QUALIFYING ELIGIBILITY
  1.  S WIIP15=DT  ;DATE GOING TO THE REPOSITORY
  1.  S WIIDFN=$P($G(WIIDATA),U,6)
  1.  ;NAMES FROM VA(20 COMPONETS
  1.  S WIICOMP=$$GET1^DIQ(2,WIIDFN,1.01,"I")
  1.  ;INTEGRATION REFERENCE #3041
  1.  S WIICOMA=$$GET1^DIQ(20,WIICOMP,1,"E") S:WIICOMA="" WIICOMA=$P($G(WIIP2),",",1)  ;"ERROR LAST NAME"
  1.  S WIICOMB=$$GET1^DIQ(20,WIICOMP,2,"E") S:WIICOMB="" WIICOMB=$P($G(WIIP2),",",2)  ;"ERROR FIRST NAME"
  1.  S WIICOMC=$$GET1^DIQ(20,WIICOMP,3,"E") S:WIICOMC="" WIICOMC="   "
  1.  ;NO THE REFERENCE TO 987.7 IS NOT A TYPO THIS IS THE FILE NUMBER THAT THIS DATA STRING IS GOING TO POPULATE
  1.  S WIISTRG="987.7^"_WIIP5_U_WIICOMA_U_WIIP3_U_WIIP6_U_WIIP7_U_WIIP8_U_WIIP10_U_1_U_WIIP11_U_WIIP12_U_WIIP13_U_WIIP14_U_WIIP15_U_WIICOMB_U_WIICOMC
  1.  S WIICNT=WIICNT+1
  1.  S ^TMP($J,WIICNT,0)=WIISTRG
  1.  S DIE="^WII(987.5,",DA=WIIENT,DR="8///4"
  1.  D ^DIE
  1.  Q
  1. XMB ;
  1.  ; XMY..........RECIPIENTS OF MSG
  1.  ; XMDUZ........MESSAGE SENDER
  1.  ; XMSUB........MESSAGE SUBJECT
  1.  ; XMTEXT.......MESSAGE TEXT
  1.  ; below line send output to XMB
  1.  ;API used see Appendix A Message Server Protocol
  1.  S WIIREV=$$GET1^DIQ(987.6,1,1,"I")  ;NATIONAL REVIEWER OF THE DATA BEFORE IT GOES OFF TO DEFAS
  1.  S XMY(WIIREV)=""
  1.  S XMDUZ=.5,XMSUB=^DD("SITE")_" - Admissions/Discharges",XMTEXT="^TMP($J," D ^XMD,KILL^XM
  1.  Q
  1. CLEAN ;
  1.  K XMDUZ,XMY,WIIREV
  1.  K ^TMP($J)
  1.  K WIIENT,WIICNT,WIIDATA,WIIP2,WIIP3,WIIP4,WIIP5,WIIP6,WIIP7,WIIP8,WIIP9,WIIP10,WIISTRG
  1.  K DA,DIC,DIE,DR,XMDUZ,XMSUB,XMTEXT,WIIP15
  1.  K WIIP11,WIIP12,WIIP13,WIIP14,WIIP2,WIICOMP,WIICOMA,WIICOMB,WIICOMC,WIIDFN
  1.  Q