Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: XOBWUA

XOBWUA.m

Go to the documentation of this file. 
  1. XOBWUA ;OAK/KEC - HWSC :: Web Server Lookup Key Manager ; 09/13/10 4:00pm
  1.  ;;1.0;HwscWebServiceClient;;September 13, 2010;Build 31
  1.  ;
  1.  QUIT
  1.  ;
  1. EN ; -- main entry point for XOBW WEB SERVER LOOKUPKEY
  1.  NEW XOBSORT,XOBKFILT,XOBSFILT,X
  1.  SET XOBSORT="K" ; default sort by KEY
  1.  SET XOBKFILT=""
  1.  SET XOBSFILT=""
  1.  DO KILL
  1.  SET VALMBCK=""
  1.  DO EN^VALM("XOBW WEB SERVER LOOKUPKEY")
  1.  QUIT
  1.  ;
  1. HDR ; -- header code
  1.  SET X="                  HWSC Web Server Lookup Key Manager"
  1.  SET VALMHDR(1)=X
  1.  SET X="                      Version: "_$PIECE($TEXT(XOBWUA+1),";",3)_"     Build: "_$$VERSION^XOBWENV()
  1.  SET VALMHDR(2)=X
  1.  SET X=$SELECT(XOBSFILT]"":XOBSFILT,1:"<no filter>")
  1.  SET VALMHDR(3)="Filters:  Key = "_$SELECT(XOBKFILT]"":XOBKFILT,1:"<no filter>")_"   Server = "_X
  1.  QUIT
  1.  ;
  1. CHGCAP ; -- change captions to indicate sort
  1.  NEW KEYCAP,SRVCAP
  1.  SET KEYCAP="Lookup Key Name"
  1.  SET SRVCAP="Web Server Name"
  1.  IF XOBSORT="K" DO
  1.  . DO CHGCAP^VALM("KEY",KEYCAP_" [Sorted By]")
  1.  . DO CHGCAP^VALM("SERVER",SRVCAP)
  1.  ELSE  DO
  1.  . DO CHGCAP^VALM("SERVER",SRVCAP_" [Sorted By]")
  1.  . DO CHGCAP^VALM("KEY",KEYCAP)
  1.  QUIT
  1.  ;
  1. INIT ; -- init variables and list array
  1.  DO CLEAR
  1.  DO MSG
  1.  DO CHGCAP
  1.  QUIT
  1.  ;
  1. MSG ; -- set default message
  1.  SET VALMSG=""
  1.  QUIT
  1.  ;
  1. BUILD ; -- build list
  1.  NEW I,XOBI,XOB0,X,XOBDATA,XOBROOT,XOBSITEI,Y,SORT,XOBX,XOBKEY,XOBSRVR
  1.  DO KILL
  1.  ;
  1.  SET VALMCNT=0
  1.  SET XOBROOT=$NAME(XOBDATA("DILIST","ID"))
  1.  DO LIST^DIC(18.13,"",".01;.03","","","","","","","",$NAME(XOBDATA))
  1.  ; -- build sort
  1.  SET XOBI=0
  1.  FOR  SET XOBI=$ORDER(@XOBROOT@(XOBI)) QUIT:'XOBI  DO
  1.  . SET XOBX=$SELECT(XOBSORT="S":$GET(@XOBROOT@(XOBI,.03)),1:$GET(@XOBROOT@(XOBI,.01)))
  1.  . SET SORT($SELECT(XOBX="":" ",1:XOBX),XOBI)=""
  1.  ; -- build list off sort and apply filters
  1.  SET XOBX=""
  1.  FOR  SET XOBX=$ORDER(SORT(XOBX)) QUIT:XOBX=""  DO
  1.  . SET XOBI=0
  1.  . FOR  SET XOBI=$ORDER(SORT(XOBX,XOBI)) QUIT:'XOBI  DO
  1.  . . SET XOBKEY=$GET(@XOBROOT@(XOBI,.01))
  1.  . . SET XOBSRVR=$GET(@XOBROOT@(XOBI,.03))
  1.  . . IF XOBSRVR="" SET XOBSRVR=$$NOTDEF()
  1.  . . IF XOBKFILT]"",$EXTRACT(XOBKEY,1,$LENGTH(XOBKFILT))'=XOBKFILT QUIT
  1.  . . IF XOBSFILT]"",$$UP^XLFSTR($EXTRACT(XOBSRVR,1,$LENGTH(XOBSFILT)))'=$$UP^XLFSTR(XOBSFILT) QUIT
  1.  . . SET VALMCNT=VALMCNT+1
  1.  . . SET X=""
  1.  . . SET X=$$SETFLD^VALM1(VALMCNT,X,"ID")
  1.  . . SET X=$$SETFLD^VALM1(XOBKEY,X,"KEY")
  1.  . . SET X=$$SETFLD^VALM1(XOBSRVR,X,"SERVER")
  1.  . . DO SET^VALM10(VALMCNT,X,VALMCNT)
  1.  . . SET ^TMP("XOB WEB SERVER LOOKUP","IDX",$JOB,VALMCNT,VALMCNT)=+$GET(XOBDATA("DILIST",2,XOBI))
  1.  ;
  1.  QUIT
  1.  ;
  1. NOTDEF() ; -- constant text to use if server is not defined
  1.  QUIT "<server not defined>"
  1.  ;
  1. CLEAR ; -- clean up entries
  1.  DO REFRESH
  1.  QUIT
  1.  ;
  1. REFRESH ; -- refresh display
  1.  DO BUILD
  1.  SET VALMBCK="R"
  1.  QUIT
  1.  ;
  1. KILL ; -- kill off list location
  1.  KILL ^TMP("XOB WEB SERVER LOOKUP",$JOB)
  1.  KILL ^TMP("XOB WEB SERVER LOOKUP","XOB",$JOB)
  1.  QUIT
  1.  ;
  1. HELP ; -- help code
  1.  SET X="?" DO DISP^XQORM1 WRITE !!
  1.  QUIT
  1.  ;
  1. EXIT ; -- exit code
  1.  QUIT
  1.  ;
  1. ADD ; -- add a web server lookup identifier entry
  1.  ; -- Protocol: XOBW ASSOCIATE ADD
  1.  DO ACTION("ADD",0)
  1.  QUIT
  1.  ;
  1. EDIT ; -- edit a web server lookup identifier entry
  1.  ; -- Protocol: XOBW ASSOCIATE EDIT
  1.  DO ACTION("EDIT",0)
  1.  QUIT
  1.  ;
  1. DEL ; -- delete web server lookup identifier entry
  1.  ; -- Protocol: XOBW ASSOCIATE DELETE
  1.  DO ACTION("DEL",0)
  1.  QUIT
  1.  ;
  1. EXPAND ; -- expand web server lookup identifier entry
  1.  DO ACTION("EXPAND",1)
  1.  QUIT
  1.  ;
  1. SORT ; -- sort list
  1.  ; -- Protocol: XOBW ASSOCIATE SORT
  1.  DO ACTION("SORT",0)
  1.  DO HDR
  1.  DO CHGCAP
  1.  QUIT
  1.  ;
  1. KFILTER ; -- specify look up key filter
  1.  ; -- Protocol: XOBW ASSOCIATE FILTER KEY
  1.  DO ACTION("KFILTER",0)
  1.  DO HDR
  1.  QUIT
  1.  ;
  1. SFILTER ; -- specify web server filter
  1.  ; -- Protocol: XOBW ASSOCIATE FILTER SERVER
  1.  DO ACTION("SFILTER",0)
  1.  DO HDR
  1.  QUIT
  1.  ;
  1. ACTION(TYPE,XOBPAUSE) ; -- execute action
  1.  DO FULL^VALM1
  1.  NEW X,Y
  1.  SET X="DO "_TYPE_"^XOBWUA1"
  1.  XECUTE X
  1.  IF XOBPAUSE DO PAUSE^VALM1
  1.  DO REFRESH
  1.  DO MSG
  1.  QUIT
  1.  ;