Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: LEX2104

LEX2104.m

Go to the documentation of this file.
  1. LEX2104 ;ISL/KER - LEX*2.0*104 Env Check ;11/24/2015
  1. ;;2.0;LEXICON UTILITY;**104**;Sep 23, 1996;Build 1
  1. ;
  1. ; Global Variables
  1. ; ^LEXM N/A
  1. ;
  1. ; External References
  1. ; FIND^DIC ICR 2051
  1. ; $$IENS^DILF ICR 2054
  1. ; EN^DIQ1 ICR 10015
  1. ; $$FMTE^XLFDT ICR 10103
  1. ; $$PATCH^XPDUTL ICR 10141
  1. ; $$PKG^XPDUTL ICR 10141
  1. ; $$VER^XPDUTL ICR 10141
  1. ; $$VERSION^XPDUTL ICR 10141
  1. ; BMES^XPDUTL ICR 10141
  1. ; MES^XPDUTL ICR 10141
  1. ;
  1. ; Local Variables NEWed or KILLed by Kernel Installation
  1. ; and Distribution System (KIDS):
  1. ;
  1. ; XPDABORT,XPDDIQ,XPDQUIT
  1. ;
  1. ; see Kernel Developer Guide, Chapter 14,
  1. ; KIDS Developer Tools, Advanced Build Techniques
  1. ;
  1. ; The following sections must be updated with each quarterly
  1. ; patch
  1. ;
  1. ; IMP^LEX20nn Import names
  1. ;
  1. ; This section sets the following variables:
  1. ;
  1. ; LEXBUILD Build Name LEX*2.0*nn
  1. ; LEXPTYPE Patch Type Remedy or Quarterly
  1. ; LEXIGHF Name of Host File LEX_2_nn.GBL
  1. ; LEXLREV Revision Number nn
  1. ; LEXFY Fiscal Year FYnn
  1. ; LEXQTR Quarter 1st, 2nd, 3rd, or 4th
  1. ; LEXREQP(n) Required Patch Array
  1. ;
  1. ; GD^LEX20nn Global Data
  1. ;
  1. ; This is a listing of globals that this patch writes
  1. ; to, it contains a closed global root, a global ID,
  1. ; a global name and file numbers.
  1. ;
  1. ; IPL^LEX20nnP Informational Patch List
  1. ;
  1. ; This is a listing of informational patches that
  1. ; accompany this patch. It consist of a patch nane
  1. ; and a sequence number when available. It is used
  1. ; to update the package file at the site with the
  1. ; informational patches.
  1. ;
  1. ENV ; Environment Check
  1. ;
  1. ; General
  1. ;
  1. N LEXPTYPE,LEXLREV,LEXREQP,LEXBUILD,LEXIGHF,LEXFY,LEXQTR,LEXG,LEXB,LEXE,LEXR,LEXSTR,LEXOK D IMP
  1. K XPDDIQ("XPZ1","B"),XPDDIQ("XPI1","B") S XPDDIQ("XPZ1","B")="NO",XPDDIQ("XPI1","B")="NO"
  1. S LEXSTR=$G(LEXPTYPE) S:$L($G(LEXFY))&($L($G(LEXQTR))) LEXSTR=LEXSTR_" for "_$G(LEXFY)_" "_$G(LEXQTR)_" Quarter"
  1. D BM(LEXSTR),M("")
  1. S U="^"
  1. ; No user
  1. D:+($$UR)'>0 ET("User not defined (DUZ)")
  1. ; No IO
  1. D:+($$SY)'>0 ET("Undefined IO variable(s)")
  1. I $D(LEXE) D ABRT Q
  1. ;
  1. ; Load Distribution
  1. ;
  1. ; XPDENV = 0 Environment Check during Load
  1. ;
  1. ; Check Version (2.0)
  1. I $$VERSION^XPDUTL("LEX")'="2.0" D D ABRT Q
  1. . D ET("Version 2.0 not found. Please install Lexicon Utility v 2.0")
  1. N LEXOK,LEXG,LEXR,LEXB
  1. ; Check Required Patches
  1. D:$O(LEXREQP(0))'>0 IMP I $O(LEXREQP(0))>0 D
  1. . W ! N LEXPAT,LEXI,LEXPN,LEXP,LEXR,LEXC,LEXO,LEXC1,LEXC2,LEXC3,LEXC4,LEX
  1. . S (LEXR,LEXC)=0 S LEXC1=3,LEXC2=24,LEXC3=37,LEXC4=50
  1. . S LEXI=0 F S LEXI=$O(LEXREQP(LEXI)) Q:+LEXI'>0 D
  1. . . S LEXC=LEXC+1,LEXPAT=$G(LEXREQP(LEXI))
  1. . S LEXI=0 F S LEXI=$O(LEXREQP(LEXI)) Q:+LEXI'>0 D
  1. . . N LEXPAT,LEXREL,LEXINS,LEXCOM,LEXINE,LEXREQ,LEXTX S LEXREQ=$G(LEXREQP(LEXI))
  1. . . S LEXPAT=$P(LEXREQ,"^",1),LEXREL=$P(LEXREQ,"^",2),LEXCOM=$P(LEXREQ,"^",3)
  1. . . S LEXPN=$$INS(LEXPAT) S LEXINS=$$INSD(LEXPAT),LEXINE=$P(LEXINS,"^",2)
  1. . . I LEXI=1 D
  1. . . . W !,?LEXC1,"Checking for ",!
  1. . . . W !,?LEXC1,"Patch",?LEXC2,"Released",?LEXC3,"Installed",?LEXC4,"Content"
  1. . . S LEXTX=$J(" ",LEXC1)_LEXPAT
  1. . . S LEXTX=LEXTX_$J(" ",(LEXC2-$L(LEXTX)))
  1. . . S:LEXREL?7N LEXTX=LEXTX_$P($$FMTE^XLFDT(LEXREL,"5DZ"),"@",1)
  1. . . S LEXTX=LEXTX_$J(" ",(LEXC3-$L(LEXTX)))
  1. . . I +LEXPN>0 D
  1. . . . S LEXO=+($G(LEXO))+1 S:$L($G(LEXINE)) LEXTX=LEXTX_LEXINE
  1. . . . S LEXTX=LEXTX_$J(" ",(LEXC4-$L(LEXTX)))
  1. . . . S:$L(LEXCOM) LEXTX=LEXTX_LEXCOM
  1. . . D M(LEXTX)
  1. . . I +LEXPN'>0 D
  1. . . . N LEXP S LEXP=$G(LEXPAT) S:LEXP[" SEQ"&($L($P(LEXP," SEQ",1))) LEXP=$P(LEXP," SEQ",1)
  1. . . . D ET((LEXP_" not found, please install "_LEXP_" before continuing"))
  1. . W:+($G(LEXO))'=LEXC !
  1. I $D(LEXE) D M(),ABRT Q
  1. S LEXG=$$RGBL
  1. I $D(LEXE)&(+LEXG=0) D ABRT Q
  1. I $D(LEXE)&(+LEXG<0) D ABRT Q
  1. I '$D(LEXFULL)&(+($G(XPDENV))'=1) D QUIT Q
  1. ;
  1. ; Install Package(s)
  1. ;
  1. ; XPDENV = 1 Environment Check during Install
  1. ;
  1. ; Check Data "is installed" or "is translated"
  1. N LEXIT S LEXIT=+($$CPD) I '$D(LEXFULL)&(LEXIT) D QUIT Q
  1. ; Checking Global "Write" Protection
  1. D:+($G(XPDENV))=1 GBLS I $D(LEXE) D ABRT Q
  1. ; Check Import Global Checksum
  1. D:+($G(XPDENV))=1 CS I $D(LEXE) D ABRT Q
  1. ;
  1. ; Quit, Exit or Abort
  1. ;
  1. QUIT ; Quit Passed Environment Check
  1. K LEXFULL D OK
  1. Q
  1. EXIT ; Exit Failed Environment Check
  1. D:$D(LEXE) ED S XPDQUIT=2 K LEXE,LEXFULL Q
  1. ABRT ; Abort Failed Environment Check, KILL the distribution
  1. D:$D(LEXE) ED S XPDABORT=1,XPDQUIT=1 S:$L($G(LEXBUILD)) XPDQUIT(LEXBUILD)=1
  1. K LEXE,LEXFULL
  1. Q
  1. T1 ; Environment Check #1 (for testing only)
  1. K XPDENV D ENV
  1. Q
  1. T2 ; Environment Check #2 (for testing only)
  1. N XPDENV S XPDENV=1 D ENV
  1. Q
  1. ;
  1. ; Checks
  1. ;
  1. GBLS ; Check Write access on globals
  1. N LEXB1,LEXB2,LEXE,LEXGBL,LEXRT,LEXT,LEXF,LEXI,LEXX,LEXOK,LEXCPD,LEXS,X S LEXOK=1
  1. D BM(" I will now check the protection on ^LEX, ^ICPT, ^ICD and ^DIC Globals.")
  1. D M(" If you get an ERROR, you will need to change the protection on these")
  1. D M(" globals to allow read/write as indicated:")
  1. D BM(" Owner Group World Network")
  1. D M(" Cache systems RWD RW RW RWD")
  1. D BM(" Checking:"),M(" ")
  1. S LEXCPD=$$CPD,LEXS="",X=1 F LEXI=1:1 D Q:'$L(LEXX)
  1. . S LEXX="" S LEXE="S LEXX=$T(GD+"_LEXI_")" X LEXE S LEXX=$$TRIM(LEXX) Q:'$L(LEXX) Q:'$L($TR(LEXX,";",""))
  1. . S LEXGBL=$P(LEXX,";",3) Q:+LEXCPD>0&(LEXGBL="^LEXM(0)") S LEXRT=$P(LEXX,";",4),LEXT=$P(LEXX,";",5),LEXF=$P(LEXX,";",6)
  1. . S (LEXB1,LEXB2)="",$P(LEXB1," ",(19-$L(LEXRT)))="",$P(LEXB2," ",(28-$L(LEXT)))=""
  1. . I '$D(@LEXGBL) D RGNF S LEXOK=0 D M((" <"_LEXRT_" not found>")) Q
  1. . D M((" "_LEXRT_LEXB1_LEXT_LEXB2_LEXF)) S @LEXGBL=$G(@LEXGBL)
  1. D:LEXOK M(" --> ok") D:'LEXOK M(" ??") D M(" ")
  1. Q
  1. RGBL(X) ; Check Write access on globals
  1. N LEXCPD,LEXS,LEXI,LEXX,LEXEC,LEXGBL,LEXRT,LEXT,LEXF,LEXB1,LEXB2
  1. S LEXCPD=$$CPD,LEXS="",X=1 F LEXI=1:1 D Q:'$L(LEXX)
  1. . S LEXX="" S LEXEC="S LEXX=$T(GD+"_LEXI_")" X LEXEC S LEXX=$$TRIM(LEXX) Q:'$L(LEXX) Q:'$L($TR(LEXX,";",""))
  1. . S LEXGBL=$P(LEXX,";",3) Q:+LEXCPD>0&(LEXGBL="^LEXM(0)") S LEXRT=$P(LEXX,";",4),LEXT=$P(LEXX,";",5),LEXF=$P(LEXX,";",6)
  1. . S (LEXB1,LEXB2)="",$P(LEXB1," ",(15-$L(LEXRT)))="",$P(LEXB2," ",(28-$L(LEXT)))=""
  1. . I '$D(@LEXGBL) S:LEXS'[LEXRT LEXS=LEXS_", "_LEXRT S X=-1 S:LEXGBL["LEXM("&(X=1) X=0
  1. I $L(LEXS),X'>0 D
  1. . S:LEXS[", " LEXS=$P(LEXS,", ",1,($L(LEXS,", ")-1))_" and "_$P(LEXS,", ",$L(LEXS,", "))
  1. . S:$E(LEXS,1,2)=", " LEXS=$E(LEXS,3,$L(LEXS)) S:$E(LEXS,1,7)[" and " LEXS=$P(LEXS," and ",2)
  1. . D:X=-1 ET(("Global"_$S(LEXS[", "!(LEXS[" and "):"s",1:"")_" "_LEXS_" either not found or incomplete."))
  1. . D:X=0 CM
  1. Q X
  1. RGNF ; Required global not found
  1. N LEXPTYPE,LEXLREV,LEXREQP,LEXBUILD,LEXIGHF,LEXFY,LEXQTR D IMP
  1. D:$G(LEXGBL)["^LEX"&($G(LEXGBL)'["^LEXM") ET(""),ET("Required global "_$P($G(LEXGBL),"(",1)_" not found.")
  1. D:$G(LEXGBL)["^LEX"&($G(LEXGBL)["^LEXM") CM
  1. Q
  1. INS(X) ; Installed
  1. N LEX,LEXP,LEXV,LEXI,LEXS S LEX=$P($G(X)," ",1) I $L(LEX,"*")=3 S X=$$PATCH^XPDUTL(LEX) Q X
  1. S LEXP=$$PKG^XPDUTL(LEX),LEXV=$$VER^XPDUTL(LEX),LEXI=$$VERSION^XPDUTL(LEXP)
  1. Q:+LEXV>0&(LEXV=LEXI) 1
  1. Q 0
  1. INSD(X) ; Installed on
  1. N DA,LEX,LEXDA,LEXE,LEXI,LEXMSG,LEXNS,LEXOUT,LEXPI,LEXPN,LEXSCR,LEXVI,LEXVD,LEXVI,LEXVR S LEX=$G(X)
  1. S LEXNS=$$PKG^XPDUTL(LEX),LEXVR=$$VER^XPDUTL(LEX),LEXPN=$P(X,"*",3)
  1. Q:'$L(LEXNS) "" S LEXVR=+LEXVR Q:LEXVR'>0 "" S LEXPN=+LEXPN S:LEXVR'["." LEXVR=LEXVR_".0"
  1. S LEXSCR="I $G(^DIC(9.4,+($G(Y)),""VERSION""))="""_LEXVR_""""
  1. D FIND^DIC(9.4,,.01,"O",LEXNS,10,"C",LEXSCR,,"LEXOUT","LEXMSG")
  1. S LEXPI=$G(LEXOUT("DILIST",2,1)) K LEXOUT,LEXMSG Q:+LEXPI'>0 "" Q:'$D(@("^DIC(9.4,"_LEXPI_",22)")) ""
  1. K DA S DA(1)=LEXPI S LEXDA=$$IENS^DILF(.DA)
  1. D FIND^DIC(9.49,LEXDA,".01;1I;2I","O",LEXVR,10,"B",,,"LEXOUT","LEXMSG")
  1. S LEXVD=$G(LEXOUT("DILIST","ID",1,2)) I $E(LEXVD,1,7)?7N&(+LEXPN'>0) D Q X
  1. . S X=$E(LEXVD,1,7)_"^"_$TR($$FMTE^XLFDT($E(LEXVD,1,7),"5DZ"),"@"," ")
  1. S:$E(LEXVD,1,7)'?7N LEXVD=$G(LEXOUT("DILIST","ID",1,1)) I $E(LEXVD,1,7)?7N&(+LEXPN'>0) D Q X
  1. . S X=$E(LEXVD,1,7)_"^"_$TR($$FMTE^XLFDT($E(LEXVD,1,7),"5DZ"),"@"," ")
  1. Q:+LEXPN'>0 "" S LEXVI=$G(LEXOUT("DILIST",2,1)) K LEXOUT,LEXMSG
  1. Q:+LEXVI'>0 "" Q:'$D(@("^DIC(9.4,"_LEXPI_",22,"_LEXVI_",""PAH"")")) ""
  1. K DA S DA(2)=LEXPI,DA(1)=LEXVI S LEXDA=$$IENS^DILF(.DA)
  1. S LEXSCR="I $G(^DIC(9.4,"_LEXPI_",22,"_LEXVI_",""PAH"",+($G(Y)),0))[""SEQ #"""
  1. D FIND^DIC(9.4901,LEXDA,".01;.02I",,LEXPN,10,"B",LEXSCR,,"LEXOUT","LEXMSG")
  1. S LEXI=$G(LEXOUT("DILIST","ID",1,.02)) I '$L(LEXI) D
  1. . S LEXSCR="" D FIND^DIC(9.4901,LEXDA,".01;.02I",,LEXPN,10,"B",LEXSCR,,"LEXOUT","LEXMSG")
  1. . S LEXI=$G(LEXOUT("DILIST","ID",1,.02))
  1. Q:'$L(LEXI) "" Q:$P(LEXI,".",1)'?7N "" S LEXE=$TR($$FMTE^XLFDT(LEXI,"5DZ"),"@"," ")
  1. Q:'$L(LEXE) "" S X=LEXI_"^"_LEXE
  1. Q X
  1. CHK ; Check the Checksum
  1. D CS I $D(LEXE) D ED Q
  1. D BM(" OK"),M(" ")
  1. Q
  1. CS ; Checksum for import global
  1. K LEXE D BM(" Running checksum routine on the ^LEXM import global, please wait")
  1. N LEXCK,LEXND,LEXV S LEXCK=+($G(^LEXM(0,"CHECKSUM")))
  1. S LEXND=+($G(^LEXM(0,"NODES"))),LEXV=+($$VC(LEXCK,LEXND))
  1. D M(" ") D:LEXV>0 M(" Checksum is ok"),M(" ")
  1. D:LEXV=0 CM D:LEXV=-1 CW D:LEXV=-2 CU D:LEXV=-3 CF
  1. Q
  1. VC(X,Y) ; Verify Checksum for import global
  1. N LEXPTYPE,LEXLREV,LEXREQP,LEXBUILD,LEXIGHF,LEXFY,LEXQTR Q:'$D(^LEXM) 0
  1. D IMP I $G(^LEXM(0,"BUILD"))'=$G(LEXBUILD) Q -1
  1. N LEXCK,LEXND,LEXCNT,LEXLC,LEXL,LEXS,LEXNC,LEXD,LEXN,LEXC,LEXGCS,LEXP,LEXT
  1. S LEXCK=+($G(X)),LEXND=+($G(Y))
  1. Q:LEXCK'>0!(LEXND'>0) -2
  1. S LEXL=64,(LEXCNT,LEXLC)=0,LEXS=(+(LEXND\LEXL))
  1. S:LEXS=0 LEXS=1 D:+($O(^LEXM(0)))>0 M("")
  1. S (LEXC,LEXN)="^LEXM",(LEXNC,LEXGCS)=0 W " "
  1. F S LEXN=$Q(@LEXN) Q:LEXN=""!(LEXN'[LEXC) D
  1. . Q:LEXN="^LEXM(0,""CHECKSUM"")"
  1. . Q:LEXN="^LEXM(0,""NODES"")"
  1. . S LEXCNT=LEXCNT+1
  1. . I LEXCNT'<LEXS S LEXLC=LEXLC+1 W:LEXLC'>LEXL "." S LEXCNT=0
  1. . S LEXNC=LEXNC+1,LEXD=@LEXN,LEXT=LEXN_"="_LEXD
  1. . F LEXP=1:1:$L(LEXT) S LEXGCS=$A(LEXT,LEXP)*LEXP+LEXGCS
  1. Q:LEXNC'=LEXND -3
  1. Q:LEXGCS'=LEXCK -3
  1. Q 1
  1. SY(X) ; Check System variables
  1. Q:'$D(IO)!('$D(IOF))!('$D(IOM))!('$D(ION))!('$D(IOSL))!('$D(IOST)) 0
  1. Q 1
  1. UR(X) ; Check User variables
  1. Q:'$L($G(DUZ(0))) 0
  1. Q:+($G(DUZ))=0!($$NOTDEF(+$G(DUZ))) 0
  1. Q 1
  1. CPD(X) ; Check Current Patched Data is installed
  1. N INS S INS=1
  1. Q 0
  1. ;
  1. ; Error messages
  1. ;
  1. CM ; Missing ^LEXM
  1. N LEXPTYPE,LEXLREV,LEXREQP,LEXBUILD,LEXIGHF,LEXFY,LEXQTR D IMP D ET(""),ET("Missing import global ^LEXM.") D CO
  1. Q
  1. CW ; Wrong ^LEXM
  1. N LEXB,LEXPTYPE,LEXLREV,LEXREQP,LEXBUILD,LEXIGHF,LEXFY,LEXQTR D IMP S LEXB=$G(^LEXM(0,"BUILD")) D ET("")
  1. I $L(LEXBUILD),$L(LEXB),LEXBUILD'=LEXB D Q
  1. . D ET(("Incorrect import global ^LEXM found ("_LEXB_" global).")) D CKO
  1. D ET("Incorrect import global ^LEXM found.") D CKO
  1. Q
  1. CU ; Unable to verify
  1. N LEXPTYPE,LEXLREV,LEXREQP,LEXBUILD,LEXIGHF,LEXFY,LEXQTR D IMP D ET(""),ET("Unable to verify checksum for import global ^LEXM (possibly corrupt).") D CKO
  1. Q
  1. CF ; Failed checksum
  1. N LEXPTYPE,LEXLREV,LEXREQP,LEXBUILD,LEXIGHF,LEXFY,LEXQTR D IMP D ET("") D ET("Import global ^LEXM failed checksum.") D CKO
  1. Q
  1. CO ; Obtain new global
  1. N LEXPTYPE,LEXLREV,LEXREQP,LEXBUILD,LEXIGHF,LEXFY,LEXQTR D IMP
  1. D ET(""),ET(" Please obtain a copy of the import global ^LEXM contained in the ")
  1. D ET((" global host file "_LEXIGHF_" before continuing with the "_LEXBUILD))
  1. D ET((" installation."))
  1. Q
  1. TEST ;
  1. D CW,ED
  1. Q
  1. CKO ; Kill and Obtain new global
  1. N LEXPTYPE,LEXLREV,LEXREQP,LEXBUILD,LEXIGHF,LEXFY,LEXQTR D IMP D ET("")
  1. D ET((" Use the entry point KALL^LEXXGI2 to safely KILL the existing "))
  1. D ET((" import global ^LEXM from your system. Then obtain a new copy"))
  1. D ET((" of ^LEXM contained in the global host file "_LEXIGHF_" before"))
  1. D ET((" continuing with the "_LEXBUILD_" installation."))
  1. Q
  1. ET(X) ; Error Text
  1. N LEXI S LEXI=+($G(LEXE(0))),LEXI=LEXI+1,LEXE(LEXI)=" "_$G(X),LEXE(0)=LEXI
  1. Q
  1. ED ; Error Display
  1. N LEXI S LEXI=0 F S LEXI=$O(LEXE(LEXI)) Q:+LEXI=0 D M(LEXE(LEXI))
  1. D M(" ") K LEXE Q
  1. ;
  1. ; Miscellaneous
  1. ;
  1. NOTDEF(IEN) ; Check to see if user is defined
  1. N DA,DR,DIQ,LEX,DIC S DA=IEN,DR=.01,DIC=200,DIQ="LEX" D EN^DIQ1 Q '$D(LEX)
  1. OK ; Environment is OK
  1. N LEXPTYPE,LEXLREV,LEXREQP,LEXBUILD,LEXIGHF,LEXFY,LEXQTR,LEXT
  1. D IMP S LEXT=" Environment "_$S($L(LEXBUILD):("for patch/build "_LEXBUILD_" "),1:"")_"is ok"
  1. D BM(LEXT),M(" ")
  1. Q
  1. BM(X) ; Blank Line with Message
  1. S X=$G(X) S:$E(X,1)'=" " X=" "_X D BMES^XPDUTL(X) Q
  1. M(X) ; Message
  1. S X=$G(X) S:$E(X,1)'=" " X=" "_X D MES^XPDUTL(X) Q
  1. TRIM(X) ; Trim Spaces
  1. S X=$G(X) F Q:$E(X,1)'=" " S X=$E(X,2,$L(X))
  1. F Q:$E(X,$L(X))'=" " S X=$E(X,1,($L(X)-1))
  1. Q X
  1. IMP ; Import names
  1. S LEXPTYPE="Code Set Remedy Ticket Fixes"
  1. S LEXPTYPE="Code Set Update"
  1. ; Revision
  1. S LEXLREV=104
  1. ; Required Builds Array
  1. ; LEX(1)=build SEQ #^released date^subject
  1. ; LEX(n)=build SEQ #^released date^subject
  1. S LEXREQP(1)="LEX*2.0*101 SEQ #93^3150930^Code Set FY16 1st Qtr"
  1. ; This Build Name
  1. S LEXBUILD="LEX*2.0*104"
  1. ; This Build's Export Global Host Filename
  1. S LEXIGHF="LEX_2_104.GBL"
  1. ; Fiscal Year
  1. S LEXFY="FY16"
  1. ; Quarter
  1. S LEXQTR="2nd"
  1. Q
  1. EF ; Exported Files
  1. ;;^LEX(757.01);^LEX(*;Lexicon;757-757.41
  1. ;;^LEXT(757.2);^LEXT(757.2);Lexicon Subsets/Defaults;757.2
  1. ;;
  1. ;;^ICPT(0);^ICPT(;CPT/HCPCS;81
  1. ;;^DIC(81.1,0);^DIC(81.1);CPT Category;81.1
  1. ;;^DIC(81.2,0);^DIC(81.2);CPT Copyright;81.2
  1. ;;^DIC(81.3,0);^DIC(81.3);CPT Modifier;81.3
  1. ;;
  1. ;;^ICD9(0);^ICD9(;ICD Diagnosis;80
  1. ;;^ICD0(0);^ICD0(;ICD Operation/Procedure;80.1
  1. ;;^ICD(0);^ICD(;DRG Grouper;80.2
  1. ;;^ICM(0);^ICM(;MAJOR DIAGNOSTIC CATEGORY;80.3
  1. Q
  1. GD ; Global Data
  1. ;;^ICPT(0);^ICPT(;CPT/HCPC;81
  1. ;;^DIC(81.1,0);^DIC(81.1);CPT Category;81.1
  1. ;;^DIC(81.3,0);^DIC(81.3);CPT Modifier;81.3
  1. ;;^LEX(757.01);^LEX(*;Lexicon;757-757.41