Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ENFAR3

ENFAR3.m

Go to the documentation of this file. 
  1. ENFAR3 ;WIRMFO/SAB-FIXED ASSET RPT, CHECK OF EQUIP CAPITALIZATION ;5/29/2002
  1.  ;;7.0;ENGINEERING;**25,63,71**;Aug 17, 1993
  1.  ;-----------------------------------------------------------------
  1.  ;Patch 71 Increases Threshold from $25,000.00 to $100,000.00
  1.  ;
  1.  ;ENCAP = Investment Category
  1.  ;ENSGL = Standard General Ledger
  1.  ; ENCT = Capitalization Threshold
  1.  ;ENTYI = Type of Entry
  1.  ;
  1.  ;-----------------------------------------------------------------
  1. EN W !,"This report searches the entire equipment file and may take some"
  1.  W !,"time to complete. Consider queuing this report to run after-hours."
  1.  ; ask device
  1.  S %ZIS="QM" D ^%ZIS G:POP EXIT
  1.  I $D(IO("Q")) D  G EXIT
  1.  . S ZTRTN="QEN^ENFAR3",ZTDESC="Check of Equipment Capitalization"
  1.  . D ^%ZTLOAD,HOME^%ZIS K ZTSK
  1. QEN ; queued entry
  1.  U IO
  1.  S (END,ENPG)=0 D NOW^%DTC S Y=% D DD^%DT S ENDT=Y
  1.  S ENL="",$P(ENL,"-",IOM)=""
  1.  D HD
  1.  ;
  1.  ;The new capitalization threshold of 100K will take effect for
  1.  ;this report after the 1-time job runs on July 24, 2002 (3020724).
  1.  S ENCT=$S(DT>3020724:100000,1:25000)
  1.  ;
  1.  ; loop thru equipment file
  1.  S ENT=0
  1.  S ENDA=0 F  S ENDA=$O(^ENG(6914,ENDA)) Q:'ENDA  D  Q:END
  1.  . Q:$P($G(^ENG(6914,ENDA,3)),U,11)]""  ; ignore dispositioned items
  1.  . S ENY2=$G(^ENG(6914,ENDA,2)),ENY8=$G(^ENG(6914,ENDA,8))
  1.  . S ENTYI=$P($G(^ENG(6914,ENDA,0)),U,4) ;TYPE OF ENTRY (#7)
  1.  . S ENVAL=$P(ENY2,U,3) ;TOTAL ASSET VALUE (#12)
  1.  . S X=$P(ENY2,U,9),ENCMR=$S(X:$P($G(^ENG(6914.1,X,0)),U),1:X)
  1.  . ;;S X=$P(ENY8,U,2),ENCAP=$S(X=1:"YES",X=0:"NO",1:X)
  1.  . S ENCAP=$P(ENY8,U,2) ;INVESTMENT CATEGORY (#34)
  1.  . ;
  1.  . ;ENSGL = Standard General Ledger (#38)
  1.  . S X=$P(ENY8,U,6),ENSGL=$S(X:$P($G(^ENG(6914.3,X,0)),U),1:X)
  1.  . K ENY2,ENY8
  1.  . ; perform checks
  1.  . K EN S ENC=0
  1.  . I ENCAP'=1,ENVAL'<ENCT,ENTYI="NX"!(ENTYI="") D
  1.  . . S ENC=ENC+1,EN(ENC)="Check capitalization"
  1.  . ;
  1.  . ;Investment Category (1) is Capitalized/Accountable
  1.  . I ENCAP=1 D
  1.  . . I ENTYI="" S ENC=ENC+1,EN(ENC)="Type Entry is blank"
  1.  . . I ENTYI="NX" D
  1.  . . . I ENVAL<ENCT S ENC=ENC+1,EN(ENC)="Check capitalization"
  1.  . . . I $$LOC^ENFAVAL(ENCMR)="" S ENC=ENC+1,EN(ENC)="Check CMR"
  1.  . . . I ENSGL="" S ENC=ENC+1,EN(ENC)="SGL is blank"
  1.  . . . I ENSGL=6100 S ENC=ENC+1,EN(ENC)="SGL is 6100 (Expensed)"
  1.  . I ENC D
  1.  . . ; print questionable equipment item
  1.  . . S ENT=ENT+1
  1.  . . S ENCAP=$S(ENCAP=1:"YES",1:"NO")
  1.  . . I $Y+3+ENC>IOSL D HD Q:END
  1.  . . W !!,ENDA,?12,ENTYI,?19,ENCMR,?26
  1.  . . W $J("$"_$FN(ENVAL,",",2),14),?47,ENCAP,?55,EN(1)
  1.  . . F ENI=2:1:ENC W !,?55,EN(ENI)
  1.  I 'END D
  1.  . W !!,ENT," questionable equipment items found"
  1.  . I $E(IOST,1,2)="C-" S DIR(0)="E" D ^DIR K DIR
  1.  D ^%ZISC
  1. EXIT I $D(ZTQUEUED) S ZTREQ="@"
  1.  K DIR,DIROUT,DIRUT,DTOUT,DUOUT,X,Y
  1.  K END,ENDT,ENL,ENPG
  1.  K EN,ENC,ENCAP,ENCT,ENCMR,ENDA,ENI,ENSGL,ENT,ENTYI,ENVAL
  1.  Q
  1. HD ; header
  1.  I $D(ZTQUEUED),$$S^%ZTLOAD S ZTSTOP=1,END=1 Q
  1.  I $E(IOST,1,2)="C-",ENPG S DIR(0)="E" D ^DIR K DIR I 'Y S END=1 Q
  1.  I $E(IOST,1,2)="C-"!ENPG W @IOF
  1.  S ENPG=ENPG+1
  1.  W !,"CHECK OF EQUIPMENT CAPITALIZATION",?48,ENDT,?72,"page ",ENPG
  1.  W !!,?12,"TYPE"
  1.  W !,"EQUIP ID#",?12,"ENTRY",?19,"CMR",?26,"  ASSET VALUE"
  1.  W ?42,"CAPITALIZED"
  1.  W !,$E(ENL,1,10),?12,$E(ENL,1,5),?19,$E(ENL,1,5),?26,$E(ENL,1,14)
  1.  W ?42,$E(ENL,1,11),?55,$E(ENL,1,23)
  1.  Q
  1.  ;ENFAR3