BPSOSC2 ;BHAM ISC/FCS/DRS - Certification testing ;06/01/2004
;;1.0;E CLAIMS MGMT ENGINE;**1,5,8,10,11,15**;JUN 2004;Build 13
;;Per VHA Directive 2004-038, this routine should not be modified.
;
Q
; SETBPS - Overwrite BPS array with values from BPS Certification file
; Input
; ENTRY - IEN for BPS Certification (#9002313.31)
; Output
; BPS Array - This is newed in BPSOSCA and is shared by all BPSOSC* routines
; and others
SETBPS(ENTRY) ;
;
I $G(ENTRY)="" Q
;
; Initialize some variables
N A,B,N,X,DUR,FIELD,CNT,CNT2
;
; If there is a payer in the Certification File, reset transaction header
; values based on this payer sheet
I $P(^BPS(9002313.31,ENTRY,0),"^",4) D
. S BPS("NCPDP","IEN")=$P(^BPS(9002313.31,ENTRY,0),"^",4)
. S BPS("NCPDP","Version")=$P($G(^BPSF(9002313.92,BPS("NCPDP","IEN"),1)),U,2)
;
; Get the Maximum claims per transmission
S BPS("NCPDP","# Meds/Claim")=+$P($G(^BPS(9002313.31,ENTRY,0)),U,6)
I BPS("NCPDP","# Meds/Claim")=0 S BPS("NCPDP","# Meds/Claim")=1
;
; Loop through claim header fields
S A=0,N=1
F S A=$O(^BPS(9002313.31,ENTRY,1,A)) Q:'A D
. S X=^BPS(9002313.31,ENTRY,1,A,0)
. S FIELD=$P(^BPSF(9002313.91,$P(X,U),0),U)
. D SETBPS1(FIELD,$P(X,U,2))
;
; Loop through prescription fields
; Set variable DUR for first DUR record
S N=0,DUR=1
F S N=$O(^BPS(9002313.31,ENTRY,2,N)) Q:'N D
. S A=0
. F S A=$O(^BPS(9002313.31,ENTRY,2,N,1,A)) Q:'A D
.. S X=^BPS(9002313.31,ENTRY,2,N,1,A,0)
.. S FIELD=$P(^BPSF(9002313.91,$P(X,U),0),U)
.. D SETBPS1(FIELD,$P(X,U,2),N)
. ;
. ; Submission Clarification Codes
. K BPS("RX",N,"Submission Clarif Code")
. S A=0,CNT=0
. F S A=$O(^BPS(9002313.31,ENTRY,2,N,2,A)) Q:'A D
.. S X=^BPS(9002313.31,ENTRY,2,N,2,A,0)
.. I X]"" S CNT=CNT+1,BPS("RX",N,"Submission Clarif Code",CNT)=X
. ;
. ; Other Amount Claimed
. K BPS("RX",N,"Other Amt Qual")
. S A=0,CNT=0
. F S A=$O(^BPS(9002313.31,ENTRY,2,N,4,A)) Q:'A D
.. S X=^BPS(9002313.31,ENTRY,2,N,4,A,0)
.. I X]"" D
... S CNT=CNT+1
... S BPS("RX",N,"Other Amt Value",CNT)=$P(X,U,1)
... S BPS("RX",N,"Other Amt Qual",CNT)=$P(X,U,2)
. ;
. ; COB data
. K BPS("RX",N,"OTHER PAYER")
. S A=0,CNT=0
. F S A=$O(^BPS(9002313.31,ENTRY,2,N,3,A)) Q:'A D
.. S CNT=CNT+1
.. S BPS("RX",N,"OTHER PAYER",CNT,0)=$G(^BPS(9002313.31,ENTRY,2,N,3,A,0))
.. ; Other Payer Paid Amounts
.. S B=0,CNT2=0
.. F S B=$O(^BPS(9002313.31,ENTRY,2,N,3,A,1,B)) Q:'B D
... S CNT2=CNT2+1
... S BPS("RX",N,"OTHER PAYER",CNT,"P",CNT2,0)=$G(^BPS(9002313.31,ENTRY,2,N,3,A,1,B,0))
.. I CNT2'=0 S $P(BPS("RX",N,"OTHER PAYER",CNT,0),U,6)=CNT2
.. ; Other Payer Reject Codes
.. S B=0,CNT2=0
.. F S B=$O(^BPS(9002313.31,ENTRY,2,N,3,A,2,B)) Q:'B D
... S CNT2=CNT2+1
... S BPS("RX",N,"OTHER PAYER",CNT,"R",CNT2,0)=$G(^BPS(9002313.31,ENTRY,2,N,3,A,2,B,0))
.. I CNT2'=0 S $P(BPS("RX",N,"OTHER PAYER",CNT,0),U,7)=CNT2
.. ; Other Payer-Patient Paid Amounts
.. S B=0,CNT2=0
.. F S B=$O(^BPS(9002313.31,ENTRY,2,N,3,A,3,B)) Q:'B D
... S CNT2=CNT2+1
... S BPS("RX",N,"OTHER PAYER",CNT,"PP",CNT2,0)=$G(^BPS(9002313.31,ENTRY,2,N,3,A,3,B,0))
.. I CNT2'=0 S $P(BPS("RX",N,"OTHER PAYER",CNT,0),U,8)=CNT2
.. ; Benefit Stages
.. S B=0,CNT2=0
.. F S B=$O(^BPS(9002313.31,ENTRY,2,N,3,A,4,B)) Q:'B D
... S CNT2=CNT2+1
... S BPS("RX",N,"OTHER PAYER",CNT,"BS",CNT2,0)=$G(^BPS(9002313.31,ENTRY,2,N,3,A,4,B,0))
.. I CNT2'=0 S $P(BPS("RX",N,"OTHER PAYER",CNT,0),U,9)=CNT2
. S BPS("RX",N,"OTHER PAYER",0)=CNT
;
; Construct a few other fields that weren't already set
; Patient Name is needed by BPSOSCE
S BPS("Patient","Name")=$G(BPS("Patient","Last Name"))_","_$G(BPS("Patient","First Name"))
Q
;
; Overwrite BPS array values
SETBPS1(FIELD,VALUE,N) ;
N OK S OK=0
N I F I=1:1 Q:$T(TABLE+I)[";;*" D Q:OK
. N X S X=$T(TABLE+I)
. I $P(X,";",3)'=FIELD Q
. S @("BPS("_$P(X,";",4)_")=VALUE")
. S OK=1
Q
;
TABLE ;;
;;101;"NCPDP","BIN Number"
;;102;"NCPDP","Version"
;;103;"Transaction Code"
;;104;"NCPDP","PCN"
;;109;"Transaction Count"
;;110;"NCPDP","Software Vendor/Cert ID"
;;115;"Insurer","Medicaid ID Number"
;;201;"Site","NPI"
;;202;"Service Provider ID Qual"
;;301;"Insurer","Group #"
;;302;"Insurer","Policy #"
;;303;"Insurer","Person Code"
;;304;"Patient","DOB"
;;305;"Patient","Sex"
;;306;"Insurer","Relationship"
;;307;"Patient","Place of Service"
;;308;"Patient","Other Coverage Code"
;;309;"Insurer","Eligibility Clarification Code"
;;310;"Patient","First Name"
;;311;"Patient","Last Name"
;;312;"Cardholder","First Name"
;;313;"Cardholder","Last Name"
;;314;"Home Plan"
;;322;"Patient","Street Address"
;;323;"Patient","City"
;;324;"Patient","State"
;;325;"Patient","Zip"
;;326;"Patient","Phone #"
;;331;"Patient","Patient ID Qualifier"
;;332;"Patient","SSN"
;;344;"RX",N,"Quantity Intended"
;;345;"RX",N,"Days Supply Intended"
;;350;"Patient","Patient E-Mail Address"
;;357;"Claim",N,"Delay Reason Code"
;;359;"Insurer","Medigap ID"
;;360;"Insurer","Medigap Indicator"
;;361;"Insurer","Provider Accept Assign Ind"
;;364;"RX",N,"Prescriber First Name"
;;365;"RX",N,"Prescriber Street Address"
;;366;"RX",N,"Prescriber City Address"
;;367;"RX",N,"Prescriber State/Province Address"
;;368;"RX",N,"Prescriber Zip/Postal Zone"
;;384;"Patient","Patient Residence"
;;391;"Claim",N,"Patient Assignment Indicator"
;;401;"NCPDP","DOS"
;;402;"RX",N,"RX IEN"
;;403;"RX",N,"Refill #"
;;405;"RX",N,"Days Supply"
;;406;"RX",N,"Compound Code"
;;407;"RX",N,"NDC"
;;408;"RX",N,"DAW"
;;409;"RX",N,"Ingredient Cost"
;;411;"RX",N,"Prescriber NPI"
;;412;"RX",N,"Dispensing Fee"
;;414;"RX",N,"Date Written"
;;415;"RX",N,"# Refills"
;;418;"RX",N,"Level of Service"
;;419;"RX",N,"Origin Code"
;;421;"RX",N,"Primary Care Provider NPI"
;;423;"RX",N,"Basis of Cost Determination"
;;424;"RX",N,"Diagnosis Code"
;;426;"RX",N,"Usual & Customary"
;;427;"RX",N,"Prescriber Last Name"
;;429;"RX",N,"Unit Dose Indicator"
;;430;"RX",N,"Gross Amount Due"
;;433;"RX",N,"Patient Paid Amount"
;;436;"RX",N,"Product ID Qualifier"
;;438;"RX",N,"Incentive Amount"
;;439;"RX",N,"DUR",DUR,439
;;440;"RX",N,"DUR",DUR,440
;;441;"RX",N,"DUR",DUR,441
;;442;"RX",N,"Quantity"
;;444;"RX",N,"Provider NPI"
;;445;"Claim",N,"Original Product Code"
;;453;"Claim",N,"Original Product ID Qual"
;;455;"RX",N,"Rx/Service Ref Num Qual"
;;460;"RX",N,"Quantity Prescribed"
;;461;"Claim",N,"Prior Auth Type"
;;462;"Claim",N,"Prior Auth Num Sub"
;;463;"Claim",N,"Intermediary Auth Type ID"
;;464;"Claim",N,"Intermediary Auth ID"
;;465;"RX",N,"Provider ID Qualifier"
;;466;"RX",N,"Prescriber ID Qualifier"
;;467;"RX",N,"Prescriber Billing Location"
;;468;"RX",N,"Primary Care Prov ID Qual"
;;469;"Patient","Primary Care Prov Location Code"
;;470;"RX",N,"Primary Care Prov Last Name"
;;473;"RX",N,"DUR",DUR,473
;;474;"RX",N,"DUR",DUR,474
;;475;"RX",N,"DUR",DUR,475
;;476;"RX",N,"DUR",DUR,476
;;481;"Insurer","Flat Sales Tax Amt Sub"
;;482;"Insurer","Percentage Sales Tax Amt Sub"
;;483;"Insurer","Percent Sales Tax Rate Sub"
;;484;"Insurer","Percent Sales Tax Basis Sub"
;;498;"RX",N,"Prescriber Phone #"
;;524;"Insurer","Plan ID"
;;590;"Provider","Pharmacist Initials"
;;600;"RX",N,"Unit of Measure"
;;678;"Claim","Time of Service"
;;679;"Provider","Pharmacist ID"
;;*
--- Routine Detail --- with STRUCTURED ROUTINE LISTING ---[H[J[2J[HBPSOSC2 7502 printed Oct 16, 2024@17:52:22 Page 2
BPSOSC2 ;BHAM ISC/FCS/DRS - Certification testing ;06/01/2004
+1 ;;1.0;E CLAIMS MGMT ENGINE;**1,5,8,10,11,15**;JUN 2004;Build 13
+2 ;;Per VHA Directive 2004-038, this routine should not be modified.
+3 ;
+4 QUIT
+5 ; SETBPS - Overwrite BPS array with values from BPS Certification file
+6 ; Input
+7 ; ENTRY - IEN for BPS Certification (#9002313.31)
+8 ; Output
+9 ; BPS Array - This is newed in BPSOSCA and is shared by all BPSOSC* routines
+10 ; and others
SETBPS(ENTRY) ;
+1 ;
+2 IF $GET(ENTRY)=""
QUIT
+3 ;
+4 ; Initialize some variables
+5 NEW A,B,N,X,DUR,FIELD,CNT,CNT2
+6 ;
+7 ; If there is a payer in the Certification File, reset transaction header
+8 ; values based on this payer sheet
+9 IF $PIECE(^BPS(9002313.31,ENTRY,0),"^",4)
Begin DoDot:1
+10 SET BPS("NCPDP","IEN")=$PIECE(^BPS(9002313.31,ENTRY,0),"^",4)
+11 SET BPS("NCPDP","Version")=$PIECE($GET(^BPSF(9002313.92,BPS("NCPDP","IEN"),1)),U,2)
End DoDot:1
+12 ;
+13 ; Get the Maximum claims per transmission
+14 SET BPS("NCPDP","# Meds/Claim")=+$PIECE($GET(^BPS(9002313.31,ENTRY,0)),U,6)
+15 IF BPS("NCPDP","# Meds/Claim")=0
SET BPS("NCPDP","# Meds/Claim")=1
+16 ;
+17 ; Loop through claim header fields
+18 SET A=0
SET N=1
+19 FOR
SET A=$ORDER(^BPS(9002313.31,ENTRY,1,A))
if 'A
QUIT
Begin DoDot:1
+20 SET X=^BPS(9002313.31,ENTRY,1,A,0)
+21 SET FIELD=$PIECE(^BPSF(9002313.91,$PIECE(X,U),0),U)
+22 DO SETBPS1(FIELD,$PIECE(X,U,2))
End DoDot:1
+23 ;
+24 ; Loop through prescription fields
+25 ; Set variable DUR for first DUR record
+26 SET N=0
SET DUR=1
+27 FOR
SET N=$ORDER(^BPS(9002313.31,ENTRY,2,N))
if 'N
QUIT
Begin DoDot:1
+28 SET A=0
+29 FOR
SET A=$ORDER(^BPS(9002313.31,ENTRY,2,N,1,A))
if 'A
QUIT
Begin DoDot:2
+30 SET X=^BPS(9002313.31,ENTRY,2,N,1,A,0)
+31 SET FIELD=$PIECE(^BPSF(9002313.91,$PIECE(X,U),0),U)
+32 DO SETBPS1(FIELD,$PIECE(X,U,2),N)
End DoDot:2
+33 ;
+34 ; Submission Clarification Codes
+35 KILL BPS("RX",N,"Submission Clarif Code")
+36 SET A=0
SET CNT=0
+37 FOR
SET A=$ORDER(^BPS(9002313.31,ENTRY,2,N,2,A))
if 'A
QUIT
Begin DoDot:2
+38 SET X=^BPS(9002313.31,ENTRY,2,N,2,A,0)
+39 IF X]""
SET CNT=CNT+1
SET BPS("RX",N,"Submission Clarif Code",CNT)=X
End DoDot:2
+40 ;
+41 ; Other Amount Claimed
+42 KILL BPS("RX",N,"Other Amt Qual")
+43 SET A=0
SET CNT=0
+44 FOR
SET A=$ORDER(^BPS(9002313.31,ENTRY,2,N,4,A))
if 'A
QUIT
Begin DoDot:2
+45 SET X=^BPS(9002313.31,ENTRY,2,N,4,A,0)
+46 IF X]""
Begin DoDot:3
+47 SET CNT=CNT+1
+48 SET BPS("RX",N,"Other Amt Value",CNT)=$PIECE(X,U,1)
+49 SET BPS("RX",N,"Other Amt Qual",CNT)=$PIECE(X,U,2)
End DoDot:3
End DoDot:2
+50 ;
+51 ; COB data
+52 KILL BPS("RX",N,"OTHER PAYER")
+53 SET A=0
SET CNT=0
+54 FOR
SET A=$ORDER(^BPS(9002313.31,ENTRY,2,N,3,A))
if 'A
QUIT
Begin DoDot:2
+55 SET CNT=CNT+1
+56 SET BPS("RX",N,"OTHER PAYER",CNT,0)=$GET(^BPS(9002313.31,ENTRY,2,N,3,A,0))
+57 ; Other Payer Paid Amounts
+58 SET B=0
SET CNT2=0
+59 FOR
SET B=$ORDER(^BPS(9002313.31,ENTRY,2,N,3,A,1,B))
if 'B
QUIT
Begin DoDot:3
+60 SET CNT2=CNT2+1
+61 SET BPS("RX",N,"OTHER PAYER",CNT,"P",CNT2,0)=$GET(^BPS(9002313.31,ENTRY,2,N,3,A,1,B,0))
End DoDot:3
+62 IF CNT2'=0
SET $PIECE(BPS("RX",N,"OTHER PAYER",CNT,0),U,6)=CNT2
+63 ; Other Payer Reject Codes
+64 SET B=0
SET CNT2=0
+65 FOR
SET B=$ORDER(^BPS(9002313.31,ENTRY,2,N,3,A,2,B))
if 'B
QUIT
Begin DoDot:3
+66 SET CNT2=CNT2+1
+67 SET BPS("RX",N,"OTHER PAYER",CNT,"R",CNT2,0)=$GET(^BPS(9002313.31,ENTRY,2,N,3,A,2,B,0))
End DoDot:3
+68 IF CNT2'=0
SET $PIECE(BPS("RX",N,"OTHER PAYER",CNT,0),U,7)=CNT2
+69 ; Other Payer-Patient Paid Amounts
+70 SET B=0
SET CNT2=0
+71 FOR
SET B=$ORDER(^BPS(9002313.31,ENTRY,2,N,3,A,3,B))
if 'B
QUIT
Begin DoDot:3
+72 SET CNT2=CNT2+1
+73 SET BPS("RX",N,"OTHER PAYER",CNT,"PP",CNT2,0)=$GET(^BPS(9002313.31,ENTRY,2,N,3,A,3,B,0))
End DoDot:3
+74 IF CNT2'=0
SET $PIECE(BPS("RX",N,"OTHER PAYER",CNT,0),U,8)=CNT2
+75 ; Benefit Stages
+76 SET B=0
SET CNT2=0
+77 FOR
SET B=$ORDER(^BPS(9002313.31,ENTRY,2,N,3,A,4,B))
if 'B
QUIT
Begin DoDot:3
+78 SET CNT2=CNT2+1
+79 SET BPS("RX",N,"OTHER PAYER",CNT,"BS",CNT2,0)=$GET(^BPS(9002313.31,ENTRY,2,N,3,A,4,B,0))
End DoDot:3
+80 IF CNT2'=0
SET $PIECE(BPS("RX",N,"OTHER PAYER",CNT,0),U,9)=CNT2
End DoDot:2
+81 SET BPS("RX",N,"OTHER PAYER",0)=CNT
End DoDot:1
+82 ;
+83 ; Construct a few other fields that weren't already set
+84 ; Patient Name is needed by BPSOSCE
+85 SET BPS("Patient","Name")=$GET(BPS("Patient","Last Name"))_","_$GET(BPS("Patient","First Name"))
+86 QUIT
+87 ;
+88 ; Overwrite BPS array values
SETBPS1(FIELD,VALUE,N) ;
+1 NEW OK
SET OK=0
+2 NEW I
FOR I=1:1
if $TEXT(TABLE+I)[";;*"
QUIT
Begin DoDot:1
+3 NEW X
SET X=$TEXT(TABLE+I)
+4 IF $PIECE(X,";",3)'=FIELD
QUIT
+5 SET @("BPS("_$PIECE(X,";",4)_")=VALUE")
+6 SET OK=1
End DoDot:1
if OK
QUIT
+7 QUIT
+8 ;
TABLE ;;
+1 ;;101;"NCPDP","BIN Number"
+2 ;;102;"NCPDP","Version"
+3 ;;103;"Transaction Code"
+4 ;;104;"NCPDP","PCN"
+5 ;;109;"Transaction Count"
+6 ;;110;"NCPDP","Software Vendor/Cert ID"
+7 ;;115;"Insurer","Medicaid ID Number"
+8 ;;201;"Site","NPI"
+9 ;;202;"Service Provider ID Qual"
+10 ;;301;"Insurer","Group #"
+11 ;;302;"Insurer","Policy #"
+12 ;;303;"Insurer","Person Code"
+13 ;;304;"Patient","DOB"
+14 ;;305;"Patient","Sex"
+15 ;;306;"Insurer","Relationship"
+16 ;;307;"Patient","Place of Service"
+17 ;;308;"Patient","Other Coverage Code"
+18 ;;309;"Insurer","Eligibility Clarification Code"
+19 ;;310;"Patient","First Name"
+20 ;;311;"Patient","Last Name"
+21 ;;312;"Cardholder","First Name"
+22 ;;313;"Cardholder","Last Name"
+23 ;;314;"Home Plan"
+24 ;;322;"Patient","Street Address"
+25 ;;323;"Patient","City"
+26 ;;324;"Patient","State"
+27 ;;325;"Patient","Zip"
+28 ;;326;"Patient","Phone #"
+29 ;;331;"Patient","Patient ID Qualifier"
+30 ;;332;"Patient","SSN"
+31 ;;344;"RX",N,"Quantity Intended"
+32 ;;345;"RX",N,"Days Supply Intended"
+33 ;;350;"Patient","Patient E-Mail Address"
+34 ;;357;"Claim",N,"Delay Reason Code"
+35 ;;359;"Insurer","Medigap ID"
+36 ;;360;"Insurer","Medigap Indicator"
+37 ;;361;"Insurer","Provider Accept Assign Ind"
+38 ;;364;"RX",N,"Prescriber First Name"
+39 ;;365;"RX",N,"Prescriber Street Address"
+40 ;;366;"RX",N,"Prescriber City Address"
+41 ;;367;"RX",N,"Prescriber State/Province Address"
+42 ;;368;"RX",N,"Prescriber Zip/Postal Zone"
+43 ;;384;"Patient","Patient Residence"
+44 ;;391;"Claim",N,"Patient Assignment Indicator"
+45 ;;401;"NCPDP","DOS"
+46 ;;402;"RX",N,"RX IEN"
+47 ;;403;"RX",N,"Refill #"
+48 ;;405;"RX",N,"Days Supply"
+49 ;;406;"RX",N,"Compound Code"
+50 ;;407;"RX",N,"NDC"
+51 ;;408;"RX",N,"DAW"
+52 ;;409;"RX",N,"Ingredient Cost"
+53 ;;411;"RX",N,"Prescriber NPI"
+54 ;;412;"RX",N,"Dispensing Fee"
+55 ;;414;"RX",N,"Date Written"
+56 ;;415;"RX",N,"# Refills"
+57 ;;418;"RX",N,"Level of Service"
+58 ;;419;"RX",N,"Origin Code"
+59 ;;421;"RX",N,"Primary Care Provider NPI"
+60 ;;423;"RX",N,"Basis of Cost Determination"
+61 ;;424;"RX",N,"Diagnosis Code"
+62 ;;426;"RX",N,"Usual & Customary"
+63 ;;427;"RX",N,"Prescriber Last Name"
+64 ;;429;"RX",N,"Unit Dose Indicator"
+65 ;;430;"RX",N,"Gross Amount Due"
+66 ;;433;"RX",N,"Patient Paid Amount"
+67 ;;436;"RX",N,"Product ID Qualifier"
+68 ;;438;"RX",N,"Incentive Amount"
+69 ;;439;"RX",N,"DUR",DUR,439
+70 ;;440;"RX",N,"DUR",DUR,440
+71 ;;441;"RX",N,"DUR",DUR,441
+72 ;;442;"RX",N,"Quantity"
+73 ;;444;"RX",N,"Provider NPI"
+74 ;;445;"Claim",N,"Original Product Code"
+75 ;;453;"Claim",N,"Original Product ID Qual"
+76 ;;455;"RX",N,"Rx/Service Ref Num Qual"
+77 ;;460;"RX",N,"Quantity Prescribed"
+78 ;;461;"Claim",N,"Prior Auth Type"
+79 ;;462;"Claim",N,"Prior Auth Num Sub"
+80 ;;463;"Claim",N,"Intermediary Auth Type ID"
+81 ;;464;"Claim",N,"Intermediary Auth ID"
+82 ;;465;"RX",N,"Provider ID Qualifier"
+83 ;;466;"RX",N,"Prescriber ID Qualifier"
+84 ;;467;"RX",N,"Prescriber Billing Location"
+85 ;;468;"RX",N,"Primary Care Prov ID Qual"
+86 ;;469;"Patient","Primary Care Prov Location Code"
+87 ;;470;"RX",N,"Primary Care Prov Last Name"
+88 ;;473;"RX",N,"DUR",DUR,473
+89 ;;474;"RX",N,"DUR",DUR,474
+90 ;;475;"RX",N,"DUR",DUR,475
+91 ;;476;"RX",N,"DUR",DUR,476
+92 ;;481;"Insurer","Flat Sales Tax Amt Sub"
+93 ;;482;"Insurer","Percentage Sales Tax Amt Sub"
+94 ;;483;"Insurer","Percent Sales Tax Rate Sub"
+95 ;;484;"Insurer","Percent Sales Tax Basis Sub"
+96 ;;498;"RX",N,"Prescriber Phone #"
+97 ;;524;"Insurer","Plan ID"
+98 ;;590;"Provider","Pharmacist Initials"
+99 ;;600;"RX",N,"Unit of Measure"
+100 ;;678;"Claim","Time of Service"
+101 ;;679;"Provider","Pharmacist ID"
+102 ;;*
