Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: WVRPSCR

WVRPSCR.m

Go to the documentation of this file. 
  1. WVRPSCR ;HCIOFO/FT,JR IHS/ANMC/MWR - Display Compliance Rates ;12/9/98  13:39
  1.  ;;1.0;WOMEN'S HEALTH;**3**;Sep 30, 1998
  1.  ;;* MICHAEL REMILLARD, DDS * ALASKA NATIVE MEDICAL CENTER *
  1.  ;;  THIS REPORT WILL DISPLAY COMPLIANCE RATES FOR PAPS & MAMS.
  1.  ;
  1. PRINT ;EP
  1.  ;
  1.  N I,J,M,N,P,Q
  1.  D SETUP
  1.  D TITLE^WVUTL5("COMPLIANCE RATES FOR PAPS AND MAMS")
  1.  D TEXT1,DIRZ^WVUTL3 G:WVPOP EXIT
  1.  D DATES   G:WVPOP EXIT
  1.  D AGERNG  G:WVPOP EXIT
  1.  D DEVICE  G:WVPOP EXIT
  1.  D DATA^WVRPSCR1,EN^WVRPSCR2
  1.  D DISPLAY
  1.  I WVCRT&('$D(IO("S")))&('$G(WVPOP)) D DIRZ^WVUTL3 W @IOF
  1.  ;
  1. EXIT ;EP
  1.  D KILLALL^WVUTL8
  1.  Q
  1.  ;
  1. SETUP ;EP
  1.  D SETVARS^WVUTL5
  1.  Q
  1.  ;
  1. DATES ;EP
  1.  ;---> ASK DATE RANGE.  RETURN DATES IN WVBEGDT AND WVENDDT.
  1.  D ASKDATES^WVUTL3(.WVBEGDT,.WVENDDT,.WVPOP)
  1.  Q
  1.  ;
  1. AGERNG ;EP
  1.  ;---> ASK AGE RANGE.
  1.  ;---> RETURN AGE RANGE IN WVAGRG.
  1.  D AGERNG^WVRPSCR1(.WVAGRG,.WVPOP)
  1.  Q
  1.  ;
  1. DEVICE ;EP
  1.  ;---> GET DEVICE AND POSSIBLY QUEUE TO TASKMAN.
  1.  S ZTRTN="DEQUEUE^WVRPSCR"
  1.  F WVSV="AGRG","BEGDT","ENDDT" D
  1.  .I $D(@("WV"_WVSV)) S ZTSAVE("WV"_WVSV)=""
  1.  ;---> SAVE ATTRIBUTES ARRAY. NOTE: SUBSTITUTE LOCAL ARRAY FOR WVATT.
  1.  I $D(WVCC) N N S N=0 F  S N=$O(WVCC(N)) Q:N=""  D
  1.  .S ZTSAVE("WVCC("""_N_""")")=""
  1.  D ZIS^WVUTL2(.WVPOP,1,"HOME")
  1.  Q
  1.  ;
  1.  ;
  1. DISPLAY ;EP
  1.  U IO
  1.  S WVTITLE="*  WOMEN'S HEALTH: COMPLIANCE RATES FOR PAPS AND MAMS  *"
  1.  D CENTERT^WVUTL5(.WVTITLE)
  1.  D TOPHEAD^WVUTL7
  1.  S WVPAGE=1,WVPOP=0
  1.  S WVSUB="W !?3,""For Age Range: "",$S(WVAGRG=1:""ALL"",1:WVAGRG)"
  1.  ;
  1.  S (WVPOP,N,Z)=0
  1.  W:WVCRT @IOF D HEADER8^WVUTL7
  1.  F  S N=$O(^TMP("WV",$J,N)) Q:'N!(WVPOP)  D
  1.  .I N=16.001!(N=7.001) W ! D HDR^WVRPSCR2
  1.  .I $Y+3>IOSL D:WVCRT DIRZ^WVUTL3 Q:WVPOP  I $O(^TMP("WV",$J,N))'="" W @IOF D HEADER8^WVUTL7 D:'WVCRT HDR^WVRPSCR2
  1.  .W !,^TMP("WV",$J,N,0)
  1.  D ^%ZISC
  1.  Q
  1.  ;
  1. DEQUEUE ;EP
  1.  ;---> CALLED BY TASKMAN
  1.  D SETUP,DATA^WVRPSCR1,EN^WVRPSCR2,DISPLAY,EXIT
  1.  Q
  1.  ;
  1. TEXT1 ;
  1.  ;;This report is designed to serve as an indicator of compliance
  1.  ;;rates for PAPs and MAMs.  The report will display the percentages
  1.  ;;of women who received PAPs and MAMs for compliance purposes only,
  1.  ;;within the selected date range.
  1.  ;;
  1.  ;;Only patients who have had normal results for procedures in the
  1.  ;;specified date range are counted; the intent is to exclude
  1.  ;;any procedures that would involve abnormal results, diagnostic
  1.  ;;and follow-up procedures, etc.  Due to the complexities
  1.  ;;involved in the treatment of individual cases that involve
  1.  ;;abnormal results, those patients will not be included, even
  1.  ;;though some of them may have received screening PAPs or MAMs.
  1.  ;;
  1.  ;;This report, therefore, serves ONLY AS AN INDICATOR (NOT as an exact
  1.  ;;count of compliance rates) for gauging the success rates of annual
  1.  ;;screening programs.  It can be run for several different time frames
  1.  ;;in order to examine trends.  Assuming a screening cycle of one year,
  1.  ;;a minimum date range spanning 15 months is recommended.
  1.  S WVTAB=5,WVLINL="TEXT1" D PRINTX
  1.  Q
  1.  ;
  1. PRINTX ;EP
  1.  N I,T,X S T=$$REPEAT^XLFSTR(" ",WVTAB)
  1.  F I=1:1 S X=$T(@WVLINL+I) Q:X'[";;"  W !,T,$P(X,";;",2)
  1.  Q