Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: XMXPARM1

XMXPARM1.m

Go to the documentation of this file.
  1. XMXPARM1 ;ISC-SF/GMB-Parameter check (cont.) ;04/19/2002 12:14
  1. ;;8.0;MailMan;**36**;Jun 28, 2002
  1. CHKUSER(XMDUZ,XMNOMBOX) ; Ascertain/verify user's DUZ, and make sure authorized to use MailMan
  1. ; XMNOMBOX Is it possible that this user does not have a mailbox?
  1. ; 0=no (default); 1=yes
  1. N XMSCREEN,XMUSER,XMADDR
  1. S XMADDR=XMDUZ
  1. S XMADDR=$$UP^XLFSTR(XMADDR)
  1. ;S:'$G(XMNOMBOX) XMSCREEN="I $L($P(^(0),U,3)),$D(^XMB(3.7,+Y,2))" ; User must have an access code & mailbox
  1. I '$G(XMNOMBOX),'$$USERTYPE^XUSAP(XMDUZ,"APPLICATION PROXY") S XMSCREEN="I $L($P(^(0),U,3)),$D(^XMB(3.7,+Y,2))" ; User must have an access code & mailbox
  1. ; "B^BB^C^D" = name^alias^initial^nickname
  1. S XMDUZ=$$FIND1^DIC(200,"","O",$S(+XMADDR=XMADDR:"`"_XMADDR,1:XMADDR),"B^BB^C^D",.XMSCREEN)
  1. Q:XMDUZ
  1. S XMDUZ=XMADDR
  1. D ERRSET^XMXUTIL($S($D(DIERR):39432,1:39433),XMDUZ) ; User '|1|' ambiguous / not found.
  1. Q
  1. XMATTACH(XMATTACH) ; Validate attachments
  1. Q
  1. XMBN(XMBN) ; Check bulletin name
  1. I $G(XMBN)="" D ERRSET^XMXUTIL(39430) Q ; Bulletin name must be supplied.
  1. Q:$D(^XMB(3.6,"B",XMBN))
  1. D ERRSET^XMXUTIL(39431,XMBN) ; Bulletin '|1|' not found.
  1. Q
  1. XMBODY(XMBODY,XMOPTNL) ; Check the body of the message (just make sure there is a body)
  1. I $G(XMBODY)="" D Q
  1. . I '$G(XMOPTNL) D ERRSET^XMXUTIL(39405) ;Message must have a body.
  1. I $E(XMBODY,1,6)="XMBODY" D Q
  1. . D ERRSET^XMXUTIL(39406) ;Message body may not be called XMBODY.
  1. I $D(@XMBODY)'>9 D Q
  1. . D ERRSET^XMXUTIL(39407,XMBODY) ;Message body '|1|' has no data.
  1. Q
  1. XMCODE(XMPARM,XMCODE,XMSET) ;
  1. Q:XMSET[(U_XMCODE_U)
  1. N XMP
  1. S XMP("PARAM","ID")=XMPARM
  1. S XMP("PARAM","VALUE")=XMCODE
  1. ;S XMP("PARAM","FILE")=3.901,XMP("PARAM","FIELD")=1.8
  1. S XMP(1)=XMSET
  1. D ERRSET^XMXUTIL(39438,.XMP) ; Must be one of |1|.
  1. Q
  1. XMHINT(XMHINT) ; Validate a scramble hint
  1. I $G(XMHINT)="" Q
  1. ;I $G(XMHINT)="" D ERRSET^XMXUTIL(39436) Q ; Scramble hint must be supplied
  1. ;D CHK^DIE(3.9,1.8,"H",XMHINT)
  1. I $L(XMHINT)>0,$L(XMHINT)<41,XMHINT'[U Q
  1. N XMP
  1. S XMP("PARAM","ID")="XMINSTR(""SCR HINT"")"
  1. S XMP("PARAM","VALUE")=XMHINT
  1. ;S XMP("PARAM","FILE")=3.901,XMP("PARAM","FIELD")=1.8
  1. S XMP(1)=1,XMP(2)=40
  1. D ERRSET^XMXUTIL(39437,.XMP) ; Must be |1|-|2| characters, no ^.
  1. Q
  1. XMKEY(XMKEY) ; Validate a scramble key
  1. I $G(XMKEY)="" D ERRSET^XMXUTIL(39435) Q ; Scramble key must be supplied.
  1. ;D CHK^DIE(3.9,1.85,"H",XMKEY)
  1. I $L(XMKEY)>2,$L(XMKEY)<21 Q
  1. N XMP
  1. S XMP("PARAM","ID")="XMINSTR(""SCR KEY"")"
  1. S XMP("PARAM","VALUE")=XMKEY
  1. ;S XMP("PARAM","FILE")=3.9,XMP("PARAM","FIELD")=1.85
  1. S XMP(1)=3,XMP(2)=20
  1. D ERRSET^XMXUTIL(39434,.XMP) ; Must be |1|-|2| characters.
  1. Q
  1. XMKZ(XMK,XMKZ) ;
  1. I $G(XMKZ),$D(^XMB(3.7,XMDUZ,2,XMK,1,"C",XMKZ)) Q
  1. N XMP S XMP(1)=XMKZ,XMP(2)=XMK
  1. D ERRSET^XMXUTIL(34351,.XMP) ; message not found in basket
  1. Q
  1. XMKZA(XMKZA) ; Check the message numbers (just make sure there is at least one)
  1. Q:$D(XMKZA)
  1. D ERRSET^XMXUTIL(39418) ;No message numbers.
  1. Q
  1. XMROOT(XMPARM,XMROOT) ; Validate root
  1. Q
  1. XMSTRIP(XMSTRIP) ; Validate a message strip string
  1. I $L(XMSTRIP)>0,$L(XMSTRIP)<21 Q
  1. N XMP
  1. S XMP("PARAM","ID")="XMINSTR(""STRIP"")"
  1. S XMP("PARAM","VALUE")=XMSTRIP
  1. S XMP(1)=1,XMP(2)=20
  1. D ERRSET^XMXUTIL(39434,.XMP) ; Must be |1|-|2| characters.
  1. Q
  1. XMTO(XMTO,XMOPTNL) ; Check the addressees (just make sure there is at least one)
  1. Q:$D(XMTO)
  1. I $G(XMOPTNL),$$GOTADDR^XMXADDR Q
  1. D ERRSET^XMXUTIL(39408) ;No recipients
  1. Q