Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: LA7VOBX4

LA7VOBX4.m

Go to the documentation of this file. 
  1. LA7VOBX4 ;DALOI/JMC - LAB OBX Segment message builder (MI subscripts) cont'd ;11/18/11  14:48
  1.  ;;5.2;AUTOMATED LAB INSTRUMENTS;**74**;Sep 27, 1994;Build 229
  1.  ;
  1.  ; Continuation of LA7VOBX3
  1.  ;
  1.  Q
  1.  ;
  1.  ;
  1. GEN ; Fields common to all MI OBX segments.
  1.  ;
  1.  ;
  1.  ; Initialize OBX segment
  1.  S LA7OBX(0)="OBX"
  1.  S LA7OBX(1)=$$OBX1^LA7VOBX(.LA7OBXSN)
  1.  ;
  1.  S LA7OBX(3)=$$OBX3^LA7VOBX($P(LA7CODE,"!",2),$P(LA7CODE,"!",3),LA7ALT,LA7FS,LA7ECH,$G(LA7INTYP))
  1.  ;
  1.  ; Test value
  1.  S LA7OBX(5)=$$OBX5^LA7VOBX(LA7VAL,LA7OBX(2),LA7FS,LA7ECH)
  1.  ;
  1.  ; Set sub-id and save for constructing parents
  1.  I LA7ISOID'="" D
  1.  . S LA7OBX(4)=$$OBX4^LA7VOBX(LA7ISOID,LA7FS,LA7ECH)
  1.  . I LA7SAVID D
  1.  . . F I=1,2 S LA7ISOID(LA7ISOID,I)=LA7OBX(I+2)
  1.  . . I $G(HL("VER"))="2.2" S LA7ISOID(LA7ISOID,3)=LA7OBX(5) Q
  1.  . . F I=2,4 I $P(LA7OBX(5),$E(LA7ECH,1),I)'="" S LA7ISOID(LA7ISOID,3)=$P(LA7OBX(5),$E(LA7ECH,1),I) Q
  1.  ;
  1.  ; Order result status - "P"artial, "F"inal , "A"mended results
  1.  ; If no status from individual components then use status from zeroth node.
  1.  ; If no release date then pending else final
  1.  ; If amended, overrides all other status
  1.  ;
  1.  S LA7OBX(11)=$$OBX11^LA7VOBX(LA7RS)
  1.  ;
  1.  ; Observation date/time - collection date/time per HL7 standard
  1.  I $P(LA76305(0),"^") S LA7OBX(14)=$$OBX14^LA7VOBX($P(LA76305(0),"^"))
  1.  ;
  1.  S LA7DIV=""
  1.  I LA7PLREF'="" S LA7DIV=$P($$RESPL^LA7VHLU2(LA7PLREF),"^")
  1.  I 'LA7DIV S LA7DIV=$P($G(^LR(LRDFN,"MI",LRIDT,"RF")),"^")
  1.  I 'LA7DIV,$$DIV4^XUSER(.LA7DIV,$P(LA76305(0),"^",4)) S LA7DIV=$O(LA7DIV(0))
  1.  ;
  1.  ; Facility that performed the testing
  1.  S LA7OBX(15)=$$OBX15^LA7VOBX(LA7DIV,LA7FS,LA7ECH)
  1.  ;
  1.  ; Person that verified the test
  1.  I $P(LA76305(0),"^",4) S LA7VERP=$P(LA76305(0),"^",4)
  1.  I LA7VERP S LA7OBX(16)=$$OBX16^LA7VOBX(LA7VERP,LA7DIV,LA7FS,LA7ECH)
  1.   ;
  1.  ; Performing organization name/address
  1.  I LA7DIV'="" D
  1.  . N LA7DT
  1.  . S LA7OBX(23)=$$OBX23^LA7VOBX(4,LA7DIV,LA7FS,LA7ECH)
  1.  . S LA7DT=$S($P(LA76305(0),"^",3):$P(LA76305(0),"^",3),1:$$NOW^XLFDT)
  1.  . S LA7OBX(24)=$$OBX24^LA7VOBX(4,LA7DIV,LA7DT,LA7FS,LA7ECH)
  1.  ;
  1.  D BUILDSEG^LA7VHLU(.LA7OBX,.LA7ARRAY,LA7FS)
  1.  ;
  1.  Q
  1.  ;
  1.  ;
  1. CC ; Organism's Colony count
  1.  ; If "CFU/ml" found then move units to OBX-6 (Units).
  1.  N LA7X
  1.  ;
  1.  S LA7IENS=LRIDT(2)_","_LRIDT_","_LRDFN_","
  1.  S LA7OBX(2)=$$OBX2^LA7VOBX(LA7SUBFL,1)
  1.  ;
  1.  ; Isolate ID as sub-id
  1.  S LA7ISOID=$$GETISO^LA7VHLU1(LA7SUBFL,LA7IENS)
  1.  ;
  1.  S LA7VAL=$$GET1^DIQ(LA7SUBFL,LA7IENS,1)
  1.  S LA7X=$$UP^XLFSTR(LA7VAL)
  1.  I LA7X["CFU/ML" D
  1.  . S LA7OBX(6)=$$OBX6^LA7VOBX("CFU/ml","",LA7FS,LA7ECH,$G(LA7INTYP))
  1.  . S LA7X("CFU/ml")="",LA7X("CFU/ML")=""
  1.  . S LA7VAL=$$REPLACE^XLFSTR(LA7VAL,.LA7X)
  1.  ;
  1.  S LA7Y="MI-"_$P(LRSB,",")_"-1^"_$$GET1^DID(LA7SUBFL,1,"","LABEL")_"^99VA63"
  1.  S LA7ALT=LA7Y_"^"_LA7Y
  1.  S LA7PLREF=LRDFN_",MI,"_LRIDT_",3,"_LRIDT(2)
  1.  ;
  1.  Q
  1.  ;
  1.  ;
  1. ORG ; Organism
  1.  ;
  1.  N LA7X,LA7Y
  1.  ;
  1.  S LA7OBX(2)=$$OBX2^LA7VOBX(LA7SUBFL,.01)
  1.  S LA7IENS=LRIDT(2)_","_LRIDT_","_LRDFN_","
  1.  S LA7VAL=""
  1.  ;
  1.  ; Isolate ID as sub-id
  1.  S LA7ISOID=$$GETISO^LA7VHLU1(LA7SUBFL,LA7IENS)
  1.  ;
  1.  I $G(LA7NVAF)=1 S LA7OBX(2)="CE"
  1.  S LA7X=$$GET1^DIQ(LA7SUBFL,LA7IENS,.01,"I"),LA7X(.01)=$$GET1^DIQ(LA7SUBFL,LA7IENS,.01)
  1.  ; Check for SNOMED coding/local coding as alternate
  1.  S LA7Y=$$IEN2SCT^LA7VHLU6(61.2,LA7X,DT)
  1.  I LA7Y D
  1.  . S LA7VAL=$P(LA7Y,"^",1,3),$P(LA7VAL,"^",4,6)=LA7X_"^"_LA7X(.01)_"^99VA61.2"
  1.  . I $G(LA7NVAF)'=1 S LA7OBX(2)="CWE",$P(LA7VAL,"^",7,8)=$P(LA7Y,"^",4)_"^5.2",$P(LA7VAL,"^",9)=LA7X(.01)
  1.  ; If no SNOMED then use local coding as primary
  1.  I LA7VAL="" D
  1.  . S LA7VAL=LA7X_"^"_LA7X(.01)_"^99VA61.2"
  1.  . I $G(LA7NVAF)'=1 S LA7OBX(2)="CWE",$P(LA7VAL,"^",7)="5.2",$P(LA7VAL,"^",9)=LA7X(.01)
  1.  ;
  1.  S LA7Y="MI-"_$P(LRSB,",")_"-.01^"_$$GET1^DID(LA7SUBFL,.01,"","LABEL")_"^99VA63"
  1.  S LA7ALT=LA7Y_"^"_LA7Y
  1.  ;
  1.  S LA7OBX(8)=$$OBX8^LA7VOBX("A")
  1.  ;
  1.  S LA7PLREF=LRDFN_",MI,"_LRIDT_","_$P(LRSB,",")_","_LRIDT(2)_",0"
  1.  ;
  1.  ; Set flag to save sub-id for parent-child relationship
  1.  S LA7SAVID=1
  1.  Q
  1.  ;
  1.  ;
  1. MIC ; Organism's susceptibilities
  1.  ;
  1.  N LA7IENS,LA7SCT,LA7SUB,LA7X,LA7Y
  1.  ;
  1.  ; Bact or TB organism
  1.  S LA7SUB=$S($P(LRSB,",")=12:3,1:12)
  1.  ;
  1.  S LA7OBX(2)=$$OBX2^LA7VOBX(62.06,.01)
  1.  ;
  1.  ; Determine local code for antibiotic if not mapped to NLT or in file #62.06
  1.  ;  - Use file #62.06 entry if available otherwise generate from drug node field in file #63
  1.  ;    also used to convey local display name in 9th component
  1.  S (LA7ALT,LA7X,LA7Y)=""
  1.  I $P(LRSB,",")=12 S LA7X=$O(^LAB(62.06,"AD",$P(LRSB,",",2),0))
  1.  I $P(LRSB,",")=26 S LA7X=$O(^LAB(62.06,"AD1",$P(LRSB,",",2),0))
  1.  I LA7X S LA7Y=LA7X_"^"_$$GET1^DIQ(62.06,LA7X_",",.01)_"^99VA62.06"
  1.  I LA7Y="" D
  1.  . S LA7X=$P(LRSB,",",2),LA7Y=$O(^DD(LA7SUBFL,"GL",LA7X,1,0))
  1.  . I LA7Y<1 Q
  1.  . S LA7Y="MIAB"_$P(LRSB,",")_"-"_$P(LRSB,",",2)_"^"_$$GET1^DID(LA7SUBFL,LA7Y,"","LABEL")_"^99VA63"
  1.  I $P(LA7CODE,"!",2)=""!($P(LA7CODE,"!",3)="") S LA7ALT=LA7Y
  1.  S $P(LA7ALT,"^",4,6)=LA7Y
  1.  ;
  1.  S LA7X=$G(^LR(LRDFN,"MI",LRIDT,LA7SUB,LRIDT(2),LRIDT(3)))
  1.  I $P(LA7X,"^",2)'="" S $P(LA7X,"^",2)=$$TRIM^XLFSTR($P(LA7X,"^",2),"RL"," ")
  1.  S LA7VAL=$$TRIM^XLFSTR($P(LA7X,"^"),"RL"," ")
  1.  I LA7VAL'="" D
  1.  . I "MSIR"[$E(LA7VAL),$G(LA7NVAF)'=1 D
  1.  . . S LA7Y=$S(LA7VAL="S":131196009,LA7VAL="MS":260357007,LA7VAL="R":30714006,LA7VAL="I":264841006,1:"")
  1.  . . I LA7Y D MTSCT
  1.  . I $E($P(LA7X,"^",2))?1(1"S",1"I",1"R") S LA7OBX(8)=$$OBX8^LA7VOBX($E($P(LA7X,"^",2))) Q
  1.  . I $E($P(LA7X,"^",2),1,2)?1(1"MS",1"VS") S LA7OBX(8)=$$OBX8^LA7VOBX($E($P(LA7X,"^",2),1,2))
  1.  ;
  1.  ; Determine access screen for this susceptibility
  1.  I $P(LA7X,"^",3)="" S $P(LA7X,"^",3)="A"
  1.  S LA7OBX(13)=$$OBX13^LA7VOBX($P(LA7X,"^",3),$S($G(LA7INTYP)=30:"MIS-HDR",1:"MIS"),LA7FS,LA7ECH)
  1.  ;
  1.  S LA7PLREF=LRDFN_",MI,"_LRIDT_","_LA7SUB_","_LRIDT(2)_","_LRIDT(3)
  1.  ;
  1.  Q
  1.  ;
  1.  ;
  1. MICA ; Bacteria organism's susceptibilities - free text
  1.  ;
  1.  N LA7SUB,LA7X
  1.  S LA7OBX(2)="NM"
  1.  ;
  1.  ; Bact organism
  1.  S LA7SUB=3
  1.  ;
  1.  ; Determine local code for free text antibiotic also used to convey local display name in 9th component
  1.  S LA7X=$G(^LR(LRDFN,"MI",LRIDT,LA7SUB,LRIDT(2),3,LRIDT(3),0))
  1.  S LA7ALT="MIAB"_$P(LRSB,",")_"-"_$P(LRSB,",",2)_"-"_$P(LRSB,",",3)_"^"_$P(LA7X,"^")_$S($P(LRSB,",",3)=1:" MIC",1:" MBC")_"^99VA63"
  1.  S LA7ALT=LA7ALT_"^"_LA7ALT
  1.  S $P(LA7CODE,"!",2)="87565.0000"
  1.  S $P(LA7CODE,"!",3)=$S($P(LRSB,",",3)=1:21070,1:23658)
  1.  ;
  1.  S LA7VAL=$P(LA7X,"^",$S($P(LRSB,",",3)=1:2,1:3))
  1.  ;
  1.  S LA7OBX(6)="UG/ML"
  1.  S LA7OBX(8)=""
  1.  ;
  1.  Q
  1.  ;
  1.  ;
  1. PSTAGE ; Parasite's stage
  1.  ;
  1.  N LA7IENS,LA7SUB,LA7X,LA7Y
  1.  ;
  1.  S LA7SUB=6,LA7VAL=""
  1.  S LA7OBX(2)=$$OBX2^LA7VOBX(63.35,.01)
  1.  ;
  1.  ; Isolate ID as sub-id
  1.  S LA7ISOID=$$GETISO^LA7VHLU1(63.34,LRIDT(2)_","_LRIDT_","_LRDFN_",")
  1.  ;
  1.  S LA7IENS=LRIDT(3)_","_LRIDT(2)_","_LRIDT_","_LRDFN_","
  1.  S LA7VAL=$$GET1^DIQ(LA7SUBFL,LA7IENS,.01,"E")
  1.  S LA7X=$P($G(^LR(LRDFN,"MI",LRIDT,LA7SUB,LRIDT(2),1,LRIDT(3),0)),"^")
  1.  S LA7Y=$S(LA7X="T":103551003,LA7X="C":103552005,LA7X="E":116990009,LA7X="L":48458007,LA7X="S":284701003,LA7X="G":103537003,LA7X="M":2105009,LA7X="R":103568004,LA7X="F":2105009,1:"")
  1.  I LA7Y S LA7X=LA7VAL D MTSCT
  1.  ;
  1.  S LA7Y="MI-"_$P(LRSB,",")_"-.01^"_$$GET1^DID(63.35,.01,"","LABEL")_"^99VA63"
  1.  S LA7ALT=LA7Y_"^"_LA7Y
  1.  ;
  1.  I LA7VAL'="" S LA7OBX(8)=$$OBX8^LA7VOBX("A")
  1.  ;
  1.  S LA7PLREF=LRDFN_",MI,"_LRIDT_",6,"_LRIDT(2)_",1,"_LRIDT(3)
  1.  ;
  1.  Q
  1.  ;
  1.  ;
  1. PQTY ; Parasite's stage quantity
  1.  ;
  1.  N LA7IENS,LA7SUB
  1.  ;
  1.  S LA7SUB=6,LA7VAL=""
  1.  S LA7OBX(2)=$$OBX2^LA7VOBX(63.35,1)
  1.  ;
  1.  ; Isolate ID as sub-id
  1.  S LA7ISOID=$$GETISO^LA7VHLU1(63.34,LRIDT(2)_","_LRIDT_","_LRDFN_",")
  1.  ;
  1.  S LA7X=$G(^LR(LRDFN,"MI",LRIDT,LA7SUB,LRIDT(2),1,LRIDT(3),0))
  1.  S LA7VAL=$P(LA7X,"^",2)
  1.  ;
  1.  S LA7Y="MI-"_$P(LRSB,",")_"-1^"_$$GET1^DID(63.35,1,"","LABEL")_"^99VA63"
  1.  S LA7ALT=LA7Y_"^"_LA7Y
  1.  ;
  1.  I LA7VAL'="" S LA7OBX(8)=$$OBX8^LA7VOBX("A")
  1.  ;
  1.  S LA7PLREF=LRDFN_",MI,"_LRIDT_",6,"_LRIDT(2)_",1,"_LRIDT(3)
  1.  ;
  1.  Q
  1.  ;
  1.  ;
  1. MTSCT ; Map specific values to SNOMED CT
  1.  ; Required variables
  1.  ;     LA7X = local reportable result - Will be inserted in 9th component as local term
  1.  ;     LA7Y = SCT code to lookup
  1.  ;   LA7VAL = encoded SCT term with local term
  1.  ;
  1.  N LA7SCT
  1.  I $$CODE^LEXTRAN(LA7Y,"SCT",DT,"LA7SCT")>0 D
  1.  . S LA7VAL=$P(LA7SCT(0),"^")_"^"_LA7SCT("P")_"^SCT"
  1.  . I $G(LA7NVAF)'=1 S LA7OBX(2)="CWE",$P(LA7VAL,"^",7)=$P(LA7SCT(0),"^",3),$P(LA7VAL,"^",9)=$P(LA7X,"^")
  1.  . E  S LA7OBX(2)="CE"
  1.  Q