Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DDGFAPC

DDGFAPC.m

Go to the documentation of this file.
  1. DDGFAPC ;SFISC/MKO-ADJUST PAGE COORDINATES ;01:16 PM 19 Jan 1994
  1. ;;22.2;VA FileMan;;Jan 05, 2016;Build 42
  1. ;;Per VA Directive 6402, this routine should not be modified.
  1. ;;Submitted to OSEHRA 5 January 2015 by the VISTA Expertise Network.
  1. ;;Based on Medsphere Systems Corporation's MSC FileMan 1051.
  1. ;;Licensed under the terms of the Apache License, Version 2.0.
  1. ;
  1. ;Input:
  1. ; T = PTOP: top of page
  1. ; PBRC: bottom right corner of page
  1. ;Returns:
  1. ; DDGFLIM
  1. ;
  1. N DDGFE,P1,P2,P3,P4
  1. ;
  1. D SETUP
  1. S DDGFE=0 F S Y=$$READ W:$T(@Y)="" $C(7) D:$T(@Y)]"" @Y Q:DDGFE
  1. D CLEANUP
  1. Q
  1. ;
  1. DESELECT ;
  1. S DDGFE=1
  1. Q
  1. ;
  1. LNU Q:DY'>$P(DDGFLIM,U)
  1. D MV(DY-1,DX)
  1. Q
  1. LND Q:DY'<$P(DDGFLIM,U,3)
  1. D MV(DY+1,DX)
  1. Q
  1. CHR Q:DX'<$P(DDGFLIM,U,4)
  1. D MV(DY,DX+1)
  1. Q
  1. CHL Q:DX'>$P(DDGFLIM,U,2)
  1. D MV(DY,DX-1)
  1. Q
  1. TBR Q:DX'<$P(DDGFLIM,U,4)
  1. D MV(DY,DX+$$MIN(5,$P(DDGFLIM,U,4)-DX))
  1. Q
  1. TBL Q:DX'>$P(DDGFLIM,U,2)
  1. D MV(DY,DX-$$MIN(5,DX-$P(DDGFLIM,U,2)))
  1. Q
  1. SCT Q:DY'>$P(DDGFLIM,U)
  1. D MV($P(DDGFLIM,U),DX)
  1. Q
  1. SCB Q:DY'<$P(DDGFLIM,U,3)
  1. D MV($P(DDGFLIM,U,3),DX)
  1. Q
  1. SCR Q:DX'<$P(DDGFLIM,U,4)
  1. D MV(DY,$P(DDGFLIM,U,4))
  1. Q
  1. SCL Q:DX'>$P(DDGFLIM,U,2)
  1. D MV(DY,$P(DDGFLIM,U,2))
  1. Q
  1. ;
  1. MV(DDGFY,DDGFX) ;
  1. I T="PTOP" D
  1. . F DDGFC=P1_U_P2,P1_U_P4,P3_U_P2,P3_U_P4 D REPALL^DDGLIBW(DDGFC_"^1^1")
  1. . S P1=P1+DDGFY-DY,P2=P2+DDGFX-DX,P3=P3+DDGFY-DY,P4=P4+DDGFX-DX
  1. ;
  1. I T="PBRC" D
  1. . D:DDGFX'=DX REPALL^DDGLIBW(P1_U_P4_"^1^1")
  1. . D:DDGFY'=DY REPALL^DDGLIBW(P3_U_P2_"^1^1")
  1. . D REPALL^DDGLIBW(P3_U_P4_"^1^1")
  1. . S P3=P3+DDGFY-DY,P4=P4+DDGFX-DX
  1. ;
  1. D CORNER()
  1. S DY=DDGFY,DX=DDGFX
  1. K DDGFC
  1. Q
  1. ;
  1. CORNER(N) ;Draw corners of box
  1. ;In: P1,P2,P3,P4,T; if N:normal video
  1. N DY,DX
  1. S DY=P1,DX=P2 X IOXY
  1. W $P(DDGLGRA,DDGLDEL)_$S($G(N):"",1:$P(DDGLVID,DDGLDEL,6))_$P(DDGLGRA,DDGLDEL,5)
  1. S DY=P1,DX=P4 X IOXY W $P(DDGLGRA,DDGLDEL,6)
  1. S DY=P3,DX=P2 X IOXY W $P(DDGLGRA,DDGLDEL,7)
  1. S DX=P4 X IOXY
  1. W $P(DDGLGRA,DDGLDEL,8)_$S($G(N):"",1:$P(DDGLVID,DDGLDEL,10))_$P(DDGLGRA,DDGLDEL,2)
  1. Q
  1. ;
  1. MIN(X,Y,Z) ;Return the minimum of two or three numbers
  1. N A
  1. S A=$S(X<Y:X,1:Y)
  1. Q:$G(Z)="" A
  1. Q $S(A<Z:A,1:Z)
  1. ;
  1. RC(DDGFY,DDGFX) ;Update status line, reset DX and DY, move cursor
  1. N S
  1. I DDGFR D
  1. . S DY=IOSL-6,DX=IOM-9,S="R"_(DDGFY+1)_",C"_(DDGFX+1)
  1. . X IOXY W S_$J("",7-$L(S))
  1. S DY=DDGFY,DX=DDGFX X IOXY
  1. Q
  1. ;
  1. SETUP ;Initial setup
  1. S DDGFDY=DY,DDGFDX=DX
  1. ;
  1. ;Get page coordinates
  1. S P4=@DDGFREF@("F",DDGFPG)
  1. S P1=$P(P4,U),P2=$P(P4,U,2),P3=$P(P4,U,3),P4=$P(P4,U,4)
  1. S DDGFAREA=P1_U_P2_U_(P3-P1+1)_U_(P4-P2+1)
  1. ;
  1. ;Draw corners in reverse video, reset DDGFLIM
  1. D CORNER()
  1. I T="PTOP" S DDGFLIM=0_U_(DX-P2)_U_(DY+IOSL-8-P3)_U_(DX+IOM-2-P4)
  1. I T="PBRC" S DDGFLIM=P1+2_U_(P2+2)_U_(IOSL-8)_U_(IOM-2)
  1. Q
  1. ;
  1. CLEANUP ;Final cleanup
  1. I DDGFDY'=DY!(DDGFDX'=DX) D
  1. . D PAGE^DDGFUPDP(P1,P2,P3,P4,T,DDGFAREA)
  1. E D CORNER(1) S DDGFLIM=P1_U_P2_U_P3_U_P4
  1. ;
  1. D RC(DY,DX)
  1. K DDGFDY,DDGFDX,DDGFAREA
  1. Q
  1. ;
  1. READ() N S,Y
  1. F R *Y:DTIME D C Q:Y'=-1
  1. Q Y
  1. ;
  1. C I Y<0 S Y="TO" Q
  1. S S=""
  1. C1 S S=S_$C(Y)
  1. I DDGF("SIN")'[(U_S) D I Y=-1 W $C(7) Q
  1. . I $C(Y)'?1L S Y=-1 Q
  1. . S S=$E(S,1,$L(S)-1)_$C(Y-32) S:DDGF("SIN")'[(U_S_U) Y=-1
  1. ;
  1. I DDGF("SIN")[(U_S_U),S'=$C(27) S Y=$P(DDGF("SOUT"),U,$L($P(DDGF("SIN"),U_S_U),U)) Q
  1. R *Y:5 G:Y'=-1 C1 W $C(7)
  1. Q