Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: MCARAPI

MCARAPI.m

Go to the documentation of this file. 
  1. MCARAPI ; HOIFO/NCA - Electrocardiogram Data Extraction ;7/3/96  09:13
  1.  ;;2.3;Medicine;**34**;09/13/1996
  1.  ; Reference IA #3780
  1.  ;           IA #10154 Access 2nd piece of ^DD(filenumber,fieldnumber,0)
  1. GET(RESULTS,MCARDFN,MCSDT,MCEDT,MCFLDS) ; Returns list of data from Electrocardiogram File #691.5
  1.  ; Input: RESULTS - the global array in which  (Required)
  1.  ;                  to return results.
  1.  ;        MCARDFN - the patient DFN.           (Required)
  1.  ;        MCSDT - the start date of the date   (Required)
  1.  ;                range to return the data in.
  1.  ;                This must be in FM internal
  1.  ;                format.
  1.  ;        MCEDT - the end date of the date     (Required)
  1.  ;                range to return the data in.
  1.  ;                This must be in FM internal
  1.  ;                format.
  1.  ;        MCFLDS - a list of fields from file #691.5 to  (Required)
  1.  ;                 be returned in RESULTS.  MCFLDS should
  1.  ;                 contain a list of fields delimited by ";"
  1.  ;                 example: MCFLDS=".01;11;20..."
  1.  ;
  1.  ; Output: RESULTS  (Passed by Reference)
  1.  ;         Global array return in the following FM DIQ call format:
  1.  ;         example:
  1.  ;          ^TMP("MCDATA",$J,file #,record ien_",",field #,"E")=Data
  1.  ;          ^TMP("MCDATA",$J,subfile #,entry #_","_record ien,
  1.  ;                field of the multiple,"E")=data
  1.  ;     
  1.  ;         Only the Electrocardiogram records in the following
  1.  ;         statuses will be returned in the list:
  1.  ;  
  1.  ;         RELEASED ON-LINE VERIFIED
  1.  ;         RELEASED OFF-LINE VERIFIED
  1.  ;         RELEASED NOT VERIFIED
  1.  ;         RELEASED ON-LINE VERIFIED OF SUPERSEDED
  1.  ;         RELEASED OFF-LINE VERIFIED OF SUPERSEDED
  1.  ;
  1.  ;         RESULTS(0) will equal one of the following, if the call
  1.  ;         failed:
  1.  ;             -1^No Patient DFN.
  1.  ;             -1^No Start Date Range.
  1.  ;             -1^No End Date Range.
  1.  ;             -1^Start Date greater than End Date.
  1.  ;             -1^No fields defined.
  1.  ;             -1^Global TMP array only.
  1.  ;         If no return array defined,^TMP("MCAPI",$J,0) equals
  1.  ;             -1^No return array global.
  1.  ;
  1.  ;         If no data, RESULTS(0) equals
  1.  ;             -1^No data for patient.
  1.  ;
  1.  N MCCODE,MCDR,MCK,MCLP,MCN,MCNOD,MCSUBF,MCX,MCY
  1.  K ^TMP("MCAPI",$J)
  1.  I '$D(RESULTS) S ^TMP("MCAPI",$J,0)="-1^No return array global." Q
  1.  I $G(RESULTS)'["^TMP" S ^TMP("MCAPI",$J,0)="-1^Global TMP array only." Q
  1.  I '+$G(MCARDFN) S @RESULTS@(0)="-1^No Patient DFN." Q
  1.  I '$G(MCSDT) S @RESULTS@(0)="-1^No Start Date Range." Q
  1.  I '$G(MCEDT) S @RESULTS@(0)="-1^No End Date Range." Q
  1.  I MCSDT>MCEDT S @RESULTS@(0)="-1^Start Date greater than End Date." Q
  1.  I $G(MCFLDS)="" S @RESULTS@(0)="-1^No fields defined." Q
  1.  S (MCDR,MCX,MCY)="",MCEDT=MCEDT\1+.3
  1.  S MCN=$L(MCFLDS,";")
  1.  F MCK=1:1:MCN S MCY=+$P(MCFLDS,";",MCK) I MCY D
  1.  .Q:'$$VFIELD^DILFD(691.5,MCY)
  1.  .S MCNOD=$P($G(^DD(691.5,+MCY,0)),"^",2),MCSUBF=0
  1.  .I +MCNOD[691.5&($E(MCNOD,$L(MCNOD)-1,$L(MCNOD))="PA") S MCSUBF=1
  1.  .S MCDR=MCDR_$S(MCDR="":"",1:";")_MCY_$S(MCSUBF:"*",1:"")
  1.  .Q
  1.  S MCLP=0 F  S MCLP=$O(^MCAR(691.5,"C",MCARDFN,MCLP)) Q:MCLP<1  D
  1.  .S MCX=$G(^MCAR(691.5,MCLP,0)) Q:MCX=""
  1.  .Q:$P(MCX,"^")<MCSDT!($P(MCX,"^")>MCEDT)
  1.  .S MCCODE=$P($G(^MCAR(691.5,MCLP,"ES")),"^",7)
  1.  .S:MCCODE="" MCCODE="RNV"
  1.  .I MCCODE="S"!(MCCODE["D") Q
  1.  .D GETS^DIQ(691.5,MCLP_",",MCDR,"E",$NA(@RESULTS))
  1.  .Q
  1.  I '$D(@(RESULTS)) S @RESULTS@(0)="-1^No data for patient."
  1.  Q