Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: XTVSLPC

XTVSLPC.m

Go to the documentation of this file. 
  1. XTVSLPC ;ALBANY FO/GTS - VistA Package Sizing Manager; 17-NOV-2016
  1.  ;;7.3;TOOLKIT;**143,152**;Apr 25, 1995;Build 3
  1.  ;Per VA Directive 6402, this routine should not be modified.
  1.  ;
  1. EN(CMPRFNME) ; -- main entry point for XTVS PKG MGR PARAM COMPARE
  1.  ; Input: CMPRFNME - File to compare Selected XTMPSIZE.DAT file
  1.  ;        XTVPSPRM - Selected/Displayed Parameter file [Partition variable set by INIT^XTVSLP]
  1.  ;
  1.  IF CMPRFNME'["XTMPSIZE" DO  QUIT
  1.  . DO JUSTPAWS^XTVSLAPI("Comparison XTMPSIZE.DAT file NOT selected!")
  1.  ;
  1.  D EN^VALM("XTVS PKG MGR PARAM COMPARE")
  1.  Q
  1.  ;
  1. HDR ; -- header code
  1.  NEW DEFDIR,SPCPAD,DIRHEAD
  1.  SET SPCPAD=""
  1.  SET DEFDIR=$$GET^XPAR("SYS","XTVS PACKAGE MGR DEFAULT DIR",1,"I")
  1.  SET VALMHDR(1)="           VistA Package Size Analysis Manager - Parameter Compare"
  1.  SET VALMHDR(2)="                         Version: "_$$VERNUM^XTVSLM()_"     Build: "_$$BLDNUM^XTVSLM()
  1.  SET DIRHEAD="Default Directory: "_DEFDIR
  1.  SET $P(SPCPAD," ",(80-$L(DIRHEAD))/2)=""
  1.  SET VALMHDR(3)=SPCPAD_DIRHEAD
  1.  SET SPCPAD=""
  1.  SET DIRHEAD="Selected file [SEL]: "_XTVPSPRM
  1.  SET $P(SPCPAD," ",(80-$L(DIRHEAD))/2)=""
  1.  SET VALMHDR(4)=SPCPAD_DIRHEAD
  1.  SET DIRHEAD="Comparison file [CPR]: "_CMPRFNME
  1.  SET $P(SPCPAD," ",(80-$L(DIRHEAD))/2)=""
  1.  SET VALMHDR(5)=SPCPAD_DIRHEAD
  1.  QUIT
  1.  ;
  1. INIT ; - Build Selected and Comparison XTMPSIZE parameter arrays
  1.  NEW DEFDIR,NODENUM,NODECUR,CURNDNM,CPRNDNM,PKGRPTD,PKGDEL,DELSTATE
  1.  DO KILL ;Kill all processing & data arrays and video attributes & control arrays
  1.  SET DEFDIR=$$GET^XPAR("SYS","XTVS PACKAGE MGR DEFAULT DIR",1,"I")
  1.  ;
  1.  ;Build Selected XTMPSIZE parameter array
  1.  DO OPEN^%ZISH("XTMP",DEFDIR,XTVPSPRM,"R")
  1.  U IO
  1.  SET NODENUM=0
  1.  FOR  S LINEITEM="" READ LINEITEM:5 Q:$$STATUS^%ZISH  DO
  1.  . IF LINEITEM]"" DO
  1.  .. SET NODENUM=NODENUM+1
  1.  .. SET ^TMP("XTVS CUR PARAM",$JOB,NODENUM)=LINEITEM ;Creates ^TMP("XTVS CUR PARAM",$JOB) array
  1.  D CLOSE^%ZISH("XTMP")
  1.  ;
  1.  ;Build comparison XTMPSIZE parameter array
  1.  DO OPEN^%ZISH("XTMP2",DEFDIR,CMPRFNME,"R")
  1.  U IO
  1.  SET NODENUM=0
  1.  FOR  S LINEITEM="" READ LINEITEM:5 Q:$$STATUS^%ZISH  DO
  1.  . IF LINEITEM]"" DO
  1.  .. SET NODENUM=NODENUM+1
  1.  .. SET ^TMP("XTVS CPR PARAM",$JOB,NODENUM)=LINEITEM ;Creates ^TMP("XTVS CPR PARAM",$JOB) array
  1.  D CLOSE^%ZISH("XTMP2")
  1.  ;
  1.  ;Create ^TMP("XTVS PKG MAN PARM COMPARE",$JOB) comparison result array for ListMan display
  1.  SET (PKGRPTD,VALMCNT)=0
  1.  ;
  1.  DO ADD^XTVSLAPI(.VALMCNT," ")
  1.  DO ADD^XTVSLAPI(.VALMCNT,"CHANGED PACKAGES",1,1,16) ;Output Header for Changed Package list
  1.  ;Loop through each "Selected" (latest) Package Lineitem
  1.  SET CURNDNM=0
  1.  FOR  SET CURNDNM=$O(^TMP("XTVS CUR PARAM",$JOB,CURNDNM)) QUIT:CURNDNM=""  SET NODECUR=^TMP("XTVS CUR PARAM",$JOB,CURNDNM) DO
  1.  . SET DELSTATE=0
  1.  . IF NODECUR=$G(^TMP("XTVS CPR PARAM",$JOB,CURNDNM)) DO DELPKG(CURNDNM,CURNDNM) SET DELSTATE=1 ;;Remove unedited package from CPR & CUR globals
  1.  . IF (NODECUR'=$G(^TMP("XTVS CPR PARAM",$JOB,CURNDNM))),('DELSTATE) DO  ;;If Selected Package '= same node on Compare Package lineitem
  1.  .. SET (PKGDEL,CPRNDNM)=0
  1.  .. FOR  SET CPRNDNM=$O(^TMP("XTVS CPR PARAM",$JOB,CPRNDNM)) QUIT:CPRNDNM=""  QUIT:PKGDEL  DO COMPARE(CPRNDNM,NODECUR,.VALMCNT,.PKGDEL,.PKGRPTD)
  1.  IF PKGRPTD=0 DO
  1.  . DO ADD^XTVSLAPI(.VALMCNT," No edited packages!")
  1.  ;
  1.  DO ADDDELRP("CUR",.VALMCNT) ;Report packages added new to Selected package extract
  1.  DO ADDDELRP("CPR",.VALMCNT) ;Report packages deleted from Selected package extract
  1.  SET PKGRPTD=0
  1.  D MSG
  1.  ;
  1.  QUIT
  1.  ;
  1. COMPARE(CPRNDNM,NODECUR,VALMCNT,PKGDEL,PKGRPTD) ; Compare Selected & Comparison parameter files, report diff's and cleanup ^TMP globals
  1.  NEW NODECPR,CURPKG,CPRPKG,FNDCHG,CPRPCS,CURPCS
  1.  SET CURPKG=$P(NODECUR,"^")
  1.  SET NODECPR=^TMP("XTVS CPR PARAM",$JOB,CPRNDNM)
  1.  SET CPRPKG=$P(NODECPR,"^")
  1.  ;
  1.  ; Set CPRPCS and CURPCS to compare Selected Parameter file to Comparison Parameter file
  1.  ;  (pce 10 = * on CPR parameter files indicated circular Parent/Child relationship)
  1.  SET CPRPCS=$L(NODECPR,"^")
  1.  SET CURPCS=$L(NODECUR,"^")
  1.  IF $P(NODECPR,"^",CPRPCS)="*" SET CPRPCS=CPRPCS-1
  1.  IF $P(NODECUR,"^",CURPCS)="*" SET CURPCS=CURPCS-1
  1.  ;
  1.  IF ($P(NODECUR,"^",1,CURPCS)=$P(NODECPR,"^",1,CPRPCS)) DO DELPKG(CURNDNM,CPRNDNM) SET PKGDEL=1 ;Remove unedited Pkg from TMP globals, set PKGDEL to QUIT CPR loop
  1.  IF ($P(NODECUR,"^",1,CURPCS)'=$P(NODECPR,"^",1,CPRPCS)),(CPRPKG=CURPKG) DO
  1.  . SET FNDCHG=$$CHNGCHK(NODECUR,NODECPR,.VALMCNT) ;NOTE: FNDCHG not used
  1.  . DO DELPKG(CURNDNM,CPRNDNM) ;Remove edited Pkg from globals
  1.  . SET PKGRPTD=1 ;PKGRPTD prevents 'No edited packages' msg
  1.  . SET PKGDEL=1 ; Quit CPR Node loop
  1.  QUIT
  1.  ;
  1. CHNGCHK(NODECUR,NODECPR,VALMCNT) ; Check selected parameter file (SEL) against a comparison parameter file (CPR)
  1.  NEW FNDCHNG,PKGHDRPT,PKGNAME,STRVLMCT
  1.  NEW CURPPFX,CPRPPFX,CURHF,CPRHF,CURLF,CPRLF,CURADPFX,CPRADPFX,CUREXPFX,CPREXPFX,CURFL,CPRFL,CURFRL,CPRFRL,CURPP,CPRPP
  1.  ;Variable doc key:
  1.  ; CPR* is compare file data
  1.  ; CUR* is current (Selected) file data
  1.  ;   *PPFX  - Primary Prefix
  1.  ;   *HF    - *Highest file number
  1.  ;   *LF    - *Lowest file number
  1.  ;   *ADPFX - Additional Prefixes
  1.  ;   *EXPFX - Excluded Prefixes
  1.  ;   *FL    - File List
  1.  ;   *FRL   - File Range List
  1.  ;   *PP    - Parent Package
  1.  ;
  1.  SET (FNDCHNG,PKGHDRPT)=0
  1.  SET PKGNAME=$P(NODECUR,"^")
  1.  SET STRVLMCT=VALMCNT
  1.  ;
  1.  ;Prefix
  1.  SET CURPPFX=$P(NODECUR,"^",2)
  1.  SET CPRPPFX=$P(NODECPR,"^",2)
  1.  IF CURPPFX'=CPRPPFX DO
  1.  .DO:'PKGHDRPT HDROUT(PKGNAME,.PKGHDRPT,.VALMCNT)
  1.  .DO ADD^XTVSLAPI(.VALMCNT,"SEL Prefix: "_$S(CURPPFX]"":CURPPFX,1:"{none}")_"    CPR Prefix: "_$S(CPRPPFX]"":CPRPPFX,1:"{none}"))
  1.  ;
  1.  ;Low File
  1.  SET CURLF=$P(NODECUR,"^",3)
  1.  SET CPRLF=$P(NODECPR,"^",3)
  1.  IF CURLF'=CPRLF DO
  1.  .DO:'PKGHDRPT HDROUT(PKGNAME,.PKGHDRPT,.VALMCNT)
  1.  .DO ADD^XTVSLAPI(.VALMCNT,"SEL Low File #: "_$S(CURLF]"":CURLF,1:"{none}")_"    CPR Low File #: "_$S(CPRLF]"":CPRLF,1:"{none}"))
  1.  ;
  1.  ;High File
  1.  SET CURHF=$P(NODECUR,"^",4)
  1.  SET CPRHF=$P(NODECPR,"^",4)
  1.  IF CURHF'=CPRHF DO
  1.  .DO:'PKGHDRPT HDROUT(PKGNAME,.PKGHDRPT,.VALMCNT)
  1.  .DO ADD^XTVSLAPI(.VALMCNT,"SEL High File #: "_$S(CURHF]"":CURHF,1:"{none}")_"    CPR High File #: "_$S(CPRHF]"":CPRHF,1:"{none}"))
  1.  ;
  1.  ;Additional Prefixes
  1.  SET CURADPFX=$P(NODECUR,"^",5)
  1.  SET CPRADPFX=$P(NODECPR,"^",5)
  1.  IF CURADPFX'=CPRADPFX DO
  1.  .DO:'PKGHDRPT HDROUT(PKGNAME,.PKGHDRPT,.VALMCNT)
  1.  .DO LISTDIF("Additional Prefixes",CURADPFX,CPRADPFX,.VALMCNT)
  1.  ;
  1.  ;Excluded Prefixes
  1.  SET CUREXPFX=$P(NODECUR,"^",6)
  1.  SET CPREXPFX=$P(NODECPR,"^",6)
  1.  IF CUREXPFX'=CPREXPFX DO
  1.  .DO:'PKGHDRPT HDROUT(PKGNAME,.PKGHDRPT,.VALMCNT)
  1.  .DO LISTDIF("Excepted Prefixes",CUREXPFX,CPREXPFX,.VALMCNT)
  1.  ;
  1.  ;File List
  1.  SET CURFL=$P(NODECUR,"^",7)
  1.  SET CPRFL=$P(NODECPR,"^",7)
  1.  IF CURFL'=CPRFL DO
  1.  .DO:'PKGHDRPT HDROUT(PKGNAME,.PKGHDRPT,.VALMCNT)
  1.  .DO LISTDIF("Files",CURFL,CPRFL,.VALMCNT)
  1.  ;
  1.  ;File Range List
  1.  SET CURFRL=$P(NODECUR,"^",8)
  1.  SET CPRFRL=$P(NODECPR,"^",8)
  1.  IF CURFRL'=CPRFRL DO
  1.  .DO:'PKGHDRPT HDROUT(PKGNAME,.PKGHDRPT,.VALMCNT)
  1.  .DO LISTDIF("File Ranges",CURFRL,CPRFRL,.VALMCNT)
  1.  ;
  1.  ;Parent
  1.  SET CURPP=$P(NODECUR,"^",9)
  1.  SET CPRPP=$P(NODECPR,"^",9)
  1.  IF CURPP'=CPRPP DO
  1.  .DO:'PKGHDRPT HDROUT(PKGNAME,.PKGHDRPT,.VALMCNT)
  1.  .DO ADD^XTVSLAPI(.VALMCNT,"Parent")
  1.  .DO ADD^XTVSLAPI(.VALMCNT,"  SEL: "_$S(CURPP]"":CURPP,1:"{none}"))
  1.  .DO ADD^XTVSLAPI(.VALMCNT,"  CPR: "_$S(CPRPP]"":CPRPP,1:"{none}"))
  1.  ;
  1.  IF VALMCNT'=STRVLMCT SET FNDCHNG=1
  1.  QUIT FNDCHNG
  1.  ;
  1. ADDDELRP(EXTRCT,VALMCNT) ;Report packages Added/Deleted to/from Selected extract
  1.  NEW HDRTXT,NODENM,NODEVAL,DATAELMT,PKGFND
  1.  ;
  1.  SET HDRTXT=$S(EXTRCT="CUR":"ADDED",1:"DELETED")_" PACKAGES:"
  1.  DO ADD^XTVSLAPI(.VALMCNT," ")
  1.  DO ADD^XTVSLAPI(.VALMCNT," ")
  1.  DO ADD^XTVSLAPI(.VALMCNT,HDRTXT,1,1,$L(HDRTXT))
  1.  ;
  1.  SET PKGFND=0
  1.  SET NODENM=""
  1.  FOR  SET NODENM=$O(^TMP("XTVS "_EXTRCT_" PARAM",$JOB,NODENM)) QUIT:NODENM=""  SET NODEVAL=^TMP("XTVS "_EXTRCT_" PARAM",$JOB,NODENM) DO
  1.  . SET PKGFND=1
  1.  . DO HDROUT($P(NODEVAL,"^",1),.PKGHDRPT,.VALMCNT) ;Output package name
  1.  . ;
  1.  . SET DATAELMT=$P(NODEVAL,"^",2)
  1.  . DO ADD^XTVSLAPI(.VALMCNT,"Prefix: "_$S(DATAELMT]"":DATAELMT,1:"{none}"))
  1.  . ;
  1.  . SET DATAELMT=$P(NODEVAL,"^",3)
  1.  . DO ADD^XTVSLAPI(.VALMCNT,"Low File #: "_$S(DATAELMT]"":DATAELMT,1:"{none}"))
  1.  . ;
  1.  . SET DATAELMT=$P(NODEVAL,"^",4)
  1.  . DO ADD^XTVSLAPI(.VALMCNT,"High File #: "_$S(DATAELMT]"":DATAELMT,1:"{none}"))
  1.  . ;
  1.  . DO ADD^XTVSLAPI(.VALMCNT,"Additional Prefixes: ")
  1.  . SET DATAELMT=$P(NODEVAL,"^",5)
  1.  . DO EVENSPLT(.VALMCNT,$S(DATAELMT]"":DATAELMT,1:"{none}"))
  1.  . ;
  1.  . DO ADD^XTVSLAPI(.VALMCNT,"Excepted Prefixes: ")
  1.  . SET DATAELMT=$P(NODEVAL,"^",6)
  1.  . DO EVENSPLT(.VALMCNT,$S(DATAELMT]"":DATAELMT,1:"{none}"))
  1.  . ;
  1.  . DO ADD^XTVSLAPI(.VALMCNT,"File List: ")
  1.  . SET DATAELMT=$P(NODEVAL,"^",7)
  1.  . DO EVENSPLT(.VALMCNT,$S(DATAELMT]"":DATAELMT,1:"{none}"))
  1.  . ;
  1.  . DO ADD^XTVSLAPI(.VALMCNT,"File Range list: ")
  1.  . SET DATAELMT=$P(NODEVAL,"^",8)
  1.  . DO EVENSPLT(.VALMCNT,$S(DATAELMT]"":DATAELMT,1:"{none}"))
  1.  . ;
  1.  . SET DATAELMT=$P(NODEVAL,"^",9)
  1.  . DO ADD^XTVSLAPI(.VALMCNT,"Parent: "_$S(DATAELMT]"":DATAELMT,1:"{none}"))
  1.  ;
  1.  DO:'PKGFND ADD^XTVSLAPI(.VALMCNT," No "_$S(EXTRCT="CUR":"added",EXTRCT="CPR":"deleted",1:"")_" packages!")
  1.  QUIT
  1.  ;
  1. HELP ; -- help code
  1.  IF $D(X),X'["??" DO
  1.  . SET X="?"
  1.  . DO DISP^XQORM1 W !
  1.  IF $D(X),X["??" DO
  1.  . DO CLEAR^VALM1
  1.  . DO FULL^VALM1
  1.  . SET XTQVAR=Y
  1.  . IF XTQVAR DO
  1.  .. SET XTQVAR=0
  1.  .. FOR TXTCT=1:1 SET XTX=$P($T(LPCTXT+TXTCT^XTVSHLP1),";",3,99) QUIT:XTX="$END"  QUIT:XTQVAR  DO
  1.  ... IF XTX="$PAUSE" DO PAUSE^VALM1 D:Y CLEAR^VALM1 IF 'Y SET XTQVAR=1 QUIT
  1.  ... W !,$S(XTX["$PAUSE":"",1:XTX)
  1.  .IF 'XTQVAR DO
  1.  .. WRITE !,"List specific actions:",!
  1.  .. DO DISP^XQORM1 W !
  1.  .. WRITE !,"Email Comparison Report - This action prompts the user for Email addresses,"
  1.  .. WRITE !,"  writes the comparison report to an Email message and sends the message to"
  1.  .. WRITE !,"  the recipients.  This option can be used to send a Comparison Report to"
  1.  .. WRITE !,"  Subject Matter Experts.",!!
  1.  D MSG
  1.  Q
  1.  ;
  1. EXIT ; -- exit code
  1.  DO KILL
  1.  Q
  1.  ;
  1. MSG(TEXT) ; -- set default message
  1.  IF $G(TEXT)]"" SET VALMSG=TEXT
  1.  IF $G(TEXT)']"" SET VALMSG="Enter ?? for more actions and Help"
  1.  QUIT
  1.  ;
  1. KILL ; - Cleanup local and global display arrays
  1.  DO CLEAN^VALM10 ;Kill data and video control arrays
  1.  DO KILL^VALM10() ;Kill Video attributes
  1.  DO CLNTMPGB
  1.  KILL ^TMP("XTVS PKG MAN PARM COMPARE",$JOB)
  1.  KILL DIR,X,Y,DTOUT,DIRUT,DUOUT
  1.  QUIT
  1.  ;
  1. CLNTMPGB ;Kill temporary globals
  1.  KILL ^TMP("XTVS CUR PARAM",$JOB),^TMP("XTVS CPR PARAM",$JOB)
  1.  QUIT
  1.  ;
  1. HDROUT(PKGNAME,PKGHDRPT,VALMCNT) ; Output package header
  1.  SET PKGHDRPT=1
  1.  DO ADD^XTVSLAPI(.VALMCNT," ")
  1.  DO ADD^XTVSLAPI(.VALMCNT,"Package: "_PKGNAME,1,10,$L(PKGNAME)) ;ADD^XTVSLAPI parameters: VALMCNT,MSG,LRBOLD,STRTBLD,ENDBLD
  1.  QUIT
  1.  ;
  1. LISTDIF(ELMTNME,CURDAT,CPRDAT,VALMCNT) ; Output differences in parameter lists
  1.  NEW PCENUM,DATAELMT,CHKELMT
  1.  DO ADD^XTVSLAPI(.VALMCNT,"  "_ELMTNME)
  1.  ;
  1.  IF (CURDAT]""),(CPRDAT']"") DO 
  1.  . DO EVENSPLT(.VALMCNT,"Added entire list in SEL file: ",1)
  1.  . DO EVENSPLT(.VALMCNT,CURDAT)
  1.  IF (CURDAT']""),(CPRDAT]"") DO
  1.  . DO EVENSPLT(.VALMCNT,"Deleted entire list in SEL file: ",1)
  1.  . DO EVENSPLT(.VALMCNT,CPRDAT)
  1.  ;
  1.  IF (CURDAT]""),(CPRDAT]"") DO  ;List changes as lineitems
  1.  . DO EVENSPLT(.VALMCNT,"CPR Parameter List: "_$S(CPRDAT]"":CPRDAT,1:"{none}"),1)
  1.  . ;
  1.  . ;Check for deletions
  1.  . FOR PCENUM=1:1 SET DATAELMT=$P(CPRDAT,"|",PCENUM)  Q:DATAELMT=""  DO
  1.  .. SET CHKELMT=DATAELMT_"|"
  1.  .. IF CURDAT'[CHKELMT DO EVENSPLT(.VALMCNT,DATAELMT_" ...deleted in SEL file")
  1.  . IF PCENUM=1 DO ADD^XTVSLAPI(.VALMCNT,"      {none} ...deleted in SEL file")
  1.  . ;
  1.  . ;Check for additions
  1.  . FOR PCENUM=1:1 SET DATAELMT=$P(CURDAT,"|",PCENUM)  Q:DATAELMT=""  DO
  1.  .. SET CHKELMT=DATAELMT_"|"
  1.  .. IF CPRDAT'[CHKELMT DO EVENSPLT(.VALMCNT,DATAELMT_" ...added in SEL file")
  1.  . IF PCENUM=1 DO ADD^XTVSLAPI(.VALMCNT,"      {none} ...added in SEL file")
  1.  . ;
  1.  . DO EVENSPLT(.VALMCNT,"SEL Parameter List: "_$S(CURDAT]"":CURDAT,1:"{none}"),1)
  1.  ;
  1.  QUIT
  1.  ;
  1. EVENSPLT(VALMCNT,MSG,DTANODE) ; Add line to build display split on piece
  1.  ; VALMCNT - Selected array node number
  1.  ; MSG     - Message to add to ListMan Display
  1.  ; DTANODE - Indicates raw data node or data element changed
  1.  ;             1 : Raw data node
  1.  ;             0 : data element changed
  1.  ;
  1.  NEW PCENUM,MSGPCE,LINEOUT,START
  1.  SET DTANODE=+$G(DTANODE)
  1.  SET LINEOUT=""
  1.  SET START=1
  1.  ;
  1.  FOR PCENUM=1:1 SET MSGPCE=$P(MSG,"|",PCENUM) SET LINEOUT=LINEOUT_MSGPCE_$$DELIMEND(MSGPCE) QUIT:MSGPCE=""  DO
  1.  . IF ($L(LINEOUT)>$S(DTANODE:75,1:73))!(LINEOUT["...") DO  ;$Select DTANODE determines if leading spaces are added to LINEOUT
  1.  .. IF $L(LINEOUT)>$S(DTANODE:75,1:73) DO
  1.  ... SET PCENUM=PCENUM-1
  1.  ... SET LINEOUT=$P(MSG,"|",START,PCENUM)
  1.  .. DO ADD^XTVSLAPI(.VALMCNT,"    "_$S('DTANODE:"  ",1:"")_LINEOUT)
  1.  .. SET LINEOUT=""
  1.  .. SET START=PCENUM+1
  1.  DO:LINEOUT]"" ADD^XTVSLAPI(.VALMCNT,"    "_$S('DTANODE:"  ",1:"")_LINEOUT)
  1.  ;
  1.  QUIT
  1.  ;
  1. DELIMEND(MSGPCE) ; Return ending delimiter for LINEOUT in EVENSPLT^XTVSLPC
  1.  NEW RESULT
  1.  SET RESULT=$S((MSGPCE'["...")&(MSGPCE'="")&(MSGPCE'["{none}")&(MSGPCE'["file:"):"|",1:"")
  1.  QUIT RESULT
  1.  ;
  1. DELPKG(CURNDNM,CPRNDNM) ; Delete Package from Selected and Compare parameter files
  1.  KILL ^TMP("XTVS CUR PARAM",$JOB,CURNDNM),^TMP("XTVS CPR PARAM",$JOB,CPRNDNM)
  1.  QUIT
  1.  ;
  1.  ;PROTOCOL entry points
  1.  ;
  1. MAILRPT ; Email ^TMP("XTVS PKG MGR PARAM ERROR DISP") comparison report
  1.  ; -- Protocol: XTVS PKG MGR PARAM COMPR MAIL ACTION
  1.  NEW XTINSTMM,XTTOMM,XMERR,XMZ,XTTYPE,SUBSCPT
  1.  DO FULL^VALM1
  1.  WRITE !!," The message can take some time to be sent.",!
  1.  KILL XMERR
  1.  SET XTINSTMM("ADDR FLAGS")="R"  ;Do not Restrict addressing
  1.  SET XTTYPE="S"
  1.  DO TOWHOM^XMXAPIU(DUZ,,XTTYPE,.XTINSTMM)
  1.  IF +$G(XMERR)'>0 DO
  1.  . NEW XMY,XMTEXT,XMDUZ,XMSUB,XTLPCNT
  1.  . SET XTLPCNT=""
  1.  . FOR  SET XTLPCNT=$O(^TMP("XMY",$J,XTLPCNT)) QUIT:XTLPCNT=""  SET XMY(XTLPCNT)=""
  1.  . SET XMDUZ=DUZ
  1.  . SET XMSUB=$P(VALMHDR(4),":",2)_" ("_$P(VALMHDR(1)," - ",2)_")"
  1.  . SET ^TMP("XTVS PKG MAN CMPR MSG",$JOB,1)="Parameter Files comparison: "_$P(VALMHDR(4),":",2)_" [SEL] vs "_$P(VALMHDR(5),":",2)_" [CPR]"
  1.  . SET SUBSCPT=0
  1.  . FOR  SET SUBSCPT=$O(^TMP("XTVS PKG MAN PARM COMPARE",$JOB,SUBSCPT)) QUIT:+SUBSCPT=0  DO
  1.  .. SET ^TMP("XTVS PKG MAN CMPR MSG",$JOB,SUBSCPT+1)=^TMP("XTVS PKG MAN PARM COMPARE",$JOB,SUBSCPT,0)
  1.  . SET XMTEXT="^TMP(""XTVS PKG MAN CMPR MSG"","_$JOB_","
  1.  . DO ^XMD
  1.  . IF +XMZ>0 DO JUSTPAWS^XTVSLAPI($P(VALMHDR(1)," - ",2)_" Emailed.  [MSG #:"_XMZ_"]")
  1.  . IF +XMZ'>0  DO JUSTPAWS^XTVSLAPI("Error: "_$P(VALMHDR(1)," - ",2)_" not Emailed! ["_XMZ_"]")
  1.  . KILL ^TMP("XTVS PKG MAN CMPR MSG",$JOB)
  1.  ;
  1.  D MSG
  1.  SET VALMBCK="R"
  1.  QUIT