Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: LRLABELE

LRLABELE.m

Go to the documentation of this file. 
  1. LRLABELE ;DALOI/JMC - Zebra Stripe 2.5x4 10 part label; 6/4/98
  1.  ;;5.2;LAB SERVICE;**218**;Sep 27, 1994
  1.  ;
  1. EN ; Print 2.5x4 10 part label format
  1.  ;
  1.  N J,LRDTXT,LRFONT,LRFMT,LRLPNM,LRTXT,LRTUBE,LRX,LRZ,ETX,STX
  1.  ;
  1.  S LRLPNM=$E(PNM,1,14),LRRB=$G(LRRB)
  1.  ;
  1.  ; Determine collection sample text
  1.  I LRXL,N-I<LRXL S LRTUBE=LRTOP
  1.  E  S LRTUBE=LRPREF_LRTOP
  1.  ;
  1.  D LH
  1.  ;
  1.  ; Set specific symbology.
  1.  S LRFMT=+$G(LRBAR(+$G(LRAA)))
  1.  ;
  1.  ; Setup test list
  1.  S LRTXT=$$LRTXT^LRLABLD(.LRTS,$S(LRFMT<2:25,1:32))
  1.  I LRTXT[";" S LRDTXT=".............."
  1.  E  S LRDTXT=LRTXT
  1.  ;
  1.  I LRFMT<2 D BAR1 Q
  1.  I LRFMT>1 D BAR2
  1.  ;
  1.  Q
  1.  ;
  1. BAR1 ; Print 2.5x4 10 part labels.
  1.  ; Barcode identifier - use Code 39 with check-digit.
  1.  ; Label length = 812 dots (8 dots/mm printhead).
  1.  ;
  1.  W STX
  1.  S LRFONT="^ADN,36,10^FWR"
  1.  ;
  1.  ; Patient name
  1.  D PL^LRLABELD(433,90,$E(PNM,1,21),LRFONT)
  1.  D FONT S LRFONT=LRFONT_"^FWR"
  1.  ;
  1.  ; Print patient identifier.
  1.  D PL^LRLABELD(418,90,SSN,LRFONT)
  1.  ;
  1.  ; Patient location/room-bed number
  1.  D PL^LRLABELD(418,260,$S($L(LRRB):"B:"_LRRB,1:"W:"_LRLLOC),LRFONT)
  1.  ;
  1.  ; Print barcode.
  1.  S LRFONT="^BY2,2"
  1.  I $L(LRBARID)<7 S LRFONT="^BY3,2,"
  1.  S LRFONT=LRFONT_",60^B3N,Y,,N,N^FWR"
  1.  D PL^LRLABELD(355,95,LRBARID,LRFONT)
  1.  ;
  1.  ; Print order number.
  1.  D FONT S LRFONT=LRFONT_"^FWR"
  1.  D PL^LRLABELD(330,90,"Order #"_LRCE,LRFONT)
  1.  ;
  1.  ; Print collection sample.
  1.  D PL^LRLABELD(315,90,$E(LRTUBE,1,$S($G(LRURG0)=1:18,1:24)),LRFONT)
  1.  ;
  1.  ; Accession urgency
  1.  I $G(LRURG0)=1 D
  1.  . ; Set up graphic box.
  1.  . D GB^LRLABELD(320,317,"35,63,35")
  1.  . S LRFONT="^ADN,36,10^FWR^FR"
  1.  . ; Print urgency
  1.  . D PL^LRLABELD(315,322,"STAT",LRFONT)
  1.  ;
  1.  ; Print test list
  1.  S LRFONT="^ADN,36,10^FWR"
  1.  D PL^LRLABELD(280,90,LRTXT,LRFONT)
  1.  ;
  1.  ; Print accession.
  1.  S LRFONT="^ADN,36,10"
  1.  D PL^LRLABELD(280,0,$$CJ^XLFSTR(LRACC,16),LRFONT),FONT
  1.  ;
  1.  ; Print accession date.
  1.  D PL^LRLABELD(280,40,$$CJ^XLFSTR(LRDAT,16),LRFONT)
  1.  ;
  1.  ; Print accession - 2nd 1x2.
  1.  S LRFONT="^ADN,36,10^FWR"
  1.  D PL^LRLABELD(433,406,LRACC,LRFONT)
  1.  ;
  1.  ; Print accession date - 2nd 1x2..
  1.  D FONT S LRFONT=LRFONT_"^FWR"
  1.  D PL^LRLABELD(418,406,LRDAT,LRFONT)
  1.  ;
  1.  ; Print collection sample - 2nd 1x2.
  1.  D PL^LRLABELD(400,406,$E(LRTUBE,1,$S($G(LRURG0)=1:21,1:30)),LRFONT)
  1.  ;
  1.  ; Accession urgency - 2nd 1x2.
  1.  I $G(LRURG0)=1 D
  1.  . ; Set up graphic box.
  1.  . D GB^LRLABELD(410,666,"35,63,35")
  1.  . S LRFONT="^ADN,36,10^FWR^FR"
  1.  . ; Print urgency
  1.  . D PL^LRLABELD(405,671,"STAT",LRFONT),FONT
  1.  ;
  1.  ; Patient name - 2nd 1x2.
  1.  S LRFONT="^ADN,36,10^FWR"
  1.  D PL^LRLABELD(360,444,$E(PNM,1,21),LRFONT),FONT
  1.  ;
  1.  ; Print patient identifier - 2nd 1x2.
  1.  S LRFONT=LRFONT_"^FWR"
  1.  D PL^LRLABELD(345,444,SSN,LRFONT)
  1.  ;
  1.  ; Print order number - 2nd 1x2.
  1.  D PL^LRLABELD(325,406,"Order #"_LRCE,LRFONT)
  1.  ;
  1.  ; Print test list - 2nd 1x2, redo test list for wider area on 2nd label
  1.  S LRFONT="^ADN,36,10^FWR"
  1.  S LRTXT=$$LRTXT^LRLABLD(.LRTS,32)
  1.  I LRTXT[";" S LRDTXT=".............."
  1.  E  S LRDTXT=LRTXT
  1.  D PL^LRLABELD(280,406,LRTXT,LRFONT)
  1.  ;
  1.  D FONT,COMMON
  1.  W ETX
  1.  Q
  1.  ;
  1. BAR2 ; Print 2.5x4 10 part labels.
  1.  ; Barcode identifier using specified symbology for accession area.
  1.  ; Label length = 812 dots (8 dots/mm printhead).
  1.  ;
  1.  W STX
  1.  S LRFONT="^ADN,36,10^FWR"
  1.  ;
  1.  ; Patient name
  1.  F LRY=0,406 D PL^LRLABELD(433,LRY,$E(PNM,1,21),LRFONT)
  1.  ;
  1.  ; Accession urgency
  1.  I $P(LRURGA,"^",2) D
  1.  . S LRFONT="^ADN,36,10^FWR"
  1.  . I $P(LRURGA,"^",2)=2 D
  1.  . . ; Set up graphic box.
  1.  . . F LRY=295,699 D GB^LRLABELD(437,LRY,"35,"_(15+($L($P(LRURGA,"^"))*12))_",35")
  1.  . . ; Field reverse.
  1.  . . S LRFONT=LRFONT_"^FR"
  1.  . ; Print urgency
  1.  . F LRY=300,704 D PL^LRLABELD(433,LRY,$P(LRURGA,"^"),LRFONT)
  1.  ;
  1.  ; Print patient identifier.
  1.  D FONT S LRFONT=LRFONT_"^FWR"
  1.  F LRY=0,406 D PL^LRLABELD(418,LRY,SSN,LRFONT)
  1.  ;
  1.  ; Patient location/room-bed number
  1.  F LRY=170,576 D PL^LRLABELD(418,LRY,"W:"_LRLLOC_$S($L(LRRB):"/"_LRRB,1:""),LRFONT)
  1.  ;
  1.  ; Print barcode.
  1.  S LRFONT="^BY"_$S($L(LRBARID)>10:1,1:2)_","_$S($L(LRBARID)<7:3,1:2)_",60^"
  1.  S LRFONT=LRFONT_$S(LRFMT=2:"B3N,N,,N,N",LRFMT=3:"B3N,Y,,N,N",LRFMT=4:"BCN,,N,N",1:"BCN,,N,N")
  1.  S LRFONT=LRFONT_"^FWR"
  1.  F LRZ=10,416 D
  1.  . S LRY=LRZ+$S($L(LRBARID)<7:55,LRFMT=3:5,LRFMT=4:15,1:0)
  1.  . D PL^LRLABELD(358,LRY,LRBARID,LRFONT)
  1.  ;
  1.  ; Print human-readable ID.
  1.  D FONT S LRFONT=LRFONT_"^FWR"
  1.  F LRY=0,406 D PL^LRLABELD(335,LRY,LRBARID,LRFONT)
  1.  ;
  1.  ; Print infection warning if present.
  1.  I $L(LRINFW) D
  1.  . ; Set up graphic box.
  1.  . F LRY=140,544 D GB^LRLABELD(337,LRY,"16,"_(10+($L(LRINFW)*12))_",16,")
  1.  . D FONT S LRFONT=LRFONT_"^FWR^FR"
  1.  . ; Print infection warning.
  1.  . F LRY=145,549 D PL^LRLABELD(335,LRY,LRINFW,LRFONT)
  1.  . D FONT S LRFONT=LRFONT_"^FWR"
  1.  ;
  1.  ; Print accession date.
  1.  F LRY=0,406 D PL^LRLABELD(316,LRY,$P(LRDAT," "),LRFONT)
  1.  ;
  1.  ; Print accession.
  1.  F LRY=120,526 D PL^LRLABELD(316,LRY,LRACC,LRFONT)
  1.  ;
  1.  ; Print order number.
  1.  F LRY=0,406 D PL^LRLABELD(298,LRY,"Order #"_LRCE,LRFONT)
  1.  ;
  1.  ; Print collection sample.
  1.  F LRY=180,586 D PL^LRLABELD(298,LRY,$E(LRTUBE,1,17),LRFONT)
  1.  ;
  1.  ; Print test list
  1.  F LRY=0,406 D PL^LRLABELD(280,LRY,LRTXT,LRFONT)
  1.  D FONT,COMMON
  1.  ;
  1.  W ETX
  1.  Q
  1.  ;
  1. COMMON ; Print lower 8 sections of label - common to both formats.
  1.  ;
  1.  N LRJ
  1.  ;
  1.  S LRTXT=$$LRTXT^LRLABLD(.LRTS,200)
  1.  ;
  1.  F LRY=0,203,406,609 D
  1.  . ; Print accession
  1.  . S LRX=220,LRFONT="^ADN,36,10^FWR"
  1.  . D PL^LRLABELD(LRX,LRY,LRACC,LRFONT)
  1.  . ;
  1.  . ; Print collection sample
  1.  . S LRX=190 D FONT S LRFONT=LRFONT_"^FWR"
  1.  . D PL^LRLABELD(LRX,LRY,$E(LRTUBE,1,15),LRFONT)
  1.  . ;
  1.  . ; Print accession
  1.  . S LRX=130,LRFONT="^ADN,36,10^FWR"
  1.  . D PL^LRLABELD(LRX,LRY,LRACC,LRFONT)
  1.  . ;
  1.  . ; Print patient name
  1.  . S LRX=95
  1.  . D PL^LRLABELD(LRX,LRY,LRLPNM,LRFONT)
  1.  . ;
  1.  . ; Print patient identifier.
  1.  . S LRX=75 D FONT S LRFONT=LRFONT_"^FWR"
  1.  . D PL^LRLABELD(LRX,LRY,SSN,LRFONT)
  1.  . ;
  1.  . ; Print collection date/time
  1.  . S LRX=50
  1.  . D PL^LRLABELD(LRX,LRY,LRDAT,LRFONT)
  1.  . ;
  1.  . ; Print test list
  1.  . S LRX=0,LRFONT="^ADN,36,10^FWR"
  1.  . S LRJ=$S(LRY=203:2,LRY=406:3,LRY=609:4,1:1)
  1.  . S LRZ=$S($P(LRTXT,";",LRJ)'="":$E($P(LRTXT,";",LRJ),1,14),1:$E(LRDTXT,1,14))
  1.  . D PL^LRLABELD(LRX,LRY,LRZ,LRFONT)
  1.  Q
  1.  ;
  1.  ;
  1. LH ; Set Label Home ("LH") parameters.
  1.  ;
  1.  S STX=$C(2),ETX=$C(3)
  1.  ;
  1.  ; Set Print Orientation ("PO") to Inverted, and Label Home ("LH") parameters.
  1.  W STX,"^POI^LH360,13",ETX
  1.  ;
  1. FONT ;
  1.  ; Default font.
  1.  S LRFONT="^ADN"
  1.  Q