Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: NHINVSIT

NHINVSIT.m

Go to the documentation of this file. 
  1. NHINVSIT ;SLC/MKB -- Visit/Encounter extract
  1.  ;;1.0;NHIN;**1**;Oct 25, 2010;Build 11
  1.  ;
  1.  ; External References          DBIA#
  1.  ; -------------------          -----
  1.  ; ^AUPNVSIT                     2028
  1.  ; ^DIC(40.7                      557
  1.  ; ^DIC(42                      10039
  1.  ; ^SC                          10040
  1.  ; ^SCE                          2065
  1.  ; ^VA(200                      10060
  1.  ; DIC                           2051
  1.  ; DIQ                           2056
  1.  ; ICDCODE                       3990
  1.  ; ICPTCOD                       1995
  1.  ; PXAPI,^TMP("PXKENC",$J   1894,1895
  1.  ; VADPT                        10061
  1.  ; XUAF4                         2171
  1.  ;
  1.  ; ------------ Get encounter(s) from VistA ------------
  1.  ;
  1. EN(DFN,BEG,END,MAX,ID) ; -- find patient's visits and appointments
  1.  N NHICNT,NHITM,NHDT,NHLOC,NHDA
  1.  S DFN=+$G(DFN) Q:DFN<1
  1.  S BEG=$G(BEG,1410101),END=$G(END,9999998),MAX=$G(MAX,999999)
  1.  ;
  1.  ; get one visit
  1.  I $G(ID) D EN1(ID,.NHITM),XML(.NHITM) Q
  1.  ;
  1.  ; -- get all visits
  1.  I END,END'["." S END=END_".24" ;assume end of day
  1.  S NHICNT=0
  1.  ;F  S IDX=$Q(@IDX,-1) Q:DFN'=$P(IDX,",",2)  Q:$P(IDX,",",3)<BEG  I $P(IDX,",",5)["P" D
  1.  S NHDT=END F  S NHDT=$O(^AUPNVSIT("AET",DFN,NHDT),-1)  Q:NHDT<BEG  D  Q:NHICNT'<MAX
  1.  . S NHLOC=0 F  S NHLOC=$O(^AUPNVSIT("AET",DFN,NHDT,NHLOC)) Q:NHLOC<1  D
  1.  .. S NHDA=0 F  S NHDA=$O(^AUPNVSIT("AET",DFN,NHDT,NHLOC,"P",NHDA)) Q:NHDA<1  D
  1.  ... K NHITM D EN1(NHDA,.NHITM) Q:'$D(NHITM)
  1.  ... D XML(.NHITM) S NHICNT=NHICNT+1
  1.  Q
  1.  ;
  1. ENAA(DFN,BEG,END,MAX,ID) ; -- find patient's visits and appointments [AA]
  1.  N IDT,DA,NHICNT,NHITM
  1.  S DFN=+$G(DFN) Q:DFN<1
  1.  S BEG=$G(BEG,1410101),END=$G(END,9999998),MAX=$G(MAX,999999)
  1.  I $G(ID) D EN1(ID,.NHITM),XML(.NHITM) Q  ;one visit
  1.  D IDT S NHICNT=0
  1.  S IDT=BEG F  S IDT=$O(^AUPNVSIT("AA",DFN,IDT)) Q:IDT<1!(IDT>END)  D  Q:NHICNT'<MAX
  1.  . S DA=0 F  S DA=$O(^AUPNVSIT("AA",DFN,IDT,DA)) Q:DA<1  D
  1.  .. K NHITM D EN1(DA,.NHITM) Q:'$D(NHITM)
  1.  .. D XML(.NHITM) S NHICNT=NHICNT+1
  1.  Q
  1. IDT ; -- invert BEG and END dates for visit format:
  1.  ;  IDT=(9999999-$P(VDT,"."))_"."_$P(VDT,".",2)
  1.  N X S X=BEG
  1.  S BEG=(9999999-$P(END,"."))
  1.  S END=(9999999-$P(X,"."))_".2359"
  1.  Q
  1.  ;
  1. EN1(IEN,VST) ; -- return a visit in VST("attribute")=value
  1.  N X0,X15,X,FAC,LOC,CATG,INPT,DA
  1.  S IEN=+$G(IEN) Q:IEN<1  ;invalid ien
  1.  D ENCEVENT^PXAPI(IEN)
  1.  S X0=$G(^TMP("PXKENC",$J,IEN,"VST",IEN,0)),X15=$G(^(150))
  1.  Q:$P(X15,U,3)'="P"  Q:$P(X0,U,7)="E"  ;want primary, not historical
  1.  I $P(X0,U,7)="H" D ADM(IEN,+X0,.VST) Q
  1.  S VST("id")=IEN,VST("dateTime")=+X0
  1.  S FAC=+$P(X0,U,6),CATG=$P(X0,U,7),LOC=+$P(X0,U,22)
  1.  S:FAC VST("facility")=$$STA^XUAF4(FAC)_U_$P($$NS^XUAF4(FAC),U)
  1.  S VST("serviceCategory")=CATG_U_$$CATG(CATG)
  1.  S VST("visitString")=LOC_";"_+X0_";"_CATG
  1.  S INPT=$P(X15,U,2) S:INPT="" INPT=$S("H^I^R^D"[CATG:1,1:0)
  1.  S X=$$CPT(IEN) S:X VST("type")=$P($$CPT^ICPTCOD(X),U,2,3)
  1.  I 'X S VST("type")=U_$S('INPT&LOC:$P($G(^SC(LOC,0)),U)_" VISIT",1:$$CATG(CATG))
  1.  S VST("patientClass")=$S(INPT:"IMP",1:"AMB")
  1.  S X=$P(X0,U,8) S:X VST("stopCode")=$$AMIS(X) I LOC D
  1.  . N L0 S L0=$G(^SC(LOC,0))
  1.  . I 'X S VST("stopCode")=$$AMIS($P(L0,U,7))
  1.  . S VST("location")=$P(L0,U),VST("service")=$$SERV($P(L0,U,20))
  1.  . S X=$P(L0,U,18) S:X VST("creditStopCode")=$$AMIS(X)
  1.  . S:'FAC VST("facility")=$$FAC^NHINV(LOC)
  1.  S VST("reason")=$$POV(IEN)
  1.  ; provider(s)
  1.  S DA=0 F  S DA=$O(^TMP("PXKENC",$J,IEN,"PRV",DA)) Q:DA<1  S X0=$G(^(DA,0)) D
  1.  . S VST("provider",DA)=+X0_U_$P($G(^VA(200,+X0,0)),U)_$S($P(X0,U,4)="P":"^P^1",1:"^S^")
  1.  ; note(s)
  1.  D TIU(IEN)
  1.  K ^TMP("PXKENC",$J,IEN)
  1.  Q
  1.  ;
  1. TIU(VISIT) ; -- add notes to VST("document")
  1.  N X,Y,I,NHIN,LT,NT,DA,CNT
  1.  D FIND^DIC(8925,,.01,"QX",+$G(VISIT),,"V",,,"NHIN")
  1.  S Y="",(I,CNT)=0
  1.  F  S I=$O(NHIN("DILIST",1,I)) Q:I<1  D
  1.  . S LT=$G(NHIN("DILIST","ID",I,.01)) Q:$P(LT," ")="Addendum"
  1.  . S DA=$G(NHIN("DILIST",2,I))
  1.  . S NT=$$GET1^DIQ(8925,+DA_",",".01:1501")
  1.  . S CNT=CNT+1,VST("document",CNT)=DA_U_LT_U_NT
  1.  Q
  1.  ;
  1. POV(VISIT) ; -- return the primary Purpose of Visit as ICD^ProviderNarrative
  1.  N DA,Y,X,X0,ICD S Y=""
  1.  S DA=0 F  S DA=$O(^TMP("PXKENC",$J,VISIT,"POV",DA)) Q:DA<1  S X0=$G(^(DA,0)) I $P(X0,U,12)="P" D  Q:$L(Y)
  1.  . S X=+$P(X0,U,4),ICD=$$ICD(+X0)
  1.  . S Y=ICD_U_$$GET1^DIQ(9999999.27,X_",",.01)
  1.  Q Y
  1.  ;
  1. ICD(IEN) ; -- return code^description for ICD code, or "^" if error
  1.  N X0,NHX,N,I,X,Y S IEN=+$G(IEN)
  1.  S X0=$$ICDDX^ICDCODE(IEN) I X0<0 Q "^"
  1.  S Y=$P(X0,U,2)_U_$P(X0,U,4)       ;ICD Code^Dx name
  1.  S N=$$ICDD^ICDCODE($P(Y,U),"NHX") ;ICD Description
  1.  I N>0,$L($G(NHX(1))) S $P(Y,U,2)=NHX(1)
  1.  Q Y
  1.  ;
  1. CPT(VISIT) ; -- Return CPT code of encounter type
  1.  N DA,Y,X,X0 S Y=""
  1.  S DA=0 F  S DA=$O(^TMP("PXKENC",$J,VISIT,"CPT",DA)) Q:DA<1  S X0=$G(^(DA,0)) D  Q:$L(Y)
  1.  . S X=$P(X0,U) I X?1"992"2N S Y=X Q
  1.  Q Y
  1.  ;
  1. AMIS(X) ; -- return the AMIS code^name of Credit Stop X
  1.  N Y S Y=""
  1.  S X0=$G(^DIC(40.7,+$G(X),0)) S:$L(X0) Y=$P(X0,U,2)_U_$P(X0,U)
  1.  Q Y
  1.  ;
  1. CATG(X) ; -- Return name of visit Service Category code X
  1.  N Y S Y=""
  1.  I X="A" S Y="AMBULATORY"
  1.  I X="H" S Y="HOSPITALIZATION"
  1.  I X="I" S Y="IN HOSPITAL"
  1.  I X="C" S Y="CHART REVIEW"
  1.  I X="T" S Y="TELECOMMUNICATIONS"
  1.  I X="N" S Y="NOT FOUND"
  1.  I X="S" S Y="DAY SURGERY"
  1.  I X="O" S Y="OBSERVATION"
  1.  I X="E" S Y="EVENT (HISTORICAL)"
  1.  I X="R" S Y="NURSING HOME"
  1.  I X="D" S Y="DAILY HOSPITALIZATION DATA"
  1.  I X="X" S Y="ANCILLARY PACKAGE DAILY DATA"
  1.  Q Y
  1.  ;
  1. SERV(FTS) ; -- Return #42.4 Service for a Facility Treating Specialty
  1.  N Y S Y="",FTS=+$G(FTS)
  1.  S Y=$$GET1^DIQ(45.7,FTS_",","1:3","E")
  1.  Q Y
  1.  ;
  1. ADM(IEN,DATE,ADM) ; -- return an admission in ADM("attribute")=value
  1.  N VAIP,VAERR,HLOC,ICD,I K ADM
  1.  S IEN=+$G(IEN),DATE=+$G(DATE) Q:IEN<1  Q:DATE<1  ;invalid
  1.  S VAIP("D")=DATE D IN5^VADPT Q:'$G(VAIP(1))  ;deleted
  1.  S ADM("id")=IEN,ADM("patientClass")="IMP"
  1.  ; ADM("admitType")=$P($G(VAIP(4)),U,2)
  1.  S DATE=+$G(VAIP(3)),(ADM("dateTime"),ADM("arrivalDateTime"))=DATE,I=0
  1.  S:$G(VAIP(7)) I=I+1,ADM("provider",I)=VAIP(7)_"^P^1" ;primary
  1.  S:$G(VAIP(18)) I=I+1,ADM("provider",I)=VAIP(18)_"^A" ;attending
  1.  S ADM("specialty")=$P($G(VAIP(8)),U,2)
  1.  S X=$$SERV(+$G(VAIP(8))),ADM("service")=X
  1.  S X=$$POV(IEN) S:X ADM("reason")=X_U_$G(VAIP(9)) I 'X D
  1.  . S X=$$GET1^DIQ(405,+VAIP(1)_",",".16:79","I") ;Mvt>PTF>ICD ien
  1.  . I 'X S ADM("reason")=U_U_$G(VAIP(9)) Q  ;Dx text
  1.  . S ICD=$$ICD(X),ADM("reason")=ICD_U_$G(VAIP(9))
  1.  S HLOC=+$G(^DIC(42,+$G(VAIP(5)),44))
  1.  S:HLOC ADM("location")=$P($G(^SC(HLOC,0)),U)
  1.  S ADM("facility")=$$FAC^NHINV(+HLOC),ADM("roomBed")=$P(VAIP(6),U,2)
  1.  S ADM("serviceCategory")="H^HOSPITALIZATION"
  1.  S X=$$CPT(IEN),ADM("type")=$S(X:$P($$CPT^ICPTCOD(X),U,2,3),1:U_$$CATG("H"))
  1.  I $G(VAIP(17)) D
  1.  . S ADM("departureDateTime")=+$G(VAIP(17,1))
  1.  . ; ADM("disposition")=$G(VAIP(17,3)) ;Discharge Mvt Type
  1.  S ADM("visitString")=HLOC_";"_DATE_";H"
  1.  Q
  1.  ;
  1. ENC(IEN,ENC) ; -- return an encounter in ENC("attribute")=value
  1.  N X0,DATE,HLOC,TYPE,STS,X,Y K ENC
  1.  S IEN=+$G(IEN) Q:IEN<1  ;invalid ien
  1.  S ENC("id")="E"_IEN,X0=$G(^SCE(IEN,0))
  1.  S DATE=+X0,ENC("dateTime")=DATE
  1.  S HLOC=+$P(X0,U,4) I HLOC D
  1.  . S HLOC=HLOC_U_$P($G(^SC(HLOC,0)),U)
  1.  . S ENC("location")=$P(HLOC,U,2)
  1.  . S X=$$GET1^DIQ(44,+HLOC_",",9.5,"I")
  1.  . I X S ENC("service")=$$SERV(X)
  1.  S ENC("facility")=$$FAC^NHINV(+HLOC)
  1.  S STS=$$GET1^DIQ(409.68,IEN_",",.12,"E")
  1.  S X=$S(STS?1"INP".E:"IMP",1:"AMB"),ENC("patientClass")=X,TYPE=$E(X)
  1.  S ENC("type")=U_$S(HLOC:$P(HLOC,U,2)_" VISIT",1:$$CATG(TYPE))
  1.  S ENC("serviceCategory")=TYPE_U_$$CATG(TYPE)
  1.  S ENC("visitString")=+HLOC_";"_DATE_";"_TYPE
  1.  Q
  1.  ;
  1.  ; ------------ Return data to middle tier ------------
  1.  ;
  1. XML(VISIT) ; -- Return patient visit as XML
  1.  N ATT,X,Y,NAMES
  1.  D ADD("<visit>") S NHINTOTL=$G(NHINTOTL)+1
  1.  S ATT="" F  S ATT=$O(VISIT(ATT)) Q:ATT=""  D  D:$L(Y) ADD(Y)
  1.  . I $O(VISIT(ATT,0)) D  S Y="" Q  ;multiples
  1.  .. D ADD("<"_ATT_"s>")
  1.  .. S I=0 F  S I=$O(VISIT(ATT,I)) Q:I<1  D
  1.  ... S X=$G(VISIT(ATT,I)),NAMES=""
  1.  ... I ATT="document" S NAMES="id^localTitle^nationalTitle^Z"
  1.  ... I ATT="provider" S NAMES="code^name^role^primary^Z"
  1.  ... S Y="<"_ATT_" "_$$LOOP_"/>" D ADD(Y)
  1.  .. D ADD("</"_ATT_"s>")
  1.  . S X=$G(VISIT(ATT)),Y="" Q:'$L(X)
  1.  . S NAMES="code^name^"_$S(ATT="reason":"narrative^",1:"")_"Z"
  1.  . I X'["^" S Y="<"_ATT_" value='"_$$ESC^NHINV(X)_"' />" Q
  1.  . I $L(X)>1 S Y="<"_ATT_" "_$$LOOP_"/>"
  1.  D ADD("</visit>")
  1.  Q
  1.  ;
  1. LOOP() ; -- build sub-items string from NAMES and X
  1.  N STR,P,TAG S STR=""
  1.  F P=1:1 S TAG=$P(NAMES,U,P) Q:TAG="Z"  I $L($P(X,U,P)) S STR=STR_TAG_"='"_$$ESC^NHINV($P(X,U,P))_"' "
  1.  Q STR
  1.  ;
  1. ADD(X) ; -- Add a line @NHIN@(n)=X
  1.  S NHINI=$G(NHINI)+1
  1.  S @NHIN@(NHINI)=X
  1.  Q