Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ORLA1

ORLA1.m

Go to the documentation of this file.
  1. ORLA1 ; slc/dcm,cla - Order activity alerts ;3/10/05 15:10
  1. ;;3.0;ORDER ENTRY/RESULTS REPORTING;**11,82,215**;Dec 17, 1997
  1. ;
  1. ; DBIA 3869 GETPLIST^SDAMA202 ^TMP($J,"SDAMA202")
  1. ;
  1. BUILD ;
  1. D PARAM^ORU1
  1. K:$D(ORDEF) ^XUTL("OR",$J,"ORLP"),^("ORW"),^("ORU"),^("ORV")
  1. B1 ;
  1. D PREF
  1. I $D(ORDEF),ORDEF="P"!(ORDEF="T"),$D(^OR(100.21,+$G(ORPRIM),0)) S X=$P(^(0),"^")_" patient list",ORY=ORPRIM_"^"_$P(^(0),"^"),ORTITLE=$S($D(^XUTL("OR",$J,"ORLP",0)):$S('$P(^(0),"^",2):"PATIENT LIST",1:X),1:X),ORCOLW=40-($L(ORTITLE)\2) D P1 Q
  1. I $D(ORDEF),ORDEF="W",ORWARD,$D(^DIC(42,ORWARD,0)) S X=$P(^(0),"^")_" ward list",ORY=ORWARD_"^"_$P(^(0),"^"),ORTITLE=$S($D(^XUTL("OR",$J,"ORLP",0)):$S('$P(^(0),"^",2):"PATIENT LIST",1:X),1:X),ORCOLW=40-($L(ORTITLE)\2) D W1 Q
  1. I $D(ORDEF),ORDEF="C",ORCLIN,$D(^SC(ORCLIN,0)) S X=$P(^(0),"^")_" clinic list",ORY=ORCLIN_"^"_$P(^(0),"^"),ORTITLE=$S($D(^XUTL("OR",$J,"ORLP",0)):$S('$P(^(0),"^",2):"PATIENT LIST",1:X),1:X),ORCOLW=40-($L(ORTITLE)\2) D C0 Q
  1. I $D(ORDEF),ORDEF="V",ORPROV,$D(^VA(200,ORPROV,0)) S X=$P(^(0),"^")_" patient list",ORY=ORPROV_"^"_$P(^(0),"^"),ORTITLE=$S($D(^XUTL("OR",$J,"ORLP",0)):$S('$P(^(0),"^",2):"PATIENT LIST",1:X),1:X),ORCOLW=40-($L(ORTITLE)\2) D V1^ORLA11 Q
  1. I $D(ORDEF),ORDEF="S",ORSPEC,$D(^DIC(45.7,ORSPEC,0)) S X=$P(^(0),"^")_" specialty list",ORY=ORSPEC_"^"_$P(^(0),"^"),ORTITLE=$S($D(^XUTL("OR",$J,"ORLP",0)):$S('$P(^(0),"^",2):"PATIENT LIST",1:X),1:X),ORCOLW=40-($L(ORTITLE)\2) D S1^ORLA11 Q
  1. Q
  1. P1 ; Loading the Primary Patient List
  1. S (ORCNT,J)=0
  1. F S J=$O(^OR(100.21,+ORY,10,J)) Q:J<1 S ORX=^(J,0),ORVP=$P(ORX,"^") D PR1(ORVP,OROPREF)
  1. D PR2(OROPREF,ORTITLE,ORDEF)
  1. K ORI,ORJ,ORURMBD,ORUVP,ORVP,ORX,ORY
  1. Q
  1. W1 ;
  1. W !,"Loading Ward Patient List..."
  1. S (ORCNT,ORJ)=0
  1. F S ORJ=$O(^DPT("CN",$P(ORY,"^",2),ORJ)) Q:ORJ<1 S ORX="",ORVP=ORJ_";DPT(" D PR1(ORVP,OROPREF)
  1. D PR2(OROPREF,ORTITLE,ORDEF)
  1. K ORI,ORJ,ORURMBD,ORUVP,ORVP,ORX,ORY
  1. Q
  1. C0 ; DBIA 3869
  1. ; SLC/PKS - 5/15/2000: Next line added to fix a reported problem:
  1. N %DT,ORI,ORERR
  1. W:$L(ORCSTRT) !,"Starting date: "
  1. S %DT=$S($L(ORCSTRT):"E",1:"AE"),X=$S($L(ORCSTRT):ORCSTRT,1:"")
  1. S:'$L(ORCSTRT) %DT("A")="Patient Appointment STARTING DATE: ",%DT("B")="T"
  1. D ^%DT
  1. I Y<0 S OREND=1 Q
  1. S ORCSTRT=Y
  1. D DD^%DT
  1. W:$L(ORCEND) !,"Ending date: "
  1. S %DT=$S($L(ORCEND):"E",1:"AE"),X=$S($L(ORCEND):ORCEND,1:"")
  1. S:'$L(ORCEND) %DT("A")="Patient Appointment ENDING DATE: ",%DT("B")=Y
  1. D ^%DT
  1. I Y<0 S OREND=1 Q
  1. S ORCEND=$P(Y,".")_.5
  1. I ORCEND<ORCSTRT S ORCTMP=ORCEND,ORCEND=ORCSTRT,ORCSTRT=ORCTMP K ORCTMP
  1. W !,"Loading Clinic Patient List..."
  1. K ^TMP($J,"SDAMA202","GETPLIST")
  1. S ORCNT=0
  1. D GETPLIST^SDAMA202(+ORCLIN,"1;4","",ORCSTRT,ORCEND) ;DBIA 3869
  1. S ORERR=$$CLINERR^ORQRY01
  1. I $L(ORERR) W !,ORERR Q
  1. S ORI=0
  1. F S ORI=$O(^TMP($J,"SDAMA202","GETPLIST",ORI)) Q:ORI<1 D ;DBIA 3869
  1. . S ORCLDT=+$G(^TMP($J,"SDAMA202","GETPLIST",ORI,1))
  1. . S DFN=+$G(^TMP($J,"SDAMA202","GETPLIST",ORI,4))
  1. . I DFN,ORCLDT S ORX="" D C1
  1. K ORCLDT,ORI,ORURMBD,ORUVP,ORVP,ORX,ORY
  1. K ^TMP($J,"SDAMA202","GETPLIST")
  1. I '$L($O(^XUTL("OR",$J,"ORLP",0))) W $C(7),!,"No patients found" D READ^ORUTL Q
  1. H 1
  1. Q
  1. END ;
  1. G END^ORLA11
  1. Q
  1. C1 ;
  1. S ORVP=DFN_";DPT("
  1. D PR1(ORVP,OROPREF,ORCLDT)
  1. I '$D(^XUTL("OR",$J,"ORLP",ORUVP)),$D(^DPT(DFN,0)) S ORCNT=ORCNT+1,ORUPNM=$P(^(0),"^"),ORUSSN=$P(^(0),"^",9) S ^XUTL("OR",$J,"ORLP",ORUVP,0)=ORUPNM_"^"_ORUSSN_"^"_ORVP
  1. D PR2(OROPREF,ORTITLE,ORDEF)
  1. Q
  1. PR1(ORVP,OROPREF,ORCLDT) ;from ORLA11
  1. Q:'$G(ORVP)
  1. I '$D(^DPT(+ORVP)) W !,"Data inconsistency found, no entry for DFN="_+ORVP Q
  1. S ORUVP=+ORVP
  1. Q:$D(^XUTL("OR",$J,"ORLP",ORUVP))
  1. N DFN,RB,VAIN,VADM,X
  1. S ORCNT=ORCNT+1
  1. S DFN=ORUVP,X=$G(^DPT(ORUVP,0)),ORUPNM=$P(X,U),ORUSSN=$P(X,U,9)
  1. D INP^VADPT
  1. S ORURMBD=VAIN(5)
  1. I ORURMBD']"" S ORURMBD="~"
  1. S ORUPNM=$S($L(ORUPNM)'>15:ORUPNM,1:$$NAME^ORU(ORUPNM,"LAST, FI MI"))
  1. S:$L(ORUPNM)<16 ORUPNM=ORUPNM_$E(" ",$L(ORUPNM),16)
  1. S RB=ORURMBD,ORURMBD=ORURMBD_$E(" ",$L(ORURMBD),8)
  1. S ^XUTL("OR",$J,"ORLP",ORUVP,0)=ORUPNM_"^"_ORUSSN_"^"_ORVP_"^"_$P(ORX,"^",2)_"^"_ORURMBD
  1. I $D(ORCLDT),ORCLDT S X=ORCLDT D LTIM S ^(0)=^(0)_"^"_X
  1. S ^XUTL("OR",$J,"ORLP","B",ORUPNM,ORUVP)=""
  1. S:$D(ORCT) ORCT=ORCT+1
  1. D KVAR^VADPT
  1. ; terminal digit x-ref
  1. I OROPREF="T" S S=ORUSSN,S="A"_$E(S,8,9)_$E(S,6,7)_$E(S,1,5)_$E(S,10,11),^XUTL("OR",$J,"ORLP","C",S,ORUVP)="" K S Q
  1. ; room bed x-ref
  1. I OROPREF="R" S ^XUTL("OR",$J,"ORLP","D",RB,ORUVP)="" Q
  1. ; clinic date x-ref
  1. I $G(ORCLDT) S ^XUTL("OR",$J,"ORLP","D",ORCLDT,ORUVP)=""
  1. Q
  1. PR2(OROPREF,ORTITLE,ORDEF) ;
  1. S:$L($O(^XUTL("OR",$J,"ORLP",0))) ^(0)=$S($L($G(ORTITLE)):ORTITLE,1:"Current PATIENT List")_"^1^"_$S(OROPREF="T":"C",OROPREF="R":"D",OROPREF="C"&($G(ORDEF)="C"):"D",1:"B")_"^"_ORCNT
  1. Q
  1. LTIM ;
  1. Q:'$L(X)
  1. S X=$E(X,4,5)_"/"_$E(X,6,7)_"/"_$E(X,2,3)_$S(X[".":" "_$E(X_"0",9,10)_":"_$E(X_"000",11,12),1:"")
  1. Q
  1. KIL ;
  1. Q:'$D(^XUTL("OR",$J,"ORLP"))
  1. W !,"The current patient list will be cleared."
  1. K ^XUTL("OR",$J,"ORLP"),^("ORV"),^("ORU"),^("ORW")
  1. Q
  1. PREF ;Get a preference
  1. N ORSRV
  1. S ORSRV=$P($G(^VA(200,DUZ,5)),"^"),OROPREF=$$GET^XPAR("USR^SRV.`"_$G(ORSRV)_"^DIV^SYS^PKG","ORLP DEFAULT LIST ORDER",1,"I")
  1. Q