Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: IBJPM

IBJPM.m

Go to the documentation of this file. 
  1. IBJPM ;ALB/MAF,ARH - IBSP MCCR PARAMETERS SCREEN ;14-DEC-1995
  1.  ;;2.0;INTEGRATED BILLING;**39,137,184,271,316,416,438,517,659,687**;21-MAR-94;Build 88
  1.  ;;Per VA Directive 6402, this routine should not be modified.
  1.  ;
  1. EN ; -- main entry point for JOINT INQUIRY PARAMETERS option
  1.  D EN^VALM("IBJP MCCR PARAMETERS")
  1.  Q
  1.  ;
  1. HDR ; -- header code
  1.  S VALMHDR(1)="Display/Edit MCCR Site Parameters."
  1.  S VALMHDR(2)="Only authorized persons may edit this data."
  1.  Q
  1.  ;
  1. INIT ; -- init variables and list array
  1.  K ^TMP("IBJPM",$J)
  1.  D BLD
  1.  Q
  1.  ;
  1. HELP ; -- help code
  1.  S X="?" D DISP^XQORM1 W !!
  1.  Q
  1.  ;
  1. EXIT ; -- exit code
  1.  K ^TMP("IBJPM",$J),IBFASTXT,VALMBCK
  1.  D CLEAR^VALM1
  1.  Q
  1.  ;
  1. BLD ; -- build screen array, no variables required for input
  1.  N IBNC,IBTC,IBTW,IBSW,IBLN,IBGRPB,IBGRPE,IBLR
  1.  S IBNC(1)=1,IBTW(1)=0,IBTC(1)=5,IBSW(1)=30,IBNC(2)=43,IBTW(2)=0,IBTC(2)=47,IBSW(2)=30
  1.  ;
  1.  S (VALMCNT,IBLN)=1,IBLR=1,IBLN=$$SET("","",IBLN,IBLR),IBGRPB=IBLN
  1.  ;
  1.  ; - IB Site Parameters
  1.  S IBLN=$$SETN("IB Site Parameters",IBLN,IBLR,1)
  1.  S IBLN=$$SET("","Facility Definition",IBLN,IBLR)
  1.  S IBLN=$$SET("","Mail Groups",IBLN,IBLR)
  1.  S IBLN=$$SET("","Patient Billing",IBLN,IBLR)
  1.  S IBLN=$$SET("","Third Party Billing",IBLN,IBLR)
  1.  S IBLN=$$SET("","Provider Id",IBLN,IBLR)
  1.  S IBLN=$$SET("","EDI Transmission",IBLN,IBLR)
  1.  ;
  1.  S IBLR=2,IBGRPE=IBLN,IBLN=IBGRPB
  1.  ;
  1.  ; - Claim Tracking Parameters
  1.  S IBLN=$$SETN("Claims Tracking Parameters",IBLN,IBLR,1)
  1.  S IBLN=$$SET("","General Parameters",IBLN,IBLR)
  1.  S IBLN=$$SET("","Tracking Parameters",IBLN,IBLR)
  1.  S IBLN=$$SET("","Random Sampling",IBLN,IBLR)
  1.  S IBLN=$$SET("","HCSR Parameters",IBLN,IBLR)
  1.  ;
  1.  S IBLN=$S(IBLN>IBGRPE:IBLN,1:IBGRPE),IBLR=1,IBLN=$$SET("","",IBLN,IBLR),IBGRPB=IBLN
  1.  ;
  1.  ; - Automated Billing Parameters
  1.  S IBLN=$$SETN("Third Party Auto Billing Parameters",IBLN,IBLR,1)
  1.  S IBLN=$$SET("","General Parameters",IBLN,IBLR)
  1.  S IBLN=$$SET("","Inpatient Admission",IBLN,IBLR)
  1.  S IBLN=$$SET("","Outpatient Visit",IBLN,IBLR)
  1.  S IBLN=$$SET("","Prescription Refill",IBLN,IBLR)
  1.  ;
  1.  ; DAOU/BHS - Added 13-JUN-2002
  1.  S IBLR=2,IBLN=IBGRPB
  1.  ;
  1.  ; DAOU/BHS - Added 13-JUN-2002
  1.  ; - eIV Parameters
  1.  S IBLN=$$SETN("Insurance Verification",IBLN,IBLR,1)
  1.  S IBLN=$$SET("","General Parameters",IBLN,IBLR)
  1.  ;S IBLN=$$SET("","Batch Extracts Parameters",IBLN,IBLR) ;/vd-IB*2*687 - Removed this parameter
  1.  ;/vd-IB*2*687 - Added the following 3 parameter selections
  1.  S IBLN=$$SET("","eIV Parameters",IBLN,IBLR)
  1.  S IBLN=$$SET("","eIV Batch Extracts",IBLN,IBLR)
  1.  S IBLN=$$SET("","IIU Parameters",IBLN,IBLR)
  1.  ;/vd-IB*2*687 - End of 3 parameters selections added. 
  1.  ;/vd-IB*2*659 - Removed the following heading for maintenance purposes per
  1.  ;               a request by the ebiz group.
  1.  ;S IBLN=$$SET("","Service Type Codes",IBLN,IBLR)
  1.  ;
  1.  S (IBLN,VALMCNT)=$S(IBLN>IBGRPE:IBLN,1:IBGRPE)-1
  1.  Q
  1.  ;
  1. SET(TTL,DATA,LN,LR) ;
  1.  N IBY
  1.  S IBY=$J(TTL,IBTW(LR))_DATA D SET1(IBY,LN,IBTC(LR),(IBTW(LR)+IBSW(LR)))
  1.  S LN=LN+1
  1.  Q LN
  1.  ;
  1. SETN(TTL,LN,LR,RV) ;
  1.  N IBY
  1.  S IBY=" "_TTL_" " D SET1(IBY,LN,IBNC(LR),$L(IBY),$G(RV))
  1.  S LN=LN+1
  1.  Q LN
  1.  ;
  1. SET1(STR,LN,COL,WD,RV) ; set up TMP array with screen data
  1.  N IBX S IBX=$G(^TMP("IBJPM",$J,LN,0))
  1.  S IBX=$$SETSTR^VALM1(STR,IBX,COL,WD)
  1.  D SET^VALM10(LN,IBX) I $G(RV)'="" D CNTRL^VALM10(LN,COL,WD,IOINHI,IOINORM)
  1.  Q