Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: XMJMOR

XMJMOR.m

Go to the documentation of this file. 
  1. XMJMOR ;ISC-SF/GMB-Range actions ;12/04/2002  10:10
  1.  ;;8.0;MailMan;**9**;Jun 28, 2002
  1.  ; Replaces ^XMA0,^XMA01 (ISC-WASH/CAP)
  1. DELETE(XMDUZ,XMK) ; Delete a range of messages
  1.  N XMWHICH,XMMSG,XMABORT
  1.  S XMABORT=0
  1.  I $D(^TMP("XM",$J,".")) D
  1.  . D SELMSG^XMJMORX1(XMDUZ,0,0,XMK,"XDEL",34302,34303,.XMMSG,.XMABORT)
  1.  . ;K ^TMP("XM",$J,".")
  1.  E  D
  1.  . D WHICH(XMDUZ,XMK,34301,34303.1,.XMWHICH,.XMABORT) Q:XMABORT
  1.  . D DELMSG^XMXMSGS(XMDUZ,XMK,XMWHICH,.XMMSG)
  1.  . D:$D(XMERR) ZSHOW^XMJERR
  1.  Q:XMABORT
  1.  W:$D(XMMSG) !,XMMSG
  1.  Q
  1. FILTER(XMDUZ,XMK) ; Filter a range of messages
  1.  N XMWHICH,XMMSG,XMABORT
  1.  S XMABORT=0
  1.  I $D(^TMP("XM",$J,".")) D
  1.  . N XMKZ
  1.  . D SELMSG(XMDUZ,XMK,"XFLTR^XMXMSGS2",34306,.XMMSG)
  1.  . S XMKZ=""
  1.  . F  S XMKZ=$O(^TMP("XM",$J,".",XMKZ)) Q:'XMKZ  K:'$D(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ)) ^TMP("XM",$J,".",XMKZ)
  1.  E  D
  1.  . D WHICH(XMDUZ,XMK,34305,0,.XMWHICH,.XMABORT) Q:XMABORT
  1.  . D FLTRMSG^XMXMSGS(XMDUZ,XMK,XMWHICH,.XMMSG)
  1.  . D:$D(XMERR) ZSHOW^XMJERR
  1.  Q:XMABORT
  1.  W:$D(XMMSG) !,XMMSG
  1.  Q
  1. FORWARD(XMDUZ,XMK) ; Forward a range of messages
  1.  N XMWHICH,XMMSG,XMABORT,XMINSTR
  1.  S XMABORT=0
  1.  I $D(^TMP("XM",$J,".")) D  Q
  1.  . N XMKZ
  1.  . D INIT^XMXADDR
  1.  . S XMKZ=$O(^TMP("XM",$J,".",""))
  1.  . I '$O(^TMP("XM",$J,".",XMKZ)) D  Q
  1.  . . D FWDONE(XMDUZ,$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ,"")),.XMINSTR,.XMABORT)
  1.  . D TOWHOM^XMJMT(XMDUZ,$$EZBLD^DIALOG(34111),.XMINSTR,"",.XMABORT) Q:XMABORT  ; Forward
  1.  . D SELMSG(XMDUZ,XMK,"XFWD^XMXMSGS1",34309,.XMMSG)
  1.  . D CLEANUP^XMXADDR
  1.  . D:$D(XMERR) ZSHOW^XMJERR
  1.  . W:$D(XMMSG) !,XMMSG
  1.  D WHICH(XMDUZ,XMK,34308,0,.XMWHICH,.XMABORT) Q:XMABORT
  1.  D INIT^XMXADDR
  1.  I $P(XMWHICH,",",2,99)="",$P(XMWHICH,",",1)=+XMWHICH D  Q
  1.  . N XMZ
  1.  . S XMZ=$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",+XMWHICH,""))
  1.  . I 'XMZ W !,$$EZBLD^DIALOG(34309.3) Q  ; No messages forwarded.
  1.  . D FWDONE(XMDUZ,XMZ,.XMINSTR,.XMABORT)
  1.  D TOWHOM^XMJMT(XMDUZ,$$EZBLD^DIALOG(34111),.XMINSTR,"",.XMABORT) Q:XMABORT  ; Forward
  1.  S XMINSTR("ADDR FLAGS")="I"
  1.  D FWDMSG^XMXMSGS(XMDUZ,XMK,XMWHICH,"",.XMINSTR,.XMMSG)
  1.  D:$D(XMERR) ZSHOW^XMJERR
  1.  W:$D(XMMSG) !,XMMSG
  1.  Q
  1. FWDONE(XMDUZ,XMZ,XMINSTR,XMABORT) ; Forward just one message
  1.  N XMZREC,XMRESTR
  1.  S XMZREC=^XMB(3.9,XMZ,0)
  1.  I '$$FORWARD^XMXSEC(XMDUZ,XMZ,XMZREC) D SHOW^XMJERR Q
  1.  D GETRESTR^XMXSEC1(XMDUZ,XMZ,XMZREC,"",.XMRESTR) ; Get restrictions on the msg
  1.  D TOWHOM^XMJMT(XMDUZ,$$EZBLD^DIALOG(34111),.XMINSTR,.XMRESTR,.XMABORT) Q:XMABORT  ; Forward
  1.  D FWD^XMKP(XMDUZ,XMZ,.XMINSTR)
  1.  D CLEANUP^XMXADDR
  1.  W !,$$EZBLD^DIALOG(34309.2) ; Message forwarded.
  1.  Q
  1. LATER(XMDUZ,XMK) ; Later a range of messages
  1.  N XMWHICH,XMMSG,XMABORT,XMWHEN
  1.  S XMABORT=0
  1.  I $D(^TMP("XM",$J,".")) D
  1.  . D LTRDATE^XMJMD(.XMWHEN,.XMABORT) Q:XMABORT
  1.  . D SELMSG(XMDUZ,XMK,"XLATER^XMXMSGS2",34312,.XMMSG)
  1.  E  D
  1.  . D WHICH(XMDUZ,XMK,34311,0,.XMWHICH,.XMABORT) Q:XMABORT
  1.  . D LTRDATE^XMJMD(.XMWHEN,.XMABORT) Q:XMABORT
  1.  . D LATERMSG^XMXMSGS(XMDUZ,XMK,XMWHICH,XMWHEN,.XMMSG)
  1.  . D:$D(XMERR) ZSHOW^XMJERR
  1.  Q:XMABORT
  1.  W:$D(XMMSG) !,XMMSG
  1.  Q
  1. NEWTOGL(XMDUZ,XMK) ; New Toggle a range of messages
  1.  N XMWHICH,XMMSG,XMABORT
  1.  S XMABORT=0
  1.  I $D(^TMP("XM",$J,".")) D
  1.  . N XMKZ
  1.  . D SELMSG(XMDUZ,XMK,"XNTOGL^XMXMSGS2",34315,.XMMSG)
  1.  . S XMKZ=""
  1.  . F  S XMKZ=$O(^TMP("XM",$J,".",XMKZ)) Q:'XMKZ  K:'$D(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ)) ^TMP("XM",$J,".",XMKZ)
  1.  E  D
  1.  . D WHICH(XMDUZ,XMK,34314,0,.XMWHICH,.XMABORT) Q:XMABORT
  1.  . D NTOGLMSG^XMXMSGS(XMDUZ,XMK,XMWHICH,.XMMSG)
  1.  . D:$D(XMERR) ZSHOW^XMJERR
  1.  Q:XMABORT
  1.  W:$D(XMMSG) !,XMMSG
  1.  Q
  1. PRINT(XMDUZ,XMK,XMPRTHDR) ; Print a range of messages
  1.  N XMWHICH,XMMSG,XMRECIPS,XMABORT
  1.  ; XMPRTHDR 1=Print header
  1.  ;          0=don't (headerless print)
  1.  ; XMRECIPS 0=Don't print recipients
  1.  ;          1=Print summary recipients
  1.  ;          2=Print detail recipients
  1.  N XMSAVE,XMMSG,XMZLIST,I
  1.  S XMABORT=0
  1.  S:$G(XMPRTHDR)="" XMPRTHDR=1  ; default is to print with headers
  1.  I $D(^TMP("XM",$J,".")) D
  1.  . D LISTSEL(XMDUZ,XMK,.XMZLIST)
  1.  E  D  Q:XMABORT
  1.  . N XMWHICH
  1.  . D WHICH(XMDUZ,XMK,$S(XMPRTHDR:34317,1:34317.1),0,.XMWHICH,.XMABORT) Q:XMABORT
  1.  . D LIST(XMDUZ,XMK,.XMWHICH,.XMZLIST)
  1.  I '$D(XMZLIST) W !!,$$EZBLD^DIALOG(34319) Q  ; No valid messages selected.
  1.  I +XMZLIST(1)=XMZLIST(1) D PRTONE(XMDUZ,XMK,XMZLIST(1),XMPRTHDR,.XMABORT) Q
  1.  D QRECIP^XMJMP(.XMRECIPS,.XMABORT) Q:XMABORT
  1.  F I="DUZ","XMDUZ","XMV(","XMZLIST(","XMRECIPS","XMPRTHDR" S XMSAVE(I)=""
  1.  D EN^XUTMDEVQ("PLISTX^XMJMP",$$EZBLD^DIALOG(34501),.XMSAVE) ; MailMan: Print
  1.  Q:XMABORT!$G(POP)
  1.  W:$D(XMMSG) !!,XMMSG
  1.  Q
  1. LISTSEL(XMDUZ,XMK,XMZLIST) ;
  1.  N XMKZ,J,XMZ
  1.  S (XMKZ,J)=0
  1.  F  S XMKZ=$O(^TMP("XM",$J,".",XMKZ)) Q:'XMKZ  D
  1.  . S XMZ=$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ,"")) Q:'XMZ
  1.  . I J=0 S J=1,XMZLIST(1)=XMZ Q
  1.  . I $L(XMZLIST(J))+$L(XMZ)>240 S J=J+1,XMZLIST(J)=XMZ Q
  1.  . S XMZLIST(J)=XMZLIST(J)_","_XMZ
  1.  Q
  1. LIST(XMDUZ,XMK,XMWHICH,XMZLIST) ;
  1.  N I,J,XMRANGE,XMKZ,XMZ,XMLAST
  1.  S J=0
  1.  F I=1:1:$L(XMWHICH,",") D
  1.  . S XMRANGE=$P(XMWHICH,",",I)
  1.  . Q:'XMRANGE
  1.  . S XMKZ=$P(XMRANGE,"-",1)-.1
  1.  . S XMLAST=$S(XMRANGE["-":$P(XMRANGE,"-",2),1:XMRANGE)
  1.  . F  S XMKZ=$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ)) Q:'XMKZ!(XMKZ>XMLAST)  D
  1.  . . S XMZ=$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ,"")) Q:'XMZ
  1.  . . I J=0 S J=1,XMZLIST(1)=XMZ Q
  1.  . . I $L(XMZLIST(J))+$L(XMZ)>240 S J=J+1,XMZLIST(J)=XMZ Q
  1.  . . S XMZLIST(J)=XMZLIST(J)_","_XMZ
  1.  Q
  1. PRTONE(XMDUZ,XMK,XMZ,XMPRTHDR,XMABORT) ;
  1.  D PONE^XMJMP(XMDUZ,XMK,XMZ,XMPRTHDR,.XMABORT)
  1.  W !!,$$EZBLD^DIALOG($S(XMABORT:34318.4,1:34318.1)) ; Message (not) printed.
  1.  Q
  1. SAVE(XMDUZ,XMK) ; Save a range of messages to another basket
  1.  N XMWHICH,XMMSG,XMABORT,XMKTO,XMDIC
  1.  S XMABORT=0
  1.  S XMDIC("B")="@"  ; no default basket
  1.  I $D(^TMP("XM",$J,".")) D
  1.  . D SELBSKT^XMJBU(XMDUZ,$$EZBLD^DIALOG(34325),"L",.XMDIC,.XMKTO) ; Save messages to which basket?
  1.  . I XMKTO=U S XMMSG=$$EZBLD^DIALOG(34324.3) Q  ; No messages saved.
  1.  . I XMKTO=XMK S XMMSG=$$EZBLD^DIALOG(34326) Q  ; Same basket.  No messages saved.
  1.  . D SELMSG(XMDUZ,XMK,"XMOVE^XMXMSGS2",34324,.XMMSG)
  1.  . K ^TMP("XM",$J,".")
  1.  E  D
  1.  . D WHICH(XMDUZ,XMK,34323,0,.XMWHICH,.XMABORT) Q:XMABORT
  1.  . D SELBSKT^XMJBU(XMDUZ,$$EZBLD^DIALOG(34325),"L",.XMDIC,.XMKTO) ; Save messages to which basket?
  1.  . I XMKTO=U S XMMSG=$$EZBLD^DIALOG(34324.3) Q  ; No messages saved.
  1.  . I XMKTO=XMK S XMMSG=$$EZBLD^DIALOG(34326) Q  ; Same basket.  No messages saved.
  1.  . D MOVEMSG^XMXMSGS(XMDUZ,XMK,XMWHICH,XMKTO,.XMMSG)
  1.  . D:$D(XMERR) ZSHOW^XMJERR
  1.  Q:XMABORT
  1.  W:$D(XMMSG) !,XMMSG
  1.  Q
  1. TERM(XMDUZ,XMK) ; Terminate a range of messages
  1.  N XMWHICH,XMMSG,XMABORT
  1.  S XMABORT=0
  1.  I $D(^TMP("XM",$J,".")) D
  1.  . D SELMSG^XMJMORX1(XMDUZ,0,0,XMK,"XTERM",34329,34330,.XMMSG,.XMABORT)
  1.  . ;K ^TMP("XM",$J,".")
  1.  E  D
  1.  . D WHICH(XMDUZ,XMK,34328,34330.1,.XMWHICH,.XMABORT) Q:XMABORT
  1.  . D TERMMSG^XMXMSGS(XMDUZ,XMK,XMWHICH,.XMMSG)
  1.  . D:$D(XMERR) ZSHOW^XMJERR
  1.  Q:XMABORT
  1.  Q:'$D(XMMSG)
  1.  W !,XMMSG
  1.  I XMMSG W !,$$EZBLD^DIALOG($S(XMK<1:34331.1,1:34331)) ; You won't see future responses.  (In WASTE basket)
  1.  Q
  1. VAPOR(XMDUZ,XMK) ; Set Vaporize date for a range of messages
  1.  N XMWHICH,XMMSG,XMABORT,XMWHEN
  1.  S XMABORT=0
  1.  I $D(^TMP("XM",$J,".")) D
  1.  . D VAPRDATE(.XMWHEN,.XMABORT) Q:XMABORT
  1.  . D SELMSG^XMJMORX1(XMDUZ,0,0,XMK,"XVAPOR^XMXMSGS2",$S(XMWHEN="@":34337.2,1:34337),$S(XMWHEN="@":34338.2,1:34338),.XMMSG,.XMABORT)
  1.  E  D
  1.  . D VAPRDATE(.XMWHEN,.XMABORT) Q:XMABORT
  1.  . D WHICH(XMDUZ,XMK,$S(XMWHEN="@":34336.1,1:34336),$S(XMWHEN="@":34338.3,1:34338.1),.XMWHICH,.XMABORT) Q:XMABORT
  1.  . D VAPORMSG^XMXMSGS(XMDUZ,XMK,XMWHICH,XMWHEN,.XMMSG)
  1.  . D:$D(XMERR) ZSHOW^XMJERR
  1.  Q:XMABORT
  1.  W:$D(XMMSG) !,XMMSG
  1.  Q
  1. VAPRDATE(XMWHEN,XMABORT) ;
  1.  N DIR,X,Y
  1.  S DIR(0)="DO^NOW::EFT"
  1.  D BLD^DIALOG(37317.1,"","","DIR(""A"")")
  1.  D BLD^DIALOG(34339,"","","DIR(""?"")")
  1.  D ^DIR
  1.  I X="@" S XMWHEN="@" Q
  1.  I $D(DIRUT) S XMABORT=1 Q
  1.  S XMWHEN=Y
  1.  Q
  1. XMTPRI(XMDUZ,XMK) ; Toggle transmission priority for a range of msgs
  1.  ; XMDUZ better be .5 and XMK better be > 999!
  1.  N XMTPRI,XMWHICH,XMMSG,XMABORT
  1.  S XMABORT=0
  1.  I $D(^TMP("XM",$J,".")) D
  1.  . D ASKPRI^XMJMORX(.XMTPRI,.XMABORT) Q:XMABORT
  1.  . D SELMSG^XMJMORX1(XMDUZ,0,0,XMK,"XXP^XMXMSGS1",34334,34335,.XMMSG,.XMABORT)
  1.  E  D
  1.  . D WHICH(XMDUZ,XMK,34333,34335.1,.XMWHICH,.XMABORT) Q:XMABORT
  1.  . D ASKPRI^XMJMORX(.XMTPRI,.XMABORT) Q:XMABORT
  1.  . D XPMSG^XMXMSGS(XMDUZ,XMK,XMWHICH,XMTPRI,.XMMSG)
  1.  . D:$D(XMERR) ZSHOW^XMJERR
  1.  Q:XMABORT
  1.  W:$D(XMMSG) !,XMMSG
  1.  Q
  1. WHICH(XMDUZ,XMK,XMPROMPT,XMCONFRM,XMWHICH,XMABORT) ;
  1.  N DIR,X,Y,XMHI,XMLO
  1.  S XMLO=$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",""))
  1.  S XMHI=$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",""),-1)
  1.  S DIR("A")=$$EZBLD^DIALOG(XMPROMPT) ; ... which messages?
  1.  S DIR("??")="XM-U-M-CHOOSE RANGE"
  1.  S DIR(0)="LC^"_XMLO_":"_XMHI
  1.  D ^DIR I $D(DIRUT) S XMABORT=1 Q
  1.  S XMWHICH=Y
  1.  I XMCONFRM D CONFIRM(XMCONFRM,.XMABORT)
  1.  Q
  1. CONFIRM(XMCONFRM,XMABORT) ;
  1.  N DIR
  1.  D BLD^DIALOG(XMCONFRM,"","","DIR(""A"")") ; Do you really want to ... these messages?
  1.  S DIR("B")=$$EZBLD^DIALOG(39053) ; No
  1.  S DIR(0)="Y"
  1.  D ^DIR I $D(DIRUT)!'Y S XMABORT=1
  1.  Q
  1. POSTPRIV() ;
  1.  Q:$$POSTPRIV^XMXSEC 1
  1.  D SHOW^XMJERR
  1.  Q 0
  1. SELMSG(XMDUZ,XMK,XMRTN,XMSUM,XMMSG) ;
  1.  N XMCNT,XMKZ,XMZ,XMKALL
  1.  S (XMCNT,XMKZ)=0
  1.  F  S XMKZ=$O(^TMP("XM",$J,".",XMKZ)) Q:'XMKZ  D
  1.  . S XMZ=$O(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ,"")) Q:'XMZ
  1.  . D @XMRTN
  1.  S XMMSG=$$EZBLD^DIALOG($S(XMCNT=1:XMSUM+.1,1:XMSUM),XMCNT)
  1.  D INCRDECR^XMXMSGS(XMDUZ,.XMCNT)
  1.  Q