Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: XMJMFC

XMJMFC.m

Go to the documentation of this file.
  1. XMJMFC ;ISC-SF/GMB-Find message in file 3.9 ;07/12/2002 10:34
  1. ;;8.0;MailMan;;Jun 28, 2002
  1. ; Search for messages in the MESSAGE file
  1. FIND(XMDUZ,XMF,XMWAIT) ;
  1. I $G(XMF("FLAGS"))["U",'$$SSPRIV^XMXSEC1 D Q
  1. . D SHOW^XMJERR
  1. . D WAIT^XMXUTIL
  1. N XMKZ,XMCNT,XMABORT,XMLEN,XMFIRST,XMPAGE,XMDETAIL,XMPMAX,XMMORE,XMFLAGS,XMSCREEN,XMFROM,XMZOOM,XMCD,XMOPT,XMOX,XMSAVE
  1. S XMSAVE("FDATE")=XMF("FDATE") K XMF("FDATE")
  1. S XMSAVE("TDATE")=XMF("TDATE") K XMF("TDATE")
  1. K ^TMP("XM",$J,"MSG"),^TMP("XM",$J,".")
  1. S (XMKZ,XMZ,XMPAGE,XMCNT,XMZOOM,XMCD,XMABORT)=0,(XMDETAIL,XMMORE)=1,XMPMAX=IOSL-3
  1. D SRCHINIT(XMDUZ,.XMF,.XMFLAGS,.XMSCREEN,.XMFROM,.XMABORT) Q:XMABORT
  1. D INIT(XMDUZ,XMFLAGS,XMDETAIL,.XMLEN)
  1. D SETOPT^XMJMLR1(XMDUZ,$S(XMFLAGS["U":"!",1:0),.XMOPT,.XMOX)
  1. F D Q:XMABORT
  1. . I XMCD S XMCD=0,XMDETAIL='XMDETAIL D INIT(XMDUZ,XMFLAGS,XMDETAIL,.XMLEN)
  1. . D DISPLAY(XMDUZ,.XMF,XMFLAGS,XMSCREEN,.XMFROM,XMDETAIL,.XMKZ,.XMCNT,.XMFIRST,.XMPAGE,.XMMORE,.XMLEN,XMZOOM,XMPMAX)
  1. . I XMCNT=0 S XMABORT=1 Q
  1. . D CHOOSE^XMJMLN(XMDUZ,1,0,.XMKZ,.XMFIRST,.XMPAGE,XMMORE,.XMLEN,.XMZOOM,.XMOPT,.XMOX,"READMSG^XMJMFC",.XMABORT)
  1. . S:'$D(^TMP("XM",$J,"MSG")) XMABORT=1
  1. I XMCNT=0 D
  1. . W $$EZBLD^DIALOG(34401) ; No matches found.
  1. . Q:'$G(XMWAIT)
  1. . W ! D WAIT^XMXUTIL
  1. K ^TMP("XM",$J,"MSG"),^TMP("XM",$J,".")
  1. S XMF("FDATE")=XMSAVE("FDATE"),XMF("TDATE")=XMSAVE("TDATE")
  1. Q
  1. INIT(XMDUZ,XMFLAGS,XMDETAIL,XMLEN) ;
  1. I XMFLAGS'["U" S XMLEN("BSKT")=10
  1. S XMLEN("XMKZ")=3
  1. D INIT^XMJML(XMDUZ,"","",XMDETAIL,.XMLEN,XMFLAGS["U")
  1. Q
  1. SRCHINIT(XMDUZ,XMF,XMFLAGS,XMSCREEN,XMFROM,XMABORT) ;
  1. I XMV("ORDER")=-1 D
  1. . S XMFLAGS="B"
  1. . S XMFROM=$O(^XMB(3.9,"C",XMSAVE("TDATE")))
  1. E D
  1. . S XMFLAGS=""
  1. . S XMFROM=$O(^XMB(3.9,"C",XMSAVE("FDATE")),-1)
  1. S XMFLAGS=$S(XMV("ORDER")=-1:"B",1:"")
  1. I $G(XMF("FLAGS"))["U" D Q:XMABORT
  1. . S XMFLAGS=XMFLAGS_"U" ; Ignore file screen
  1. . D AUDIT(.XMF)
  1. . Q:'$D(XMERR)
  1. . S XMABORT=1
  1. . D SHOW^XMJERR
  1. . D WAIT^XMXUTIL
  1. S:$D(XMF("SUBJ")) XMF("SUBJ","S")=$$UP^XLFSTR(XMF("SUBJ"))
  1. S:$D(XMF("TEXT")) XMF("TEXT","S")=$S('XMF("TEXT","C"):$$UP^XLFSTR(XMF("TEXT")),1:XMF("TEXT"))
  1. S XMSCREEN=$$SCREEN(XMDUZ)
  1. Q
  1. AUDIT(XMF) ; Send a bulletin to G.XM SUPER SEARCH
  1. N XMINSTR,XMPARM,XMTEXT,I
  1. I '$$GOTLOCAL^XMXAPIG("XM SUPER SEARCH",90,2) D ERRSET^XMXUTIL(34413.6) Q
  1. S XMINSTR("FROM")=.5
  1. S XMPARM(1)=XMV("DUZ NAME")
  1. S I=1,XMTEXT(I)=$$LJ^XLFSTR($$EZBLD^DIALOG(34443)_":",30)_$$FMTE^XLFDT(XMSAVE("FDATE"))_" - "_$$FMTE^XLFDT(XMSAVE("TDATE")) ; Search period
  1. I $D(XMF("SUBJ")) D ; Subject contains
  1. . S I=I+1,XMTEXT(I)=$$LJ^XLFSTR($$EZBLD^DIALOG(34438)_":",30)_XMF("SUBJ")
  1. I $D(XMF("FROM")) D ; Message from
  1. . S I=I+1,XMTEXT(I)=$$LJ^XLFSTR($$EZBLD^DIALOG(34440)_":",30)_$$NAME^XMXUTIL(XMF("FROM"))
  1. I $D(XMF("TO")) D ; Message to
  1. . S I=I+1,XMTEXT(I)=$$LJ^XLFSTR($$EZBLD^DIALOG(34440.2)_":",30)_XMF("TO")
  1. I $D(XMF("FLINE")) D ; Lines of text, minimum
  1. . S I=I+1,XMTEXT(I)=$$LJ^XLFSTR($$EZBLD^DIALOG(34449)_":",30)_XMF("FLINE")
  1. ;I $D(XMF("TLINE")) D ; Lines of text, maximum
  1. ;. S I=I+1,XMTEXT(I)=$$LJ^XLFSTR($$EZBLD^DIALOG(34450)_":",30)_XMF("TLINE")
  1. I $D(XMF("RFROM")) D ; Response from
  1. . S I=I+1,XMTEXT(I)=$$LJ^XLFSTR($$EZBLD^DIALOG(34440.1)_":",30)_$$NAME^XMXUTIL(XMF("RFROM"))
  1. I $D(XMF("TEXT")) D
  1. . ; x.1:Message / x.2:Message or Response / x.3:Response contains
  1. . S I=I+1,XMTEXT(I)=$$LJ^XLFSTR($$EZBLD^DIALOG(34446+(XMF("TEXT","L")/10))_":",30)_XMF("TEXT")
  1. D SENDBULL^XMXBULL(DUZ,"XM SUPER SEARCH",.XMPARM,"XMTEXT","G.XM SUPER SEARCH",.XMINSTR)
  1. I $D(XMERR) D ERRSET^XMXUTIL(34413.6)
  1. Q
  1. SCREEN(XMDUZ) ;
  1. S XMSCREEN="N X S X=^(0)"
  1. I XMDUZ'=.5 D
  1. . N XMMIN
  1. . S XMMIN=$P(^XMB(3.7,XMDUZ,0),U,7)
  1. . ; If minimum date, don't choose lower date unless already in user's bskt
  1. . I XMMIN>0 S XMSCREEN=" I ^(.6)'<"_XMMIN_"!$D(^XMB(3.7,""M"",Y,XMDUZ))"
  1. ; Msg must not be SPOOL, msg must not be a reply.
  1. Q XMSCREEN_" I $P(X,U,7)'=""S"",'$P(X,U,8),$P(X,U)'?1""R"".N,$$GOODMSG^XMJMFB(XMDUZ,0,Y,.XMF)"
  1. DISPLAY(XMDUZ,XMF,XMFLAGS,XMSCREEN,XMFROM,XMDETAIL,XMKZ,XMCNT,XMFIRST,XMPAGE,XMMORE,XMLEN,XMZOOM,XMPMAX) ;
  1. N XMREC
  1. S XMFIRST(XMPAGE)=XMKZ
  1. D HEADER^XMJML(XMDETAIL,.XMLEN,$$EZBLD^DIALOG($S(XMFLAGS["U":34403.5,1:34403))) ; All Messages Super Search / All Messages Search
  1. I XMZOOM D Q
  1. . F S XMKZ=$O(^TMP("XM",$J,".",XMKZ)) Q:XMKZ="" D Q:$Y>XMPMAX
  1. . . S XMREC=^TMP("XM",$J,"MSG",XMKZ)
  1. . . D LISTMSG^XMJML($P(XMREC,U,1),$P(XMREC,U,2),XMKZ,$P(XMREC,U,3),XMDETAIL,.XMLEN)
  1. F S XMKZ=$O(^TMP("XM",$J,"MSG",XMKZ)) Q:XMKZ="" D Q:$Y>XMPMAX
  1. . S XMREC=^TMP("XM",$J,"MSG",XMKZ)
  1. . D LISTMSG^XMJML($P(XMREC,U,1),$P(XMREC,U,2),XMKZ,$P(XMREC,U,3),XMDETAIL,.XMLEN)
  1. Q:$Y>XMPMAX!'XMMORE
  1. ; File screen ^DD(3.9,0,"SCR") insists that user be author or recipient.
  1. ; If FLAGS["U", then file screen is ignored.
  1. D LIST^DIC(3.9,"","@",XMFLAGS,XMPMAX-$Y+1,.XMFROM,"","C",XMSCREEN)
  1. S:$P(^TMP("DILIST",$J,0),U,3)=0 XMMORE=0
  1. D LISTMSG(XMDUZ,XMDETAIL,.XMCNT,.XMLEN,.XMMORE)
  1. S XMKZ=XMCNT
  1. K ^TMP("DILIST",$J)
  1. W:'XMMORE !,$$EZBLD^DIALOG(34402) ; Search finished.
  1. Q
  1. LISTMSG(XMDUZ,XMDETAIL,XMCNT,XMLEN,XMMORE) ; Check and List
  1. N XMK,XMKN,XMZ,I,XMNA,XMSTOP,XMDATE
  1. S I="",XMSTOP=0,XMNA=$$EZBLD^DIALOG(34014) ; * N/A *
  1. I XMFLAGS["U" S XMK=0,XMKN=XMNA
  1. F S I=$O(^TMP("DILIST",$J,2,I),XMV("ORDER")) Q:I'>0 D Q:XMSTOP
  1. . S XMCNT=XMCNT+1
  1. . S XMZ=^TMP("DILIST",$J,2,I)
  1. . S XMDATE=+$G(^XMB(3.9,XMZ,.6))
  1. . I XMDATE,XMDATE<XMSAVE("FDATE")!(XMDATE>XMSAVE("TDATE")) D Q
  1. . . S XMMORE=0,XMSTOP=1
  1. . I XMFLAGS'["U" D
  1. . . S XMK=+$O(^XMB(3.7,"M",XMZ,XMDUZ,0))
  1. . . S XMKN=$S(XMK:$P(^XMB(3.7,XMDUZ,2,XMK,0),U),1:XMNA)
  1. . . I XMK,'$D(^XMB(3.7,XMDUZ,2,XMK,1,XMZ,0)) D ADDITM^XMUT4A(XMDUZ,XMK,XMZ)
  1. . D LISTMSG^XMJML(XMK,XMKN,XMCNT,XMZ,XMDETAIL,.XMLEN)
  1. . S ^TMP("XM",$J,"MSG",XMCNT)=XMK_U_XMKN_U_XMZ
  1. Q
  1. READMSG ; (XMDUZ,XMKZ,XMREC) <- needed!
  1. N XMK,XMKN,XMZ,XMRDR ; $G(XMRDR) is checked in READMSG^XMJBM
  1. I XMFLAGS["U" D
  1. . S XMK="!",XMKN=$$EZBLD^DIALOG(34014) ; * N/A *
  1. E D
  1. . S XMK=$P(XMREC,U,1),XMKN=$P(XMREC,U,2)
  1. S XMZ=$P(XMREC,U,3)
  1. D READMSG^XMJBM(XMDUZ,XMK,XMKN,XMZ)
  1. Q:XMFLAGS["U"
  1. Q:$D(^XMB(3.7,"M",XMZ,XMDUZ,XMK))
  1. S XMK=+$O(^XMB(3.7,"M",XMZ,XMDUZ,0))
  1. S ^TMP("XM",$J,"MSG",XMKZ)=XMK_U_$S(XMK=0:$$EZBLD^DIALOG(34014),1:$P(^XMB(3.7,XMDUZ,2,XMK,0),U))_U_XMZ ; * N/A *
  1. Q