Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: IB20P242

IB20P242.m

Go to the documentation of this file.
  1. IB20P242 ;WOIFO/SS-FY04 OPC COPAY IB*2.0*242 POST INIT ;10-SEP-03
  1. ;;2.0;INTEGRATED BILLING;**242**;21-MAR-94
  1. ;;Per VHA Directive 10-93-142, this routine should not be modified.
  1. ;
  1. POST ;
  1. I $$PATCH^XPDUTL("IB*2.0*242") D BMES^XPDUTL(" Skipping since the patch was previously installed.") Q
  1. N X,Y,IBEFFDT
  1. S IBEFFDT=3031001 ;effective date OCT 1, 2003
  1. D START,FADD(IBEFFDT),FDESCR(IBEFFDT),FINISH
  1. ;
  1. ; FADD - add additional codes to file 352.5
  1. ; FDESCR - add description updates for codes to file 352.5
  1. Q
  1. ;
  1. START ;
  1. D MESS(" FY04 OPC COPAY, Post-Install Starting")
  1. Q
  1. ;
  1. FINISH ;
  1. D MESS(" FY04 OPC COPAY, Post-Install Complete")
  1. Q
  1. ;
  1. ;add new entries in file 352.5
  1. FADD(IBEFFDT) ;
  1. N IBC,IBT,IBX,IBCODE,IBTYPE,IBOVER
  1. D MESS(" Adding new codes to file 352.5")
  1. S IBC=0
  1. F IBX=1:1 S IBT=$P($T(ADDREG+IBX),";",3) Q:'$L(IBT) D
  1. . S IBCODE=+$P(IBT,"^",1)
  1. . S IBTYPE=$P(IBT,"^",3)
  1. . S IBOVER=+$P(IBT,"^",4)
  1. . S Y=+$$ADD3525(IBCODE,IBEFFDT,IBTYPE,$E($P(IBT,"^",2),1,30),IBOVER) S:Y>0 IBC=IBC+1
  1. D MESS(" "_IBC_" entries added to 352.5")
  1. Q
  1. ;
  1. ;update description (add a new entry with new description if old one exists)
  1. FDESCR(IBEFFDT) ;
  1. N IBC,IBT,IBX,IBCODE,IBTYPE,IBOVER
  1. N IBLSTDT,IB1
  1. D MESS(" Updating descriptions in file 352.5")
  1. S IBC=0
  1. F IBX=1:1 S IBT=$P($T(DESCR+IBX),";",3) Q:'$L(IBT) D
  1. . S IBCODE=+$P(IBT,"^",1)
  1. . S IBLSTDT=$O(^IBE(352.5,"AEFFDT",IBCODE,-9999999))
  1. . I +IBLSTDT=0 D Q
  1. . . D BMES^XPDUTL(" Code "_IBCODE_" not found for description update.")
  1. . S IB1=$O(^IBE(352.5,"AEFFDT",IBCODE,IBLSTDT,0))
  1. . I +IB1=0 D Q
  1. . . D BMES^XPDUTL(" Code "_IBCODE_" not found for description update.")
  1. . S IBTYPE=+$P($G(^IBE(352.5,IB1,0)),"^",3)
  1. . S IBOVER=+$P($G(^IBE(352.5,IB1,0)),"^",5)
  1. . S Y=+$$ADD3525(IBCODE,IBEFFDT,IBTYPE,$E($P(IBT,"^",2),1,30),IBOVER) S:Y>0 IBC=IBC+1
  1. D MESS(" "_IBC_" updates added to 352.5")
  1. Q
  1. ;
  1. ;add a new entry
  1. ADD3525(IBCODE,IBEFFDT,IBTYPE,IBDECR,IBOVER) ;
  1. D BMES^XPDUTL(" "_IBCODE_" "_IBDECR)
  1. N IBIENS,IBFDA,IBER,IBRET,IBSEEKDT,IBLSTDT,IBOFL,IB1
  1. S IBIENS="+1,"
  1. S IBFDA(352.5,IBIENS,.01)=IBCODE
  1. S IBFDA(352.5,IBIENS,.02)=IBEFFDT
  1. S IBFDA(352.5,IBIENS,.03)=IBTYPE
  1. S IBFDA(352.5,IBIENS,.04)=IBDECR
  1. I IBOVER=1 S IBFDA(352.5,IBIENS,.05)=1
  1. D UPDATE^DIE("","IBFDA","IBRET","IBER")
  1. I $D(IBER) D BMES^XPDUTL(IBER("DIERR",1,"TEXT",1))
  1. Q $G(IBRET(1))
  1. ;
  1. ;output the message
  1. MESS(IBSTR) ;
  1. N IBA
  1. S IBA(2)=IBSTR
  1. S (IBA(1),IBA(3))=""
  1. D MES^XPDUTL(.IBA)
  1. Q
  1. ;
  1. ;data section
  1. ADDREG ;; non-override (regular) codes
  1. ;;221^PHONE/VISUAL IMPAIRMENT (VIST)^0^0
  1. ;;348^PRIMARY CARE GROUP^1^0
  1. ;;371^CCS EVALUATION^0^0
  1. ;;394^MED SPECIALTY GROUP^2^0
  1. ;;674^ADMIN PT ORIENT NON-CNT MAS^0^0
  1. ;;685^CARE OF CCS PROGRAM PATIENTS^0^1
  1. ;;686^CCS TELEPHONE (ETC.) CARE^0^0
  1. ;;690^TELEMEDICINE 2ND ONLY^0^1
  1. ;;717^PPD CLINIC (2ND ONLY)^0^1
  1. ;;179^REAL-TIME VIDEO CARE 2ND ONLY^0^1
  1. ;;684^HM THLTH NOVIDEO INTRVN 2 ONLY^0^1
  1. ;;
  1. ;
  1. DESCR ;; description updates
  1. ;;317^ANTI-COAGULATION CLINIC^
  1. ;;512^MENTAL HEALTH CONSULTATION^
  1. ;;527^MENTAL HEALTH PHONE PRI ONLY^
  1. ;;
  1. ;