Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: IBJDF8

IBJDF8.m

Go to the documentation of this file. 
  1. IBJDF8 ;ALB/RRG - AR PRODUCTIVITY REPORT ;29-AUG-00
  1.  ;;2.0;INTEGRATED BILLING;**123,159,192**;21-MAR-94
  1.  ;
  1. EN ; - Option entry point.
  1.  S (IBPNI,IBTDATE,IBFDATE,IBT,IBF,IBSPT,IBRPT,IBSEL,IBCLERK)=""
  1.  ;
  1. TDATE ; - Determine date range of transactions.
  1.  ; 
  1.  S DIR(0)="DA^:DT:EX"
  1.  S DIR("A")="FROM Transaction Date: "
  1.  S DIR("T")=300,DIR("L")=""
  1.  S (DIR("?"),DIR("??"))="^S IBOFF=1 D HELP^IBJDF8H"
  1.  W ! D ^DIR K DIR G:Y=""!(X="^") ENQ
  1.  S IBFDATE=Y,IBF=Y(0)
  1.  ;
  1.  S DIR(0)="DA^"_IBFDATE_":DT:EX"
  1.  S DIR("A")="  TO Transaction Date: "
  1.  S DIR("T")=300,DIR("L")=""
  1.  S (DIR("?"),DIR("??"))="^S IBOFF=11 D HELP^IBJDF8H"
  1.  W ! D ^DIR K DIR G:Y=""!(X="^") ENQ
  1.  S IBTDATE=Y,IBT=Y(0)
  1.  ;
  1. CLERK ; - Get All/Specific Clerks
  1.  D ALSP^IBJD("Clerks^Clerk","^IBE(351.73,",.IBCLERK)
  1.  I IBCLERK["^" G ENQ
  1.  ;
  1. TYPE ; - Determine type of report -Detail or Summary.
  1.  ;
  1.  D DS^IBJD G ENQ:IBRPT["^",SUMM:IBRPT="S"
  1.  ;
  1. DETOPT ; - Detail print options.
  1.  ;
  1.  ; - Determine if Clerk name or Clerk identifier should print
  1.  W ! S IBPNI=""
  1.  S DIR(0)="SA^N:NAME;I:IDENTIFIER;",DIR("T")=DTIME
  1.  S DIR("A")="Do you wish to print with Clerk (N)ame or (I)dentifier? "
  1.  S DIR("?")="^S IBOFF=21 D HELP^IBJDF8H"
  1.  D ^DIR K DIR G:$D(DIRUT)!$D(DTOUT)!$D(DUOUT)!$D(DIROUT) ENQ
  1.  S IBPNI=Y K DIROUT,DTOUT,DUOUT,DIRUT
  1.  ;
  1.  K IBOPT F X=1:1:14 S IBOPT(X)=$$CAT(X)
  1.  S IBPRT="Choose transaction type(s) to print: "
  1.  S IBSEL=$$MLTP^IBJD(IBPRT,.IBOPT,1) I 'IBSEL G ENQ
  1.  S IBSEL=","_IBSEL
  1.  ;
  1.  ; - Assign Tran types from 430.3 to user-selected transaction types
  1.  S IBTT="" D
  1.  . I IBSEL=",1,2,3,4,5,6,7,8,9,10,11,12,13," S IBTT="ALL" Q
  1.  . F I=2:1 S II=$P(IBSEL,",",I) Q:'II  D
  1.  . . S IBTT=$S(IBTT'="":IBTT_$$CATT(II)_"|",1:"|"_$$CATT(II)_"|")
  1.  ;
  1. SUMM ; - Summary print options
  1.  ;
  1.  W ! S DIR(0)="Y",DIR("B")="YES",DIR("T")=DTIME
  1.  S DIR("A")="Do you want to print the summary by Clerk"
  1.  S DIR("?")="^S IBOFF=27 D HELP^IBJDF8H"
  1.  D ^DIR K DIR G:$D(DIRUT)!$D(DTOUT)!$D(DUOUT)!$D(DIROUT) ENQ
  1.  S IBSPT=+Y K DIROUT,DTOUT,DUOUT,DIRUT
  1.  I IBSPT=1 D
  1.  . Q:IBPNI'=""
  1.  . S DIR(0)="SA^N:NAME;I:IDENTIFIER;",DIR("T")=DTIME
  1.  . S DIR("A")="Do you wish to print with Clerk (N)ame or (I)dentifier? "
  1.  . S DIR("?")="^S IBOFF=21 D HELP^IBJDF8H"
  1.  . D ^DIR K DIR G:$D(DIRUT)!$D(DTOUT)!$D(DUOUT)!$D(DIROUT) ENQ
  1.  . S IBPNI=Y K DIROUT,DTOUT,DUOUT,DIRUT
  1.  ;
  1.  ;
  1. DEV ; - Select a device.
  1.  W !!,"This report requires a ",$S(IBRPT="S":80,1:132)," column printer."
  1.  S %ZIS="QM" D ^%ZIS G:POP ENQ
  1.  I $D(IO("Q")) D  G ENQ
  1.  .S ZTRTN="DQ^IBJDF8",ZTDESC="IB - AR PRODUCTIVITY REPORT"
  1.  .S ZTSAVE("IB*")="" D ^%ZTLOAD
  1.  .I $G(ZTSK) W !!,"This job has been queued. The task no. is ",ZTSK,"."
  1.  .E  W !!,"Unable to queue this job."
  1.  .K ZTSK,IO("Q") D HOME^%ZIS
  1.  ;
  1.  U IO
  1.  ;
  1. DQ D ST^IBJDF81 ;                   Compile and print the report.
  1.  ;
  1. ENQ K DIROUT,DTOUT,DUOUT,DIRUT,I
  1.  K IBOFF,IBSNA,IBPLN,IBRPT,POP,X,ZTDESC,ZTRTN,ZTSAVE,Y,%ZIS,IBSPT,IBPNI
  1.  K IBSEL,IBTT,II,IBF,IBT,IBFDATE,IBTDATE,IBCLERK,IBPRT,IBOPT
  1.  Q
  1.  ;
  1. CAT(X) ; - Return transaction type
  1.  Q $S(X]"":$P($T(CAT1+X),";;",2),1:"")
  1.  ;
  1. CATT(X) ; - Return transaction type from 430.3 for user-selected transaction type
  1.  Q $S(X]"":$P($T(CAT1+X),";;",3),1:"")
  1.  ;
  1. CAT1 ; - Transaction types
  1.  ;;COMMENT;;45
  1.  ;;AUDIT;;0
  1.  ;;PAYMENT;;2|34
  1.  ;;REFUND;;41
  1.  ;;DEC.ADJ./CONTR;;35
  1.  ;;DEC.ADJ./NON-CONTR;;35
  1.  ;;WRITE-OFF;;23|8
  1.  ;;WAIVED;;10|11
  1.  ;;SUSPENDED;;40
  1.  ;;COMPROMISED;;9|29
  1.  ;;REPAYMENT PLAN;;25
  1.  ;;EXEMPTION;;14
  1.  ;;OTHER;;1|3|4|5|6|7|12|13|15|16|17|18|19|20|21|22|24|26|27|28|30|31|32|33|36|37|38|39|42|43|44|46|47|48|49
  1.  ;;ALL OF THE ABOVE;;0
  1.  ;