Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: XU8P586

XU8P586.m

Go to the documentation of this file. 
  1. XU8P586 ; BA/BP - PERSON CLASSES;09/22/11
  1.  ;;8.0;KERNEL;**586**; July 10, 1995;Build 1
  1.  ;;Per VHA Directive 2004-038, this routine should not be modified.
  1.  Q
  1.  ;
  1. POST ;
  1.  D DEL ;clean entry 1174-1175 if existed
  1.  D ADD ;add entry 1174-1175 in the file
  1.  D DEF ;update definition for entries
  1.  Q
  1.  ;
  1. ADD ;add the entry 1174-1175
  1.  N XUDATA
  1.  S XUDATA="1174^Optometry^Optometry Resident^^a^^V060808^390200000X^^41^^^I"
  1.  D ADD1(XUDATA)
  1.  N XUDATA
  1.  S XUDATA="1175^Podiatry^Podiatry Resident^^a^^V120213^390200000X^^48^^^I"
  1.  D ADD1(XUDATA)
  1.  Q
  1.  ;^USC(8932.1,D0,0)= (#.01) PROVIDER TYPE [1F] ^ (#1) CLASSIFICATION [2F] ^ 
  1.  ;                ==>(#2) AREA OF SPECIALIZATION [3F] ^ (#3) STATUS [4S] ^ (#4) 
  1.  ;                ==>DATE INACTIVATED [5D] ^ (#5) VA CODE [6F] ^ (#6) X12 CODE 
  1.  ;                ==>[7F] ^ (#7) reserved [8F] ^ (#8) SPECIALTY CODE [9F] ^ 
  1.  ;^USC(8932.1,D0,11,0)=^8932.111^^  (#11) DEFINITION
  1.  ;^USC(8932.1,D0,11,D1,0)= (#.01) DEFINITION [1W] ^ 
  1.  ;^USC(8932.1,D0,90002)=  ^ (#90002) INDIVIDUAL/NON [2S] ^
  1.  ;
  1. ADD1(XUDATA) ; add single entry
  1.  N FDA,FDAIEN,XUD
  1.  S XUD=$G(XUDATA)
  1.  S FDAIEN(1)=$P(XUD,"^")
  1.  S FDA(8932.1,"+1,",.01)=$P(XUD,"^",2)
  1.  S FDA(8932.1,"+1,",1)=$P(XUD,"^",3)
  1.  S FDA(8932.1,"+1,",2)=$P(XUD,"^",4)
  1.  S FDA(8932.1,"+1,",3)="a"
  1.  S FDA(8932.1,"+1,",5)=$P(XUD,"^",7)
  1.  S FDA(8932.1,"+1,",6)=$P(XUD,"^",8)
  1.  S FDA(8932.1,"+1,",8)=$P(XUD,"^",10)
  1.  S FDA(8932.1,"+1,",90002)=$P(XUD,"^",12)
  1.  D UPDATE^DIE("","FDA","FDAIEN","ERR")
  1.  Q
  1.  ;
  1. DEL ; Delete entries
  1.  N XU581,DIK,DA
  1.  F XU581=1174,1175 S DIK="^USC(8932.1,",DA=XU581 D ^DIK
  1.  Q
  1.  ;
  1. DEF ; Update definitions
  1.  N XUI
  1.  F XUI=1174,1175 D DEF1(XUI)
  1.  Q
  1.  ;
  1. DEF1(XUI) ; Update definition for single entry XUI
  1.  N XUI1,XUDATA,XUY
  1.  K ^TMP($J,"XUBA")
  1.  F XUY=1:1:100 S XUDATA=$T(@XUI+XUY) Q:XUDATA=" ;;END"  D 
  1.  . S ^TMP($J,"XUBA",XUI,XUY,0)=$P(XUDATA,";;",2)
  1.  S XUI1=XUI_","
  1.  D WP^DIE(8932.1,XUI1,11,"K","^TMP($J,""XUBA"",XUI)")
  1.  K ^TMP($J,"XUBA")
  1.  Q
  1.  ;
  1. 1174 ;
  1.  ;;An individual who is enrolled in an organized health care 
  1.  ;;education/training program leading to a degree, certification, 
  1.  ;;registration, and/or licensure to provide health care. 
  1.  ;;END
  1. 1175 ;
  1.  ;;An individual who is enrolled in an organized health care 
  1.  ;;education/training program leading to a degree, certification, 
  1.  ;;registration, and/or licensure to provide health care. 
  1.  ;;END
  1.  ;
  1. GETDEF ; get definitions
  1.  N XUI,XUY
  1.  F XUI=1174,1175 D
  1.  . S XUY=$G(^USC(8932.1,XUI,11,0)),XUY=$P(XUY,"^",3)
  1.  . I XUY>0 D GETDES(XUI,XUY)
  1.  Q
  1.  ;
  1. GETDES(XUI,XUY) ; get single entry definition
  1.  N XUA,XUB
  1.  W !,XUI," ;"
  1.  F XUA=1:1:XUY W !," ;;",$G(^USC(8932.1,XUI,11,XUA,0))
  1.  W !," ;;END"
  1.  Q
  1. GET ;
  1.  N XU586
  1.  F XU586=1174,1175 D GET1(XU586)
  1.  Q
  1.  ;
  1. GET1(XUIEN) ; Get information of given entry from Person Class file.
  1.  N XUI
  1.  S XUI=" ;;"_XUIEN_"^"_$G(^USC(8932.1,XUIEN,0))
  1.  S $P(XUI,"^",12)=$G(^USC(8932.1,XUIEN,90002))
  1.  W !," N XUDATA"
  1.  W !," S XUDATA=","""",$P(XUI,";;",2),""""
  1.  W !," D ADD1(XUDATA)"
  1.  Q