Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: EAS1192P

EAS1192P.m

Go to the documentation of this file. 
  1. EAS1192P ;DEV/BJR - EAS*1.0*192 POST-INSTALL ; Jun 09, 2020@10:51
  1.  ;;1.0;ENROLLMENT APPLICATION SYSTEM;**192**;MAR 15,2001;Build 7
  1.  ;
  1.  Q
  1.  ;
  1.  ; ICR #10141 supports BMES^XPDUTL call
  1.  ; ICR #2054 supports IENS^DILF and CLEAN^DILF calls
  1.  ; ICR #2053 supports UPDATE^DIE call
  1.  ; ICR #10103 supports FMADD^XLFDT call
  1.  ; ICR #10056 supports ^DIC(5) direct global read
  1.  ; ICR #10104 supports UP^XLFSTR call
  1.  ;
  1. PRETRAN ;Load tables
  1.  I $G(DUZ("AG"))'="V" Q
  1.  M @XPDGREF@("EAS1192")=^XTMP("EAS1192")
  1.  Q
  1.  ;
  1. EN ; Display a message to inform the user that there will be a slight
  1.  ; delay when installing the patch.
  1.  ;
  1.  N EASMESS
  1.  S EASMESS(1)="POST-INSTALLATION PROCESSING"
  1.  S EASMESS(2)="---------------------------"
  1.  S EASMESS(3)="This installation will take some time due to the large size of the file."
  1.  S EASMESS(4)="Please be patient and allow the process to complete.  Thank you!"
  1.  S EASMESS(5)=""
  1.  D BMES^XPDUTL(.EASMESS)
  1.  D ADD
  1.  Q
  1. ADD ; Parse the data coming in and file it to the globals
  1.  K ^XTMP("EAS1192")
  1.  M ^XTMP("EAS1192")=@XPDGREF@("EAS1192")
  1.  S ^XTMP("EAS1192",0)=$$FMADD^XLFDT(DT,30)_U_DT_U_"Create Zip Code FIPS code Xref"
  1.  S ^XTMP("EAS1192H",0)=$$FMADD^XLFDT(DT,30)_U_DT_U_"Duplicate FIPS not filed"
  1.  N EASGMT,EASCNTR,EASCNT,EASJ,EASRECA,EASRECR,EASDATA,EASMSG,EASADD,EASX,EASNODE
  1.  S EASRECA=0,EASRECR=0
  1.  S EASCNTR="" F  S EASCNTR=$O(^XTMP("EAS1192","DATA",2020,EASCNTR)) Q:'EASCNTR  D
  1.  .S EASGMT("YEAR")=3200000
  1.  .S EASGMT("COUNTY NAME")=$$UP^XLFSTR($P(^XTMP("EAS1192","DATA",2020,EASCNTR),U,2))
  1.  .S EASGMT("STATE")=$P(^XTMP("EAS1192","DATA",2020,EASCNTR),U)
  1.  .S EASGMT("MSA")=$P(^XTMP("EAS1192","DATA",2020,EASCNTR),U,4)
  1.  .I EASGMT("MSA")=10000 S EASGMT("MSA")=0
  1.  .F EASCNT=1:1:8 S EASGMT("THR"_EASCNT)=$P(^XTMP("EAS1192","DATA",2020,EASCNTR),U,(EASCNT+4))
  1.  .S EASGMT("STATE")=$E("00",1,2-$L(EASGMT("STATE")))_EASGMT("STATE")
  1.  .S EASGMT("FIPS")=$P(^XTMP("EAS1192","DATA",2020,EASCNTR),U,3)
  1.  .S EASGMT("ST IEN")=$O(^DIC(5,"C",EASGMT("STATE"),""))
  1.  .S EASDATA(.01)=$G(EASGMT("YEAR"))
  1.  .S EASDATA(.02)=$G(EASGMT("FIPS"))
  1.  .S EASDATA(.03)=$G(EASGMT("ST IEN"))
  1.  .S EASDATA(.04)=$G(EASGMT("COUNTY NAME"))
  1.  .S EASDATA(.05)=$G(EASGMT("MSA"))
  1.  .F EASJ=1:1:8 S EASDATA(.10+(EASJ*.01))=$G(EASGMT("THR"_EASJ))
  1.  .S EASX="" F  S EASX=$O(EASDATA(EASX)) Q:'EASX
  1.  .S EASADD=$$FILE(712.5,,.EASDATA,.EASERR)
  1.  .I EASADD S EASRECA=EASRECA+1
  1.  .I 'EASADD D
  1.  ..S EASRECR=EASRECR+1
  1.  ..S EASNODE=EASDATA(.01)_"^"_EASDATA(.02)_"^"_EASDATA(.03)_"^"_EASDATA(.04)_"^"_EASDATA(.05)
  1.  ..S EASNODE=EASNODE_"^"_EASDATA(.11)_"^"_EASDATA(.12)_"^"_EASDATA(.13)_"^"_EASDATA(.14)
  1.  ..S EASNODE=EASNODE_"^"_EASDATA(.15)_"^"_EASDATA(.16)_"^"_EASDATA(.17)_"^"_EASDATA(.18)
  1.  ..S ^XTMP("EAS1192H",EASRECR)=EASNODE_"^"_$G(EASERR)
  1.  S EASMSG(1)="Number of records added: "_EASRECA
  1.  S EASMSG(2)="Number of duplicate records: "_EASRECR
  1.  D BMES^XPDUTL(.EASMSG)
  1.  Q
  1. FILE(EASFILE,EASENDA,EASDATA,EASERR) ; File Data
  1.  ;Description: Creates a new record and files the data.
  1.  ; Input:
  1.  ; EASFILE - File or sub-file number
  1.  ; EASENDA - New name for traditional FileMan DA array with same
  1.  ; meaning. Pass by reference.  Only needed if adding to a
  1.  ; subfile.
  1.  ; EASDATA - Data array to file, pass by reference
  1.  ; Format: EASDATA(<field #>)=<value>
  1.  ;
  1.  ; Output:
  1.  ; Function Value - If no error then it returns the ien of the created record, else returns NULL.
  1.  ; EASENDA - returns the ien of the new record, NULL if none created.  If needed, pass by reference.
  1.  ; EASERR - optional error message - if needed, pass by reference
  1.  ;
  1.  ; Example: To add a record in subfile 2.0361 in the record with ien=353
  1.  ; with the field .01 value = 21:
  1.  ; S EASDATA(.01)=21,EASENDA(1)=353 I $$FILE^EAS1192(2.0361,.EASENDA,.EASDATA) W!,"DONE"
  1.  ;
  1.  ; Example: If creating a record not in a subfile, would look like this:
  1.  ; S EASDATA(.01)=21 I $$FILE^EAS1192(867,,.EASDATA) W !,"DONE"
  1.  ;
  1.  N EASFDA,EASFLD,EASIENA,EASIENS,EASERRS,EASIEN,DIERR
  1.  ;
  1.  ;EASIENS - Internal Entry Number String defined by FM
  1.  ;EASIENA - the Internal Entry Numebr Array defined by FM
  1.  ;EASFDA - the FDA array defined by FM
  1.  ;EASIEN - the ien of the new record
  1.  ;
  1.  S EASENDA="+1"
  1.  S EASIENS=$$IENS^DILF(.EASENDA)
  1.  S EASFLD=0
  1.  F  S EASFLD=$O(EASDATA(EASFLD)) Q:'EASFLD  D
  1.  .S EASFDA(EASFILE,EASIENS,EASFLD)=$G(EASDATA(EASFLD))
  1.  D UPDATE^DIE("","EASFDA","EASIENA","EASERRS(1)")
  1.  I +$G(DIERR) D
  1.  .S EASERR=$G(EASERRS(1,"DIERR",1,"TEXT",1))
  1.  .S EASIEN=""
  1.  E  D
  1.  .S EASIEN=EASIENA(1)
  1.  .S EASERR=""
  1.  D CLEAN^DILF
  1.  S EASENDA=EASIEN
  1.  Q EASIEN