Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: XMJMLR

XMJMLR.m

Go to the documentation of this file.
  1. XMJMLR ;ISC-SF/GMB-List/Read messages in basket ;05/21/2002 06:46
  1. ;;8.0;MailMan;;Jun 28, 2002
  1. ; Replaces 1^XMAL0 (ISC-WASH/THM/CAP)
  1. LIST(XMDUZ,XMK,XMKN,XMDETAIL,XMABORT) ; List messages in basket
  1. ; XMDETAIL 0=Summary; 1=Detailed
  1. N XMKZ,XMLEN,XMFIRST,XMPAGE,XMPMAX,XMZOOM,XMINSTR,XMOPT,XMOX,XMORDER
  1. I XMDUZ=.5,XMK>999 S XMORDER=XMV("ORDER"),XMV("ORDER")=1
  1. S XMINSTR("GOTO")=1 ; may go to another page
  1. D SETOPT^XMJMLR1(XMDUZ,XMK,.XMOPT,.XMOX)
  1. K ^TMP("XM",$J,".")
  1. S XMKZ="",(XMPAGE,XMZOOM)=0,XMPMAX=IOSL-3
  1. D INIT^XMJML(XMDUZ,XMK,XMKN,XMDETAIL,.XMLEN,1)
  1. F D Q:XMABORT!'$D(^XMB(3.7,XMDUZ,2,XMK,1,"C"))
  1. . D DISPLAY(XMDUZ,XMDETAIL,XMK,XMKN,.XMKZ,.XMFIRST,.XMPAGE,.XMLEN,XMZOOM,XMPMAX)
  1. . D CHOOSE(XMDUZ,.XMK,.XMKZ,.XMFIRST,.XMPAGE,.XMLEN,.XMZOOM,.XMINSTR,.XMOPT,.XMOX,.XMABORT)
  1. K ^TMP("XM",$J,".")
  1. I $D(XMORDER) S XMV("ORDER")=XMORDER
  1. Q
  1. DISPLAY(XMDUZ,XMDETAIL,XMK,XMKN,XMKZ,XMFIRST,XMPAGE,XMLEN,XMZOOM,XMPMAX) ;
  1. N XMZ
  1. S XMFIRST(XMPAGE)=XMKZ
  1. D HEADER^XMJML(XMDETAIL,.XMLEN,$$HEADLINE^XMJML(XMDUZ,XMK,XMKN))
  1. I XMZOOM D Q
  1. . F S XMKZ=$O(^TMP("XM",$J,".",XMKZ),XMV("ORDER")) Q:XMKZ="" D Q:$Y>XMPMAX
  1. . . D LISTMSG^XMJML(XMK,XMKN,XMKZ,$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ,"")),XMDETAIL,.XMLEN)
  1. F S XMKZ=$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ),XMV("ORDER")) Q:XMKZ="" D Q:$Y>XMPMAX
  1. . S XMZ=$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ,""))
  1. . I '$D(^XMB(3.7,XMDUZ,2,XMK,1,XMZ,0)) D ADDITC^XMUT4A(XMDUZ,XMK,XMZ,XMKZ)
  1. . I '$D(^XMB(3.9,XMZ,0)) D ZAPIT^XMXMSGS2(XMDUZ,XMK,XMZ) Q
  1. . D LISTMSG^XMJML(XMK,XMKN,XMKZ,XMZ,XMDETAIL,.XMLEN)
  1. Q
  1. CHOOSE(XMDUZ,XMK,XMKZ,XMFIRST,XMPAGE,XMLEN,XMZOOM,XMINSTR,XMOPT,XMOX,XMABORT) ;
  1. N XMY,XMZ,XMMORE,XMHI,XMLO
  1. S XMMORE=$S(XMKZ="":0,'$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ),XMV("ORDER")):0,1:1)
  1. S XMLO=$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",""))
  1. S XMHI=$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",""),-1)
  1. D XMDIR^XMJMLR1(XMDUZ,XMLO,XMHI,XMPAGE,XMMORE,"XM-U-BO-FULL SCREEN",.XMINSTR,.XMOPT,.XMOX,.XMY,.XMABORT) Q:XMABORT
  1. I '$D(XMY) S XMKZ=XMFIRST(XMPAGE) Q
  1. I XMY=""!($E(XMY)="+") D Q ; Page forward
  1. . I XMMORE D PFWD Q
  1. . I XMPAGE=0 S XMABORT=1 Q
  1. . D AGAIN(.XMABORT) Q:XMABORT
  1. . S XMPAGE=0
  1. . S XMKZ=XMFIRST(XMPAGE)
  1. I $E(XMY)="." D Q ; (De)Select messages
  1. . D DODOT
  1. . I XMZOOM,'$D(^TMP("XM",$J,".")) D Z
  1. . S XMKZ=XMFIRST(XMPAGE)
  1. I XMY>0 D Q ;
  1. . N XMKZLAST
  1. . S XMKZLAST=XMKZ
  1. . S XMKZ=XMY
  1. . S XMZ=$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ,""))
  1. . I XMZ D
  1. . . I '$D(^XMB(3.7,XMDUZ,2,XMK,1,XMZ,0)) D ADDITC^XMUT4A(XMDUZ,XMK,XMZ,XMKZ)
  1. . . D READMSG(XMDUZ,XMK,XMKN,XMKZ,XMZ,XMZOOM)
  1. . . D FINDXMKZ(XMDUZ,XMK,.XMFIRST,.XMPAGE,XMKZLAST,XMKZ)
  1. . E D
  1. . . S XMZ=XMY
  1. . . I $D(^XMB(3.7,XMDUZ,2,XMK,1,XMZ,0)) D Q
  1. . . . S XMKZ=$P(^XMB(3.7,XMDUZ,2,XMK,1,XMZ,0),U,2)
  1. . . . I 'XMKZ D ADDITM^XMUT4A(XMDUZ,XMK,XMZ,.XMKZ)
  1. . . . D READMSG(XMDUZ,XMK,XMKN,XMKZ,XMZ,XMZOOM)
  1. . . . D FINDXMKZ(XMDUZ,XMK,.XMFIRST,.XMPAGE,XMKZLAST,XMKZ)
  1. . . I '$D(^XMB(3.9,XMZ,0)) D Q
  1. . . . W $C(7)
  1. . . . Q:XMZ>$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",""),-1)
  1. . . . S XMKZ=$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMZ),XMV("ORDER"))
  1. . . . I 'XMKZ S XMKZ=$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMZ),-XMV("ORDER"))
  1. . . . D FINDXMKZ(XMDUZ,XMK,.XMFIRST,.XMPAGE,XMKZLAST,XMKZ)
  1. . . N XMK,XMKN,XMOK
  1. . . S XMK=+$O(^XMB(3.7,"M",XMZ,XMDUZ,0))
  1. . . I 'XMK D Q:'XMOK
  1. . . . N XMZREC
  1. . . . S XMZREC=^XMB(3.9,XMZ,0)
  1. . . . I $D(XMERR) K XMERR,^TMP("XMERR",$J)
  1. . . . S XMOK=$$ACCESS^XMXSEC(XMDUZ,XMZ,XMZREC) Q:XMOK
  1. . . . D FWD^XMJMLR1(XMDUZ,XMZ,XMZREC,1,.XMOK)
  1. . . S XMKN=$S(XMK:$P(^XMB(3.7,XMDUZ,2,XMK,0),U,1),1:$$EZBLD^DIALOG(34014)) ; * N/A *
  1. . . I XMK,'$D(^XMB(3.7,XMDUZ,2,XMK,1,XMZ,0)) D ADDITM^XMUT4A(XMDUZ,XMK,XMZ)
  1. . . D READMSG^XMJBM(XMDUZ,XMK,XMKN,XMZ)
  1. . S XMKZ=XMFIRST(XMPAGE)
  1. I XMY=0 D Q ; First page
  1. . S XMPAGE=0
  1. . S XMKZ=XMFIRST(XMPAGE)
  1. I $E(XMY)="-" D Q ; Page back
  1. . N XMCNT
  1. . S XMCNT=$E(XMY,2,99)
  1. . S:XMCNT="" XMCNT=1
  1. . S XMPAGE=XMPAGE-XMCNT
  1. . S:XMPAGE<0 XMPAGE=0
  1. . S XMKZ=XMFIRST(XMPAGE)
  1. D @XMY
  1. S XMKZ=XMFIRST(XMPAGE)
  1. Q
  1. PFWD ;
  1. N XMCNT,XMPDEST
  1. S XMCNT=$E(XMY,2,99)
  1. S:XMCNT="" XMCNT=1
  1. I XMCNT=1 S XMPAGE=XMPAGE+1 Q
  1. S XMPDEST=XMPAGE+XMCNT
  1. D FINDPAGE(.XMFIRST,.XMPAGE,XMKZ,XMPDEST)
  1. S XMKZ=XMFIRST(XMPAGE)
  1. Q
  1. FINDPAGE(XMFIRST,XMPAGE,XMKZ,XMPDEST) ;
  1. N XMO,I
  1. S XMO=$S(XMPDEST>XMPAGE:1,1:-1)
  1. F XMPAGE=XMPAGE+XMO:XMO S XMFIRST(XMPAGE)=XMKZ Q:XMPAGE=XMPDEST D Q:XMKZ=""
  1. . F I=1:1:XMPMAX S XMKZ=$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ),XMO*XMV("ORDER")) Q:XMKZ=""
  1. I '$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMFIRST(XMPAGE)),XMO*XMV("ORDER")) S XMPAGE=XMPAGE-XMO Q
  1. Q
  1. FINDXMKZ(XMDUZ,XMK,XMFIRST,XMPAGE,XMKZLAST,XMKZF) ; Find the page with XMKZF on it
  1. Q:'$D(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZF))
  1. I XMV("ORDER")=-1 D Q
  1. . I $S(XMFIRST(XMPAGE):XMFIRST(XMPAGE)>XMKZF,1:1),XMKZF'<XMKZLAST Q
  1. . N XMKZ,I
  1. . I XMKZF<XMKZLAST D Q ; Go forward
  1. . . S XMKZ=XMKZLAST
  1. . . F XMPAGE=XMPAGE+1:1 D Q:XMKZ=XMKZF
  1. . . . S XMFIRST(XMPAGE)=XMKZ
  1. . . . F I=1:1:XMPMAX S XMKZ=$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ),-1) Q:XMKZ=XMKZF
  1. . E D ; Go back
  1. . . F XMPAGE=XMPAGE-1:-1 Q:XMFIRST(XMPAGE)>XMKZF!'XMPAGE
  1. . . ;S XMKZ=XMFIRST(XMPAGE)-1
  1. . . ;F XMPAGE=XMPAGE-1:-1 D Q:XMFIRST(XMPAGE)>XMKZF
  1. . . ;. F I=1:1:XMPMAX S XMKZ=$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ)) Q:XMKZ=""
  1. . . ;. S XMFIRST(XMPAGE)=$S(XMKZ:XMKZ+1,1:XMKZ)
  1. I XMFIRST(XMPAGE)<XMKZF,$S(XMKZLAST:XMKZF'>XMKZLAST,1:1) Q
  1. N XMKZ,I
  1. I XMKZF>XMKZLAST D Q ; Go forward
  1. . S XMKZ=XMKZLAST
  1. . F XMPAGE=XMPAGE+1:1 D Q:XMKZ=XMKZF
  1. . . S XMFIRST(XMPAGE)=XMKZ
  1. . . F I=1:1:XMPMAX S XMKZ=$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ)) Q:XMKZ=XMKZF
  1. E D ; Go back
  1. . F XMPAGE=XMPAGE-1:-1 Q:XMFIRST(XMPAGE)<XMKZF!'XMPAGE
  1. . ;S XMKZ=XMFIRST(XMPAGE)-1
  1. . ;F XMPAGE=XMPAGE-1:-1 D Q:XMFIRST(XMPAGE)<XMKZF
  1. . ;. F I=1:1:XMPMAX S XMKZ=$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ),-1) Q:XMKZ=""
  1. . ;. S XMFIRST(XMPAGE)=$S(XMKZ:XMKZ+1,1:XMKZ)
  1. Q
  1. READMSG(XMDUZ,XMK,XMKN,XMKZ,XMZ,XMZOOM) ;
  1. D READMSG^XMJBM(XMDUZ,XMK,XMKN,XMZ)
  1. I $D(^TMP("XM",$J,".",XMKZ)),'$D(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ,XMZ)) K ^TMP("XM",$J,".",XMKZ)
  1. I XMZOOM,'$D(^TMP("XM",$J,".")) D Z
  1. Q
  1. AGAIN(XMABORT) ;
  1. N DIR,Y
  1. W !
  1. S DIR("A")=$$EZBLD^DIALOG(34020) ; End reached. Begin again
  1. S DIR(0)="Y",DIR("B")=$$EZBLD^DIALOG(39053) ; No
  1. D BLD^DIALOG(34021,"","","DIR(""?"")") ; Enter 'Yes' if you wish to continue reading messages; 'No' if you don't.
  1. D ^DIR
  1. Q:Y=1 ; Yes, begin again
  1. S XMABORT=1 ; No, exit.
  1. Q
  1. DODOT ;
  1. N I,XMSTRIKE,XM1,XMN,XMKZ
  1. I $E(XMY,2)="-" S XMSTRIKE=1,XMY=$E(XMY,3,999)
  1. E S XMSTRIKE=0,XMY=$E(XMY,2,999)
  1. I XMY="*" D Q
  1. . I XMSTRIKE K ^TMP("XM",$J,".") Q
  1. . S XMKZ=""
  1. . F S XMKZ=$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ)) Q:'XMKZ S ^TMP("XM",$J,".",XMKZ)=""
  1. F I=1:1:$L(XMY,",") D
  1. . S XMKZ=$P(XMY,",",I)
  1. . I XMKZ["-" D Q
  1. . . S XM1=$P(XMKZ,"-")
  1. . . S XMN=$P(XMKZ,"-",2) S:XMN="" XMN=XMHI
  1. . . S XMKZ=XM1-.1
  1. . . I 'XMSTRIKE D Q
  1. . . . F S XMKZ=$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ)) Q:XMKZ>XMN!'XMKZ S:'$D(^TMP("XM",$J,".",XMKZ)) ^(XMKZ)=""
  1. . . F S XMKZ=$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ)) Q:XMKZ>XMN!'XMKZ K:$D(^TMP("XM",$J,".",XMKZ)) ^(XMKZ)
  1. . I 'XMSTRIKE D Q
  1. . . I $D(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ)),'$D(^TMP("XM",$J,".",XMKZ)) S ^(XMKZ)=""
  1. . K:$D(^TMP("XM",$J,".",XMKZ)) ^(XMKZ)
  1. Q
  1. C ; Change the name of this basket
  1. D NAMEBSKT^XMJBU(XMDUZ,XMK,.XMKN)
  1. K XMLEN
  1. D INIT^XMJML(XMDUZ,XMK,XMKN,XMDETAIL,.XMLEN,1)
  1. Q
  1. CD ; Change Detail
  1. S XMDETAIL='XMDETAIL
  1. D INIT^XMJML(XMDUZ,XMK,XMKN,XMDETAIL,.XMLEN,1)
  1. Q
  1. D ; Delete messages
  1. D DELETE^XMJMOR(XMDUZ,XMK)
  1. D WAIT^XMXUTIL
  1. I XMZOOM,'$D(^TMP("XM",$J,".")) D Z
  1. Q
  1. F ; Forward messages
  1. D FORWARD^XMJMOR(XMDUZ,XMK)
  1. D WAIT^XMXUTIL
  1. Q
  1. FI ; Filter messages
  1. D FILTER^XMJMOR(XMDUZ,XMK)
  1. D WAIT^XMXUTIL
  1. Q
  1. H ; Headerless Print messages
  1. D PRINT^XMJMOR(XMDUZ,XMK,0)
  1. D WAIT^XMXUTIL
  1. Q
  1. L ; Later messages
  1. D LATER^XMJMOR(XMDUZ,XMK)
  1. D WAIT^XMXUTIL
  1. I XMZOOM,'$D(^TMP("XM",$J,".")) D Z
  1. Q
  1. N ; New message list
  1. D LISTONE^XMJMLN(XMDUZ,XMK,XMKN,"N0")
  1. D WAIT^XMXUTIL
  1. Q
  1. NT ; New Toggle messages
  1. D NEWTOGL^XMJMOR(XMDUZ,XMK)
  1. D WAIT^XMXUTIL
  1. Q
  1. O ; Opposite toggle
  1. N XMKZ
  1. S XMKZ=0
  1. F S XMKZ=$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ)) Q:'XMKZ D
  1. . I $D(^TMP("XM",$J,".",XMKZ)) K ^TMP("XM",$J,".",XMKZ) Q
  1. . S ^TMP("XM",$J,".",XMKZ)=""
  1. S XMPAGE=0
  1. Q
  1. P ; Print messages
  1. D PRINT^XMJMOR(XMDUZ,XMK)
  1. D WAIT^XMXUTIL
  1. Q
  1. Q ; Query messages
  1. D FINDBSKT^XMJMF(XMDUZ,XMK,XMKN)
  1. Q
  1. Q1 ; ?string - search for messages in this basket whose subject contains string.
  1. N XMF
  1. S XMF("BSKT")=XMK
  1. S XMF("SUBJ")=XMY(0)
  1. D FIND1^XMJMFB(XMDUZ,.XMF,1)
  1. Q
  1. Q2 ; ??string - search for messages whose subject starts with string.
  1. D FIND^XMJMFA(XMDUZ,XMY(0),1)
  1. Q
  1. R ; Resequence messages
  1. D R^XMJBM
  1. S XMPAGE=0
  1. K XMLEN,XMFIRST
  1. S XMFIRST(0)=""
  1. D INIT^XMJML(XMDUZ,XMK,XMKN,XMDETAIL,.XMLEN,1)
  1. D WAIT^XMXUTIL
  1. Q
  1. S ; Save messages
  1. D SAVE^XMJMOR(XMDUZ,XMK)
  1. D WAIT^XMXUTIL
  1. Q
  1. T ; Terminate messages
  1. D TERM^XMJMOR(XMDUZ,XMK)
  1. D WAIT^XMXUTIL
  1. I XMZOOM,'$D(^TMP("XM",$J,".")) D Z
  1. Q
  1. V ; Vaporize messages
  1. D VAPOR^XMJMOR(XMDUZ,XMK)
  1. D WAIT^XMXUTIL
  1. Q
  1. X ; Xmit priority toggle messages
  1. D XMTPRI^XMJMOR(XMDUZ,XMK)
  1. D WAIT^XMXUTIL
  1. Q
  1. Z ; Zoom toggle
  1. N I
  1. I XMZOOM D
  1. . S XMZOOM=0
  1. . S I=""
  1. . F S I=$O(XMFIRST(0,I)) Q:I="" S XMFIRST(I)=XMFIRST(0,I)
  1. . S XMPAGE=XMPAGE(0)
  1. E D
  1. . S XMZOOM=1
  1. . S I=""
  1. . F S I=$O(XMFIRST(I)) Q:I="" S XMFIRST(0,I)=XMFIRST(I)
  1. . S XMPAGE(0)=XMPAGE
  1. . S XMPAGE=0
  1. Q