Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ENPAT15

ENPAT15.m

Go to the documentation of this file. 
  1. ENPAT15 ;WISC/SAB-FIX PM MANHOURS ;1/13/95
  1.  ;;7.0;ENGINEERING;**15**;Aug 17, 1993
  1.  I DUZ(0)'["@" W "Please set DUZ(0)=""@"" and re-run this routine",! Q
  1. PMHRS W !,"Moving inappropriately posted PM manhours"
  1.  S ENI=0
  1.  F  S ENI=$O(^DIC(6922,ENI)) Q:'ENI  D
  1.  . ; engineering section loop
  1.  . S ENPMM=29000000
  1.  . F  S ENPMM=$O(^DIC(6922,ENI,1,"B",ENPMM)) Q:'ENPMM  D
  1.  . . ; invalid PM month loop
  1.  . . S ENII=$O(^DIC(6922,ENI,1,"B",ENPMM,0))
  1.  . . Q:'ENII
  1.  . . W "."
  1.  . . K PMTOT
  1.  . . S ENIII=0
  1.  . . F  S ENIII=$O(^DIC(6922,ENI,1,ENII,1,ENIII)) Q:'ENIII  D
  1.  . . . ; technician loop
  1.  . . . S ENY0=$G(^DIC(6922,ENI,1,ENII,1,ENIII,0))
  1.  . . . S ENTECH=$P(ENY0,U),ENHRS=$P(ENY0,U,2)
  1.  . . . I ENTECH]"",ENHRS]"" S PMTOT(ENTECH)=ENHRS
  1.  . . ; post accumulated hours
  1.  . . S ENSHKEY=ENI
  1.  . . S ENPMDT=$E(ENPMM,2,5)
  1.  . . I $D(PMTOT) D COUNT^ENBCPM8
  1.  . . ; kill invalid PM month
  1.  . . S DA(1)=ENI,DA=ENII,DIK="^DIC(6922,"_DA(1)_",1,"
  1.  . . D ^DIK
  1.  . ;clean up internal count of technicians
  1.  . ;source of problem was COUNT+8^ENBCPM8 (repaired with this patch)
  1.  . S ENPMM=0
  1.  . L +^DIC(6922,ENI)
  1.  . F  S ENPMM=$O(^DIC(6922,ENI,1,"B",ENPMM)) Q:'ENPMM  D
  1.  . . S ENII=$O(^DIC(6922,ENI,1,"B",ENPMM,0)) Q:'ENII  D
  1.  . . . S (ENIII,ENLAST,ENCOUNT)=0
  1.  . . . F  S ENIII=$O(^DIC(6922,ENI,1,ENII,1,ENIII)) Q:'ENIII  S ENLAST=ENIII,ENCOUNT=ENCOUNT+1
  1.  . . . S:ENLAST $P(^DIC(6922,ENI,1,ENII,1,0),"^",3)=ENLAST,$P(^(0),"^",4)=ENCOUNT
  1.  . L -^DIC(6922,ENI)
  1.  K DA,DIK,ENHRS,ENI,ENII,ENIII,ENPMDT,ENPMM,ENSHKEY,ENTECH,ENY0,PMTOT
  1.  K ENLAST,ENCOUNT
  1.  ;
  1. UBC W !!,"Modifying Data in File #7336.9 (OFM BUDGET CATEGORY)"
  1.  S DIC=1,DIC(0)="X",X="7336.9" D ^DIC
  1.  I Y<0 W "ERROR - File 7336.9 Not Found",! G UBCEND
  1.  ; additional MM Budget Categories
  1.  S (DIC,DIE)="^OFM(7336.9,",DR="1///^S X=ENX1"
  1.  S DIC(0)="X",X="EDUCATION" D ^DIC,ERR:Y'>0
  1.  I Y>0 S ENX1="MA,MI,MM",DA=+Y D ^DIE
  1.  S DIC(0)="X",X="NHCU" D ^DIC,ERR:Y'>0
  1.  I Y>0 S ENX1="MA,MI,MM,NR",DA=+Y D ^DIE
  1.  S DIC(0)="X",X="RESEARCH" D ^DIC,ERR:Y'>0
  1.  I Y>0 S ENX1="MA,MI,MM",DA=+Y D ^DIE
  1. UBCEND K DA,DIC,DIE,DR,ENDA,ENX1,X,Y
  1. UPC W !!,"Modifying Data in File #7336.8 (OFM PROJ CATEGORY)"
  1.  S DIC=1,DIC(0)="X",X="7336.8" D ^DIC
  1.  I Y<0 W "ERROR - File 7336.8 Not Found",! G UPCEND
  1.  ; Update mapping to MM budget categories
  1.  S (DIC,DIE)="^OFM(7336.8,",DR="10///^S X=ENX10"
  1.  S DIC(0)="X",X="EDUCATION" D ^DIC,ERR:Y'>0
  1.  I Y>0 S ENX10="EDUCATION",DA=+Y D ^DIE
  1.  S DIC(0)="X",X="NHCU" D ^DIC,ERR:Y'>0
  1.  I Y>0 S ENX10="NHCU",DA=+Y D ^DIE
  1.  S DIC(0)="X",X="RESEARCH" D ^DIC,ERR:Y'>0
  1.  I Y>0 S ENX10="RESEARCH",DA=+Y D ^DIE
  1. UPCEND K DA,DIC,DIE,DR,ENDA,ENX10,X,Y
  1. INDX W !!,"Re-Indexing ENG SPACE (#6928) file"
  1.  K DIK S DIK="^ENG(""SP""," D IXALL^DIK
  1.  K DIK
  1.  Q
  1. ERR W !,"ERROR - ",X," not found in file",! Q