Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: XUMFP

XUMFP.m

Go to the documentation of this file.
  1. XUMFP ;CIOFO-SF/RAM,ALB/BRM - Master File C/S Parameters ; 10/11/02 2:50pm
  1. ;;8.0;KERNEL;**206,217,246,262,369**;Jul 10, 1995;Build 27
  1. ;
  1. ;
  1. ;
  1. MAIN(IFN,IEN,TYPE,PARAM,ERROR) ; -- parameters for master file server
  1. ;
  1. ;INPUT
  1. ; IFN Internal File Number (required)
  1. ;
  1. ; IEN Internal Entry Number (required)
  1. ;
  1. ; single entry (pass by value) example: IEN=1
  1. ;
  1. ; multiple entries (pass by reference) IEN(1)=""
  1. ; IEN(2)=""
  1. ;
  1. ; ALL national entries (pass by value) IEN="ALL"
  1. ;
  1. ; NEW entry (pass by value) IEN="NEW"
  1. ;
  1. ; TYPE Message TYPE (required)
  1. ;
  1. ; 0 = MFN - unsolicited update
  1. ; 1 = MFQ - query particular record and file
  1. ; 3 = MFQ - query particular record in array
  1. ; 5 = MFQ - query group records file
  1. ; 7 = MFQ - query group records array
  1. ; 11 = MFR - query response particular rec file
  1. ; 13 = MFR - query response particular rec array
  1. ; 15 = MFR - query response group records file
  1. ; 17 = MFR - query response group records array
  1. ;
  1. ;
  1. ;INPUT/OUTPUT
  1. ;
  1. ; PARAM("PROTOCOL") IEN Protocol (#101) file
  1. ; PARAM("LLNK") HLL("LINKS",n) 'protocol^logical link'
  1. ; PARAM("PRE") Pre-update record routine
  1. ; PARAM("POST") Post-update record routine
  1. ;
  1. ; QRD -- Query definition segment
  1. ; -------------------------------
  1. ; PARAM("QDT") Query Date/Time
  1. ; PARAM("QFC") Query Format Code
  1. ; PARAM("QP") Query Priority
  1. ; PARAM("QID") Query ID
  1. ; PARAM("DRT") Deferred Response Type
  1. ; PARAM("DRDT") Deferred Response Date/Time
  1. ; PARAM("QLR") Quantity Limited Request
  1. ; PARAM("WHO") Who Subject Filter
  1. ; PARAM("WHAT") What Subject Filter
  1. ; PARAM("WDDC") What Department Data Code
  1. ; PARAM("WDCVQ") What Data Code Value Qual
  1. ; PARAM("QRL") Query Results Level
  1. ;
  1. ; MFI -- Master File Identification
  1. ; ---------------------------------
  1. ; PARAM("MFI") Master File Identifier
  1. ; PARAM("MFAI") Master File Application Identifier
  1. ; PARAM("FLEC") File-Level Event Code
  1. ; PARAM("ENDT") Entered Data/Time
  1. ; PARAM("MFIEDT") Effective Date/Time
  1. ; PARAM("RLC") Response Level Code
  1. ;
  1. ; MFE -- Master File Entry
  1. ; ------------------------
  1. ; PARAM("RLEC") Record-Level Event Code
  1. ; PARAM("MFNCID") MFN Control ID
  1. ; PARAM("MFEEDT") Effective Date/Time
  1. ; PARAM("PKV") Primary Key Value
  1. ;
  1. ; [Z...] segment(s) parameters
  1. ; -------------------------
  1. ; PARAM("SEG",SEG)="" HL7 segment name
  1. ; PARAM("SEG",SEG,"SEQ",SEQ,FLD#) seg sequence number and field
  1. ; Note: Add HL7 data type + sub components (leave value/code blank)
  1. ; Example: Institution Facility Type = "CE^~FACILILITY TYPE~VA"
  1. ; If the FIELD is a pointer and you want the lookup to be other
  1. ; than the pointed to .01 set the 3rd piece = to the extended ref.
  1. ; I.e., Parent Facility in the Association mult of Institution
  1. ; points back to Institution, if we want to get facility using
  1. ; station number (#99) instead of name (.01) set the 3rd piece
  1. ; equal to ":99" giving us "CE^~FACILILITY TYPE~VA^:99".
  1. ;
  1. ; Files involving sub-records and/or extended reference
  1. ; -----------------------------------------------------
  1. ; PARAM("SEG",SEG,"SEQ",SEQ,"FILE") See FM documentation
  1. ; PARAM("SEG",SEG,"SEQ",SEQ,"IENS") $$GET1^DIQ() for value
  1. ; PARAM("SEG",SEG,"SEQ",SEQ,"FIELD") of FILE, IENS, & FIELD.
  1. ;
  1. ; PARAM("SEG",SEG,"SEQ",SEQ,"DTYP") HL7 data type (above)
  1. ;
  1. ;
  1. ; *** NOTE: OUTPUT in ^TMP("XUMF MFS",$J,"PARAM") ***
  1. ;
  1. ; Example: MFE PKV is ^TMP("XUMF MFS",$J,"PARAM",IEN,"PKV")
  1. ; SEG ^TMP("XUMF MFS",$J,"PARAM","SEG")
  1. ;
  1. ; and another node is required for sub-file IENS for group
  1. ; ^TMP("XUMF MFS",$J,"PARAM",IEN,"IENS",SEG,SEQ)=IENS
  1. ;
  1. ; Use XUMFP4 as a template/example routine
  1. ;
  1. N QUERY,UPDATE,ALL,MFR,MFQ,HLFS,HLCS,GROUP,ARRAY,ROOT,NEW,I,J,CDSYS
  1. N PROTOCOL
  1. ;
  1. K ^TMP("XUMF MFS",$J)
  1. M ^TMP("XUMF MFS",$J,"PARAM")=PARAM
  1. ;
  1. S IEN=$G(IEN),IFN=$G(IFN)
  1. S TYPE=+$G(TYPE),ERROR=$G(ERROR)
  1. S UPDATE=$S(TYPE#2:0,1:1)
  1. S QUERY='UPDATE
  1. S GROUP=$S(UPDATE:0,TYPE[5:1,TYPE[7:1,1:0)
  1. S ARRAY=$S(UPDATE:0,TYPE[3:1,TYPE[7:1,1:0)
  1. S ALL=$S(IEN="ALL":1,1:0)
  1. S NEW=$S(IEN="NEW":1,1:0)
  1. S MFR=$S(UPDATE:0,TYPE>10:1,1:0)
  1. S MFQ=$S(UPDATE:0,'MFR:1,1:0)
  1. ;
  1. S PROTOCOL=$G(PARAM("PROTOCOL"))
  1. ;
  1. I 'IFN S ERROR="1^invalid IFN" Q
  1. ;
  1. ; -- get root of file
  1. S ROOT=$$ROOT^DILFD(IFN,,1)
  1. ;
  1. ; -- if IEN array input, merge with param
  1. I 'ALL,'IEN,$O(IEN(0)) M ^TMP("XUMF MFS",$J,"PARAM","IEN")=IEN
  1. ;
  1. ; -- if CDSYS and ALL get entries
  1. S CDSYS=$G(^TMP("XUMF MFS",$J,"PARAM","CDSYS"))
  1. I ALL,CDSYS'="" D
  1. .S I=0 F S I=$O(@ROOT@("XUMFIDX",CDSYS,I)) Q:'I D
  1. ..S J=$O(@ROOT@("XUMFIDX",CDSYS,I,0))
  1. ..S ^TMP("XUMF MFS",$J,"PARAM","IEN",J)=I
  1. ;
  1. ; -- get ALL file 'national' entries
  1. I ALL,'$D(^TMP("XUMF MFS",$J,"PARAM","IEN")),CDSYS="" D
  1. .S I=0 F S I=$O(@ROOT@("XUMF","N",I)) Q:'I D
  1. ..S ^TMP("XUMF MFS",$J,"PARAM","IEN",I)=""
  1. ;
  1. ; -- get ALL file
  1. I ALL,'$D(^TMP("XUMF MFS",$J,"PARAM","IEN")),CDSYS="" D
  1. .S I=0 F S I=$O(@ROOT@(I)) Q:'I D
  1. ..S ^TMP("XUMF MFS",$J,"PARAM","IEN",I)=""
  1. ;
  1. ; *** insert code below ***
  1. ; insert file number in string below to add an additional file
  1. I "^4^4.1^5.12^5.13^730^5^45.7^4.11^49^9.8^"'[(U_IFN_U) S ERROR="1^file not supported" Q
  1. ; *** end insert code ***
  1. ;
  1. ; note: also create a subroutine for each supported file with
  1. ; the file number as the line TAG (replace decimal point
  1. ; of file number with the letter 'P'). This subroutine
  1. ; calls an associated routine for the specific file.
  1. ; This file should use the XUMFP namespace.
  1. ;
  1. I "^4^4.1^5.12^5.13^"[(U_IFN_U) D @("F"_$TR(IFN,".","P"))
  1. I "^730^5^4.11^49^9.8^"[(U_IFN_U) D ZL7
  1. ;
  1. K PARAM
  1. ;
  1. Q
  1. ;
  1. F4 ; -- institution file
  1. ;
  1. D ^XUMFP4
  1. ;
  1. Q
  1. ;
  1. F4P1 ; -- facility type file
  1. ;
  1. D ^XUMFPFT
  1. ;
  1. Q
  1. ;
  1. F5P12 ; -- postal code file
  1. ;
  1. D ^XUMFP512
  1. ;
  1. Q
  1. ;
  1. F5P13 ; -- county code file
  1. ;
  1. D ^XUMFP513
  1. ;
  1. Q
  1. ;
  1. ; *** insert subroutine here for additional files ***
  1. ;
  1. TAG ;D ^ROUTINE
  1. ;Q
  1. ;
  1. ;
  1. ZL7 ; generic
  1. ;
  1. D ^XUMFPMFS
  1. ;
  1. Q
  1. ;
  1. MFI(X) ; -- master file identifier function
  1. ;
  1. ;INPUT X master file indentifier (seq 1 MFI segment)
  1. ;OUTPUT $$ IFN - Internal File Number or '0' for error
  1. ;
  1. Q:X="Z04" 4
  1. Q:X="Z4T" 4.1
  1. Q:$P(X,HLCS)="5P12" 5.12
  1. Q:$P(X,HLCS)="5P13" 5.13
  1. Q:X="ZNS" 730
  1. Q:X="ZAG" 4.11
  1. Q:X="Z05" 5
  1. Q:X="Z49" 49
  1. ;
  1. ; *** add code here for new files ***
  1. ;
  1. Q 0
  1. ;
  1. DTYP(VALUE,TYP,HLCS,TOHL7) ;data type conversion
  1. ;INPUT
  1. ; VALUE value
  1. ; TYP HL7 data type
  1. ; TOHL7 1=to HL7, 0=to FileMan
  1. ;OUTPUT
  1. ; $$ formatted data
  1. ;
  1. N TEXT,CS
  1. S TYP=$G(TYP),VALUE=$G(VALUE),TOHL7=$G(TOHL7)
  1. Q:TYP="" VALUE Q:VALUE="" VALUE
  1. S TEXT=$P(TYP,U,2),TYP=$P(TYP,U)
  1. I TYP="ST"!(TYP="ID") Q VALUE
  1. I TYP="DT",TOHL7 D Q $$HLDATE^HLFNC(VALUE)
  1. .N X,Y S X=VALUE D ^%DT S VALUE=+Y
  1. I TYP="DT" Q $$FMDATE^HLFNC(+VALUE)
  1. I TYP="ZST" D Q VALUE
  1. .N IEN5 S IEN5=+$O(^DIC(5,"C",VALUE,""))
  1. .S:IEN5 VALUE=$P($G(^DIC(5,IEN5,0)),"^")
  1. I 'TOHL7 Q $P(VALUE,HLCS)
  1. Q VALUE_$TR(TEXT,"~",HLCS)
  1. ;