YS254PST.m

YS254PST ;BAL/KTL - Patch 254 Post-init ; 10/06/2023

 ;;5.01;MENTAL HEALTH;**254**;Dec 30, 1994;Build 5

 ;

 ; Reference to EN^XPAR in ICR #2263

 ; Reference to GETLST^XPAR in ICR #2263

 ; Reference to XLFSTR in ICR #10104

 Q

EDTDATE ; date used to update 601.71:18

 ;;3250103.2159

 Q

PRE ; nothing necessary

 Q

POST ; post-init

 N INST

 S INST="HIT-6"

 D DROPTST(INST)

 D UPDTST(INST)

 D UPDURL

 Q

 ;

UPDTST(NAME) ; Update Date Edited

 N IEN,REC

 S IEN=$O(^YTT(601.71,"B",NAME,0)) Q:'IEN

 S REC(11)="Y"

 S REC(18)=$P($T(EDTDATE+1),";;",2)

 D FMUPD^YTXCHGU(601.71,.REC,IEN)

 Q

 ;

DROPTST(NAME) ; Change OPERATIONAL to dropped

 N IEN,REC

 S IEN=$O(^YTT(601.71,"B",NAME,0))

 I +IEN'=0 D

 . S REC(10)="D"

 . S REC(18)=$P($T(EDTDATE+1),";;",2)

 . D FMUPD^YTXCHGU(601.71,.REC,IEN)

 K REC,IEN

 S IEN=$O(^YTT(601,"B",NAME,0))

 I 'IEN QUIT

 S REC(32)="N"

 D FMUPD^YTXCHGU(601,.REC,IEN)

 Q

 ;

UPDURL ; Update GUI TOOLS URL for MHA Web

 N LIST,PARM,ERR,ENT,INST,VAL,TITL,CMD,SPEC,NEWVAL

 K ^TMP($J,"XPAR")

 S LIST=$NA(^TMP($J,"XPAR"))

 S PARM="ORWT TOOLS MENU"

 D ENVAL^XPAR(LIST,PARM,"",.ERR,1)

 S ^XTMP("YS254-TOOLS",0)=$$FMADD^XLFDT(DT,7)_U_DT_U_"MH Backup Tools Menu"

 M ^XTMP("YS254-TOOLS","XPAR")=^TMP($J,"XPAR")

 S SPEC("/home?")="/home/p254/?",SPEC("/home/?")="/home/p254/?"  ;In case URL entered home/? Patch 254

 S SPEC("/home/p250/?")="/home/p254/?"  ;Patch 254

 S ENT="" F  S ENT=$O(^TMP($J,"XPAR",ENT)) Q:ENT=""  D

 . S INST=0 F  S INST=$O(^TMP($J,"XPAR",ENT,INST)) Q:+INST=0  D

 .. S VAL=^TMP($J,"XPAR",ENT,INST)

 .. I (VAL["mha.domain.ext/app/home?"!(VAL["mha.domain.ext/app/home/")) D

 ... S TITL=$P(VAL,"="),CMD=$P(VAL,"=",2,99)

 ... S CMD=$$REPLACE^XLFSTR(CMD,.SPEC)

 ... S NEWVAL=TITL_"="_CMD

 ... D BMES^XPDUTL("Updating "_CMD_" for "_ENT)

 ... D EN^XPAR(ENT,PARM,INST,NEWVAL,.ERR)

 K ^TMP($J,"XPAR")

 Q

SCREEN ; line to put in DATA SCREEN of KIDS build

 ; $$INCLUDE^YTXCHG(Y,"TAG","RTN") calls TAG^RTN to get an array of

 ; instrument exchange entries to include in the build.  It sets Y

 ; to true if the entry should be included.

 ; 

 I $$INCLUDE^YTXCHG(Y,"XCHGLST","YS238PST")

 Q

 ;

XCHGLST(ARRAY) ; return array of instrument exchange entries

 ; ARRAY(cnt,1)=instrument exchange entry name

 ; ARRAY(cnt,2)=instrument exchange entry creation date

 ;

 N I,X

 F I=1:1 S X=$P($T(ENTRIES+I),";;",2,99) Q:X="zzzzz"  D

 . S ARRAY(I,1)=$P(X,U)

 . S ARRAY(I,2)=$P(X,U,2)

 Q

ENTRIES ; New MHA instruments ^ Exchange Entry Date

 ;;zzzzz

 ;

 Q

--- Routine Detail   --- with STRUCTURED ROUTINE LISTING ---YS254PST   2530     printed  Mar 13, 2025@21:17:40                                                                                                                                                                                                    Page 2

YS254PST  ;BAL/KTL - Patch 254 Post-init ; 10/06/2023

 +1       ;;5.01;MENTAL HEALTH;**254**;Dec 30, 1994;Build 5

 +2       ;

 +3       ; Reference to EN^XPAR in ICR #2263

 +4       ; Reference to GETLST^XPAR in ICR #2263

 +5       ; Reference to XLFSTR in ICR #10104

 +6        QUIT 

EDTDATE   ; date used to update 601.71:18

 +1       ;;3250103.2159

 +2        QUIT 

PRE       ; nothing necessary

 +1        QUIT 

POST      ; post-init

 +1        NEW INST

 +2        SET INST="HIT-6"

 +3        DO DROPTST(INST)

 +4        DO UPDTST(INST)

 +5        DO UPDURL

 +6        QUIT 

 +7       ;

UPDTST(NAME) ; Update Date Edited

 +1        NEW IEN,REC

 +2        SET IEN=$ORDER(^YTT(601.71,"B",NAME,0))

           if 'IEN

               QUIT 

 +3        SET REC(11)="Y"

 +4        SET REC(18)=$PIECE($TEXT(EDTDATE+1),";;",2)

 +5        DO FMUPD^YTXCHGU(601.71,.REC,IEN)

 +6        QUIT 

 +7       ;

DROPTST(NAME) ; Change OPERATIONAL to dropped

 +1        NEW IEN,REC

 +2        SET IEN=$ORDER(^YTT(601.71,"B",NAME,0))

 +3        IF +IEN'=0

               Begin DoDot:1

 +4                SET REC(10)="D"

 +5                SET REC(18)=$PIECE($TEXT(EDTDATE+1),";;",2)

 +6                DO FMUPD^YTXCHGU(601.71,.REC,IEN)

               End DoDot:1

 +7        KILL REC,IEN

 +8        SET IEN=$ORDER(^YTT(601,"B",NAME,0))

 +9        IF 'IEN

               QUIT 

 +10       SET REC(32)="N"

 +11       DO FMUPD^YTXCHGU(601,.REC,IEN)

 +12       QUIT 

 +13      ;

UPDURL    ; Update GUI TOOLS URL for MHA Web

 +1        NEW LIST,PARM,ERR,ENT,INST,VAL,TITL,CMD,SPEC,NEWVAL

 +2        KILL ^TMP($JOB,"XPAR")

 +3        SET LIST=$NAME(^TMP($JOB,"XPAR"))

 +4        SET PARM="ORWT TOOLS MENU"

 +5        DO ENVAL^XPAR(LIST,PARM,"",.ERR,1)

 +6        SET ^XTMP("YS254-TOOLS",0)=$$FMADD^XLFDT(DT,7)_U_DT_U_"MH Backup Tools Menu"

 +7        MERGE ^XTMP("YS254-TOOLS","XPAR")=^TMP($JOB,"XPAR")

 +8       ;In case URL entered home/? Patch 254

           SET SPEC("/home?")="/home/p254/?"

           SET SPEC("/home/?")="/home/p254/?"

 +9       ;Patch 254

           SET SPEC("/home/p250/?")="/home/p254/?"

 +10       SET ENT=""

           FOR 

               SET ENT=$ORDER(^TMP($JOB,"XPAR",ENT))

               if ENT=""

                   QUIT 

               Begin DoDot:1

 +11               SET INST=0

                   FOR 

                       SET INST=$ORDER(^TMP($JOB,"XPAR",ENT,INST))

                       if +INST=0

                           QUIT 

                       Begin DoDot:2

 +12                       SET VAL=^TMP($JOB,"XPAR",ENT,INST)

 +13                       IF (VAL["mha.domain.ext/app/home?"!(VAL["mha.domain.ext/app/home/"))

                               Begin DoDot:3

 +14                               SET TITL=$PIECE(VAL,"=")

                                   SET CMD=$PIECE(VAL,"=",2,99)

 +15                               SET CMD=$$REPLACE^XLFSTR(CMD,.SPEC)

 +16                               SET NEWVAL=TITL_"="_CMD

 +17                               DO BMES^XPDUTL("Updating "_CMD_" for "_ENT)

 +18                               DO EN^XPAR(ENT,PARM,INST,NEWVAL,.ERR)

                               End DoDot:3

                       End DoDot:2

               End DoDot:1

 +19       KILL ^TMP($JOB,"XPAR")

 +20       QUIT 

SCREEN    ; line to put in DATA SCREEN of KIDS build

 +1       ; $$INCLUDE^YTXCHG(Y,"TAG","RTN") calls TAG^RTN to get an array of

 +2       ; instrument exchange entries to include in the build.  It sets Y

 +3       ; to true if the entry should be included.

 +4       ; 

 +5        IF $$INCLUDE^YTXCHG(Y,"XCHGLST","YS238PST")

 +6        QUIT 

 +7       ;

XCHGLST(ARRAY) ; return array of instrument exchange entries

 +1       ; ARRAY(cnt,1)=instrument exchange entry name

 +2       ; ARRAY(cnt,2)=instrument exchange entry creation date

 +3       ;

 +4        NEW I,X

 +5        FOR I=1:1

               SET X=$PIECE($TEXT(ENTRIES+I),";;",2,99)

               if X="zzzzz"

                   QUIT 

               Begin DoDot:1

 +6                SET ARRAY(I,1)=$PIECE(X,U)

 +7                SET ARRAY(I,2)=$PIECE(X,U,2)

               End DoDot:1

 +8        QUIT 

ENTRIES   ; New MHA instruments ^ Exchange Entry Date

 +1       ;;zzzzz

 +2       ;

 +3        QUIT