Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: DVBA16PI

DVBA16PI.m

Go to the documentation of this file. 
  1. DVBA16PI ;ALB/JFP  EXAM FILE UPDATE - POST INT ; 17 FEB 1998
  1.  ;;2.7;AMIE;**16**;Apr 10, 1995
  1.  ;
  1.  ; This is the post-install for patch 16 to inactivate old Exams and
  1.  ; add new Exams into AMIE EXAM file (396.6).
  1.  ;
  1. EN ;
  1.  D BMES^XPDUTL("DVBA*2.7*16 Post Installation --")
  1.  D MES^XPDUTL("   Update to AMIE EXAM file (#396.6).")
  1.  D MES^XPDUTL("  ")
  1.  I '$D(^DVB(396.6)) D BMES^XPDUTL("Missing file 396.6, AMIE EXAM file")
  1.  I $D(^DVB(396.6)) D
  1.  .D INACT
  1.  .D NEW
  1.  Q
  1.  ;
  1. INACT ;inactivate exams
  1.  N LINE,IEN,EXM,PNM,BDY,ROU,STAT,WKS,DIE,DR,DA,X,Y
  1.  D BMES^XPDUTL("Inactivating AMIE EXAM file entries...")
  1.  F I=1:1 S LINE=$P($T(TXTOLD+I),";;",2) Q:LINE="QUIT"  D
  1.  .D GET K X,Y,DA
  1.  .I $P($G(^DVB(396.6,IEN,0)),"^",1)'=EXM D  Q
  1.  ..D BMES^XPDUTL("  *** Warning - Entry #"_IEN)
  1.  ..D MES^XPDUTL("                for exam "_EXM)
  1.  ..D MES^XPDUTL("                could not be inactivated.")
  1.  .S DIE="^DVB(396.6,",DA=IEN,DR=".5///I" D ^DIE
  1.  .D BMES^XPDUTL("  Entry #"_IEN_" for exam "_EXM)
  1.  .D MES^XPDUTL("     successfully inactivated.")
  1.  D MES^XPDUTL("  ")
  1.  Q
  1.  ;
  1. NEW ;add new exam
  1.  N LINE,IEN,EXM,PNM,BDY,ROU,STAT,WKS,DIC,DIE,DR,DA,X,Y
  1.  D BMES^XPDUTL("Adding new AMIE EXAM file entries...")
  1.  F I=1:1 S LINE=$P($T(TXTNEW+I),";;",2) Q:LINE="QUIT"  D
  1.  .D GET K X,Y,DA
  1.  .D BMES^XPDUTL("  Attempting to add Entry #"_IEN_"...")
  1.  .I $D(^DVB(396.6,IEN,0)) D  Q
  1.  ..D MES^XPDUTL("  You already have an Entry #"_IEN_".")
  1.  ..D MES^XPDUTL("  Updating "_EXM_".")
  1.  ..S DIE="^DVB(396.6,",DA=IEN,DR=".01///"_EXM_";.07///"_WKS_";.5///"_STAT_";2///"_BDY_";6///"_PNM_";7///"_ROU
  1.  ..D ^DIE
  1.  .S DIC="^DVB(396.6,",DIC(0)="LZ",X=EXM,DINUM=IEN
  1.  .S DIC("DR")=".07///"_WKS_";.5///"_STAT_";2///"_BDY_";6///"_PNM_";7///"_ROU
  1.  .D FILE^DICN
  1.  .I +Y=IEN D  Q
  1.  ..D MES^XPDUTL("  Successfully added Entry #"_IEN)
  1.  ..D MES^XPDUTL("  for exam "_EXM_".")
  1.  .I +Y=-1 D
  1.  ..D MES^XPDUTL("  *** Warning - Unable to add Entry #"_IEN)
  1.  ..D MES^XPDUTL("                for exam "_EXM_".")
  1.  Q
  1. GET ;get exam data
  1.  S (IEN,EXM,PNM,BDY,ROU,STAT,WKS)=""
  1.  S IEN=$P(LINE,";",1) ;ien
  1.  S EXM=$P(LINE,";",2) ;exam name
  1.  S PNM=$P(LINE,";",3) ;print name
  1.  S BDY=$P(LINE,";",4) ;body system
  1.  S ROU=$P(LINE,";",5) ;routine name
  1.  S STAT=$P(LINE,";",6) ;status
  1.  S WKS=$P(LINE,";",8) ;worksheet number
  1.  Q
  1.  ;
  1.  ; List of exams to be inactivated
  1.  ; format:  ien;exam name;;;routine;status;;wks#
  1. TXTOLD ;
  1.  ;;103;AUDIO;;;DVBCWHW;I;;1305
  1.  ;;111;ARTERIES AND VEINS;;;DVBCWAV;I;;0105
  1.  ;;112;HEART AND HYPERTENSION;;;DVBCWHH;I;;0110
  1.  ;;125;ARRHYTHMIAS;;;DVBCWAW;I;;0115
  1.  ;;128;MENTAL DISORDERS (EXCEPT PTSD AND EATING DISORDERS);;;DVBCWMD;I;;0905
  1.  ;;QUIT
  1.  ;
  1.  ;
  1.  ; List of new exams to activate
  1.  ; format:  ien;exam name;print name;body system;routine;status;;wks#
  1. TXTNEW ;
  1.  ;;153;AUDIO;AUDIO;ORGANS OF SENSE;DVBCWIO;A; ;1305
  1.  ;;154;ARTERIES, VEINS AND MISCELLANEOUS;ARTERIES/VEINS;CARDIOVASCULAR;DVBCWVN;A; ;0105
  1.  ;;155;HEART;HEART;CARDIOVASCULAR;DVBCWHE;A; ;0110
  1.  ;;156;HYPERTENSION;HYPERTENSION;CARDIOVASCULAR;DVBCWHY;A; ;0120
  1.  ;;157;ARRHYTHMIAS;ARRHYTHMIAS;CARDIOVASCULAR;DVBCWAM;A; ;0115
  1.  ;;158;MENTAL DISORDERS (NOT INITIAL PTSD OR EATING DISORDERS);MENTAL DISORDERS;MENTAL;DVBCWMO;A; ;0905
  1.  ;;159;GULF WAR GUIDELINES;GULF WAR GUIDELINES;SPECIAL;DVBCWGW;A; ;1740
  1.  ;;QUIT