Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: XMXTO

XMXTO.m

Go to the documentation of this file. 
  1. XMXTO ;ISC-SF/GMB-Address a msg ;08/08/2000  14:38
  1.  ;;8.0;MailMan;;Jun 28, 2002
  1.  ; Entry points:
  1.  ; ITOWHOM  Interactive 'to whom:'
  1.  ; TOWHOM   Silent 'to whom:'
  1. ITOWHOM(XMDUZ,XMZ,XMTYPE,XMINSTR) ; Interactive
  1.  ; XMDUZ             DUZ of who is sending or forwarding the message
  1.  ; XMZ               The message number
  1.  ;                   (need not be supplied if XMTYPE="S" and
  1.  ;                   XMINSTR("ADDR FLAGS")["R")
  1.  ; XMTYPE            S='Send to:'
  1.  ;                   F='Forward to:'
  1.  ; XMINSTR("SELF BSKT") Basket to deliver to if sender is recipient
  1.  ; XMINSTR("SHARE DATE") Delete date if recipient is "SHARED,MAIL"
  1.  ; XMINSTR("SHARE BSKT") Basket if recipient is "SHARED,MAIL"
  1.  ; XMINSTR("TO PROMPT") Initial prompt to whom to send the message (default=XMDUZ)
  1.  ; XMINSTR("FLAGS")  Any or all or none of the following:
  1.  ;                   (Necessary only if XMTYPE="S" and XMINSTR("ADDR FLAGS")["R")
  1.  ;                   X Closed msg (may not be forwarded)
  1.  ;                   C Confidential msg (surrogates may not read)
  1.  ; XMINSTR("ADDR FLAGS")   Any or all of the following:
  1.  ;                   I Do not Initialize (kill) the ^TMP addressee global
  1.  ;                   R Do not Restrict addressees
  1.  N XMRESTR,XMABORT
  1.  K XMERR,^TMP("XMERR",$J)
  1.  D INIT(XMDUZ,.XMZ,XMTYPE,.XMINSTR,.XMRESTR,.XMPROMPT) Q:$D(XMERR)
  1.  S XMABORT=0
  1.  D TOWHOM^XMJMT(XMDUZ,XMPROMPT,.XMINSTR,.XMRESTR,.XMABORT)
  1.  Q:'XMABORT
  1.  D ERRSET^XMXUTIL($S(XMABORT=1:37000,1:37001)) ; up-arrow out. / time out.
  1.  Q
  1. TOWHOM(XMDUZ,XMZ,XMTYPE,XMTO,XMINSTR,XMFULL) ; Silent
  1.  ; XMDUZ       (in)  DUZ of who is sending or forwarding the message
  1.  ; XMZ         (in)  The message number
  1.  ;                   (need not be supplied if XMTYPE="S" and
  1.  ;                   XMINSTR("ADDR FLAGS")["R")
  1.  ; XMTYPE      (in)  S='Send to:'
  1.  ;                   F='Forward to:'
  1.  ; XMTO        (in)  ONE addressee
  1.  ; XMINSTR("SELF BSKT")  (in) Basket to deliver to if sender is recipient
  1.  ; XMINSTR("SHARE DATE") (in) Delete date if recipient is "SHARED,MAIL"
  1.  ; XMINSTR("SHARE BSKT") (in) Basket if recipient is "SHARED,MAIL"
  1.  ; XMINSTR("FLAGS")      (in) Any or all or none of the following:
  1.  ;                   (Necessary only if XMTYPE="S" and XMINSTR("ADDR FLAGS")["R")
  1.  ;                   X Closed msg (may not be forwarded)
  1.  ;                   C Confidential msg (surrogates may not read)
  1.  ; XMINSTR("ADDR FLAGS")   Any or all of the following:
  1.  ;                   I Do not Initialize (kill) the ^TMP addressee global
  1.  ;                   R Do not Restrict addressees
  1.  ; XMFULL      (out) the full address
  1.  N XMRESTR
  1.  K XMERR,^TMP("XMERR",$J)
  1.  D INIT(XMDUZ,.XMZ,XMTYPE,.XMINSTR,.XMRESTR) Q:$D(XMERR)
  1.  D CHKADDR^XMXADDR(XMDUZ,.XMTO,.XMINSTR,.XMRESTR,.XMFULL)
  1.  Q
  1. INIT(XMDUZ,XMZ,XMTYPE,XMINSTR,XMRESTR,XMPROMPT) ;
  1.  I XMTYPE="S" D
  1.  . S XMPROMPT=$$EZBLD^DIALOG(34110) ; Send
  1.  . D:$G(XMINSTR("ADDR FLAGS"))'["R" CHKLINES^XMXSEC1(XMDUZ,XMZ,.XMRESTR)
  1.  E  D
  1.  . N XMZREC
  1.  . S XMZREC=^XMB(3.9,XMZ,0)
  1.  . S XMPROMPT=$$EZBLD^DIALOG(34111) ; Forward
  1.  . Q:'$$FORWARD^XMXSEC(XMDUZ,XMZ,XMZREC)
  1.  . D:$G(XMINSTR("ADDR FLAGS"))'["R" GETRESTR^XMXSEC1(XMDUZ,XMZ,XMZREC,.XMINSTR,.XMRESTR)
  1.  D:$G(XMINSTR("ADDR FLAGS"))'["I" INIT^XMXADDR
  1.  Q