Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: LEX2145P

LEX2145P.m

Go to the documentation of this file.
  1. LEX2145P ;ISL/TJH - LEX*2.0*145 Pre/Post Install ; 09/07/2023
  1. ;;2.0;LEXICON UTILITY;**145**;Sep 23, 1996;Build 1
  1. ;
  1. ; Global Variables
  1. ; ^LEXM( N/A
  1. ;
  1. ; External References
  1. ; DBIA #10006
  1. ; DBIA #10103
  1. ; DBIA #2067
  1. ; DBIA #10141
  1. ; DBIA #10112
  1. ; DBIA #2729
  1. ; DBIA #2171
  1. ; DBIA #4440
  1. ;
  1. Q
  1. POST ; Post-Install
  1. ;
  1. ; From IMP in the Environment Check
  1. ;
  1. ; LEXBUILD Build Name - LEX*2.0*nnn
  1. ; LEXPTYPE Patch Type - Remedy or Quarterly
  1. ; LEXFY Fiscal Year - FYnn
  1. ; LEXQTR Quarter - 1st, 2nd, 3rd, or 4th
  1. ; LEXIGHF Name of Host File - LEX_2_nnn.GBL
  1. ; LEXLREV Revision - nnn
  1. ; LEXREQP Required Builds - build;build;build
  1. ;
  1. ; Note: All references to the patch number should be
  1. ; checked and updated as necessary.
  1. ;
  1. ; The sub-routine (Informational Patch List) must
  1. ; be updated with each patch. It should include
  1. ; (as a minimum) the patch names of all of the
  1. ; informational patches associated with the Lexicon
  1. ; Patch. This will update the Package file at the
  1. ; site.
  1. ;
  1. N LEXEDT,LEXPTYPE,LEXLREV,LEXREQP,LEXBUILD,LEXIGHF,LEXFY,LEXQTR,LEXB,LEXCD,LEXSTR,LEXLAST,LEXOK,X,Y S LEXOK=0 D IMP
  1. S LEXEDT=$G(^LEXM(0,"CREATED")) D:LEXOK>0 LOAD,CON,IP
  1. Q
  1. LOAD ; Load Data
  1. ;
  1. ; LEXSHORT Send Short Message
  1. ; LEXMSG Flag to send Message
  1. ;
  1. N LEXSHORT,LEXMSG S LEXSHORT="",LEXMSG=""
  1. S LEXSTR=$G(LEXPTYPE) S:$L($G(LEXFY))&($L($G(LEXQTR))) LEXSTR=LEXSTR_" for "_$G(LEXFY)_" "_$G(LEXQTR)_" Quarter"
  1. S U="^",LEXB=$G(^LEXM(0,"BUILD")) Q:LEXB="" Q:$G(LEXBUILD)=""
  1. D:LEXB=LEXBUILD EN^LEXXGI
  1. LQ ; Load Quit
  1. D KLEXM
  1. Q
  1. ;
  1. KLEXM ; Subscripted Kill of ^LEXM
  1. H 2 N DA S DA=0 F S DA=$O(^LEXM(DA)) Q:+DA=0 K ^LEXM(DA)
  1. N LEX S LEX=$G(^LEXM(0,"PRO")) K ^LEXM(0)
  1. Q
  1. ;
  1. IP ; Informational Patches
  1. N LEX,LEXP,LEXPS,LEXSQ,LEXT,LEXI,LEXE,LEXX,LEXC,LEXPTYPE,LEXLREV,LEXREQP,LEXBUILD,LEXIGHF,LEXFY,LEXQTR,LEXSUB,LEXOK D IMP S LEXSUB=""
  1. I $G(LEXPTYPE)="Code Set Update",$G(LEXFY)["FY",$L($G(LEXQTR)) S LEXSUB="Code Set "_LEXFY_" "_LEXQTR_" Qtr Update"
  1. S LEXC=0 F LEXI=1:1 D Q:'$L(LEXX)
  1. . S LEXX="" S LEXE="S LEXX=$T(IPL+"_LEXI_")" X LEXE S:'$L($TR($G(LEXX),";","")) LEXX="" Q:'$L(LEXX) S LEXPS=$P(LEXX,";;",2) S:$L(LEXPS,"*")=3 LEXC=LEXC+1
  1. I LEXC>0 S LEXT=" Informational Patch"_$S(+($G(LEXC))>1:"es",1:"") S:$L(LEXSUB) LEXT=LEXT_" for the "_LEXSUB S LEXT=LEXT_":" D MES^XPDUTL(LEXT)
  1. S LEXC=0 F LEXI=1:1 D Q:'$L(LEXX)
  1. . S LEXX="" S LEXE="S LEXX=$T(IPL+"_LEXI_")" X LEXE S:'$L($TR($G(LEXX),";","")) LEXX="" Q:'$L(LEXX) S LEXPS=$P(LEXX,";;",2) S:'$L(LEXPS) LEXX="" Q:'$L(LEXX)
  1. . S LEXSQ=+($P(LEXX,";;",3)) S:+LEXSQ>0 LEXPS=LEXPS_" SEQ #"_LEXSQ S LEXC=LEXC+1 D:LEXC=1 MES^XPDUTL(" ")
  1. . W:$D(LEXTEST) !,?5,LEXPS D:'$D(LEXTEST) IPU(LEXPS)
  1. D:LEXC>0 MES^XPDUTL(" ") N LEXTEST
  1. Q
  1. IPU(X) ; Patch Update
  1. N LEXID,LEXOP,LEXPC,LEXPK,LEXPKI,LEXPN,LEXPTI,LEXSQ,LEXT,LEXVR,LEXVRI,LEXAR
  1. S LEXPC=$G(X),LEXSQ=$P(LEXPC," ",2,299),LEXID=$P(LEXPC," ",1),LEXOP=""
  1. S LEXPK=$S($P(LEXPC,"*",1)="ICD":"DRG GROUPER",$P(LEXPC,"*",1)="ICPT":"CPT/HCPCS CODES",$P(LEXPC,"*",1)="LEX":"LEXICON UTILITY",1:"") Q:'$L(LEXPK)
  1. S LEXPKI=$$PIEN(LEXPK) Q:+LEXPKI'>0 S LEXVR=$P(LEXPC,"*",2) Q:'$L(LEXVR) Q:LEXVR'["." S LEXPN=$P(LEXPC,"*",3) Q:'$L(LEXPN) Q:+LEXPN'>0
  1. S LEXAR=LEXPN_"^"_$$NOW^XLFDT_"^"_$G(DUZ)
  1. I $L($G(LEXBUILD)) S LEXOP=$$PKGPAT^XPDIP(LEXPKI,LEXVR,.LEXAR)
  1. S LEXVRI=$P(LEXOP,"^",1),LEXPTI=$P(LEXOP,"^",2)
  1. S LEXT=" "_LEXID,LEXT=LEXT_$J(" ",(17-$L(LEXT)))_LEXSQ,LEXT=LEXT_$J(" ",(28-$L(LEXT)))_LEXPK
  1. I $L(LEXOP),LEXPTI>0 S LEXT=LEXT_$J(" ",(46-$L(LEXT)))_"Patch History updated" D MES^XPDUTL(LEXT)
  1. I $L(LEXOP),LEXPTI'>0 S LEXT=LEXT_$J(" ",(46-$L(LEXT)))_"Patch History not updated" D MES^XPDUTL(LEXT)
  1. I '$L(LEXOP) D MES^XPDUTL(LEXT)
  1. Q
  1. IPL ; Patch List ;;Patch;;Sequence # This is also where you would include the ICPT/ICD patch number(s).
  1. ;;ICPT*6.0*111;;
  1. ;;ICD*18.0*116;;
  1. ;;;;;;
  1. Q
  1. PRE ; Pre-Install (N/A for this patch)
  1. Q
  1. CON ; Conversion of data (N/A for this patch)
  1. Q
  1. ;
  1. ; Miscellaneous
  1. PIEN(X) ; Package IEN
  1. N DIC,DTOUT,DTOUT,Y S X=$G(X),DIC="^DIC(9.4,",DIC(0)="B" D ^DIC S X=+Y
  1. Q X
  1. IMP ; Call IMP in Environment Check
  1. K LEXBUILD,LEXFY,LEXIGHF,LEXLREV,LEXPTYPE,LEXQTR,LEXREQP N LEXF
  1. S LEXF=$P($T(+1)," ",1) S:$E(LEXF,$L(LEXF))="P" LEXF=$E(LEXF,1,($L(LEXF)-1)) Q:'$L(LEXF)
  1. S LEXF="IMP^"_LEXF Q:'$L($T(@LEXF)) D @LEXF S:$L(LEXBUILD) LEXOK=1
  1. Q