PSDRFD.m

PSDRFD ;BIR/JPW,LTL-Nurse RF Dispensing ; 8 Aug 94

 ;;3.0; CONTROLLED SUBSTANCES ;;13 Feb 97

 I '$D(PSDSITE) D ^PSDSET Q:'$D(PSDSITE)

 ;S OK=$S($D(^XUSEC("PSJ RNURSE",DUZ)):1,1:0) I 'OK W $C(7),!!,?9,"** Please contact your Pharmacy Coordinator for access to order",!,?12,"narcotic supplies.",! K OK Q

 ;I $P($G(^VA(200,DUZ,20)),U,4)']"" N XQH S XQH="PSD ESIG" D EN^XQH G END

 S PSDUZ=DUZ,(MSG,MSG1)=0,Y=DT X ^DD("DD") S REQD=Y

NURSE ;N X,X1 D SIG^XUSESIG I X1="" G END

NAOU ;select NAOU to dispense from

 W !!,"Please enter the ward from which the drug(s) will be signed out."

 K DA,DIC S DIC=58.8,DIC(0)="QEA",DIC("A")="Select Ward: "

 S DIC("S")="I $P(^(0),""^"",3)=+PSDSITE,$S('$D(^(""I"")):1,'^(""I""):1,+^(""I"")>DT:1,1:0),$P(^(0),""^"",2)=""N"",'$P(^(0),""^"",7)"

 W ! D ^DIC K DIC G:Y<0 END S NAOU=+Y,NAOUN=$P(Y,"^",2)

 I '$D(^PSD(58.8,NAOU,0)) S MSG=1 D MSG G END

 I '$O(^PSD(58.8,NAOU,1,0)) S MSG=1,MSG1=2 D MSG G END

 I '$P(^PSD(58.8,NAOU,0),U,4) S MSG=2 D MSG G END

 S PSDS=+$P(^PSD(58.8,NAOU,0),"^",4),PSDS=PSDS_"^"_+$P(^PSD(58.8,+PSDS,0),"^",5) I '+PSDS S (MSG,MSG1)=1 D MSG G END

 I '$D(^PSD(58.8,+PSDS,0)) S MSG=2 D MSG G END

 I '$O(^PSD(58.8,+PSDS,1,0)) S MSG=2,MSG1=2 D MSG G END

 ;S TYPE=$P(^PSD(58.8,+PSDS,0),"^",2),OKTYP=$S(TYPE="M":1,TYPE="S":1,1:0) I 'OKTYP W !!,"Contact your Pharmacy Coordinator.",!,"The Pharmacy Dispensing Site is invalid for this NAOU." G END

 ;check to see if NAOU is keeping perpetual inventory

 I '$P($G(^PSD(58.8,NAOU,2)),U,5) W !!,"Sorry, Pharmacy has not set up ",$G(NAOUN)," to keep a perpetual inventory." S XQUIT=1

END W:$G(PSDOUT) !!,"No dose signed out.",$C(7),!! K %,%DT,%H,%I,CNT,CNT1,DA,DIC,DIE,DINUM,DIR,DIROUT,DIRUT,DIWF,DIWL,DIWR,DR,DTOUT,DUOUT,LN,MSG,MSG1

 K NBKU,NPKG,OK,OKTYP,ORD,PSDA,PSDEM,PSDOUT,PSDQTY,PSDRD,PSDR,PSDRN,PSDS,PSDT,PSDUZ,PSDUZN,REQD,TEXT,TYPE,WORD,X,Y

 S:'$G(NAOU) XQUIT=1 Q

MSG ;display error message

 W $C(7),!!,?10,"Contact your Pharmacy Coordinator.",!,?10,"This "_$S(MSG=2:"Dispensing Site",MSG=1:"NAOU",1:"Drug")_" is missing "

 W $S(MSG1=1:"Primary Disp. Site",MSG1=2:"stocked drugs",MSG1=3:"narcotic breakdown unit",MSG1=4:"narcotic package size",1:"data")_".",!

 S XQUIT=1 Q

--- Routine Detail   --- with STRUCTURED ROUTINE LISTING ---PSDRFD   2194     printed  Apr 09, 2024@20:49:55                                                                                                                                                                                                      Page 2

PSDRFD    ;BIR/JPW,LTL-Nurse RF Dispensing ; 8 Aug 94

 +1       ;;3.0; CONTROLLED SUBSTANCES ;;13 Feb 97

 +2        IF '$DATA(PSDSITE)

               DO ^PSDSET

               if '$DATA(PSDSITE)

                   QUIT 

 +3       ;S OK=$S($D(^XUSEC("PSJ RNURSE",DUZ)):1,1:0) I 'OK W $C(7),!!,?9,"** Please contact your Pharmacy Coordinator for access to order",!,?12,"narcotic supplies.",! K OK Q

 +4       ;I $P($G(^VA(200,DUZ,20)),U,4)']"" N XQH S XQH="PSD ESIG" D EN^XQH G END

 +5        SET PSDUZ=DUZ

           SET (MSG,MSG1)=0

           SET Y=DT

           XECUTE ^DD("DD")

           SET REQD=Y

NURSE     ;N X,X1 D SIG^XUSESIG I X1="" G END

NAOU      ;select NAOU to dispense from

 +1        WRITE !!,"Please enter the ward from which the drug(s) will be signed out."

 +2        KILL DA,DIC

           SET DIC=58.8

           SET DIC(0)="QEA"

           SET DIC("A")="Select Ward: "

 +3        SET DIC("S")="I $P(^(0),""^"",3)=+PSDSITE,$S('$D(^(""I"")):1,'^(""I""):1,+^(""I"")>DT:1,1:0),$P(^(0),""^"",2)=""N"",'$P(^(0),""^"",7)"

 +4        WRITE !

           DO ^DIC

           KILL DIC

           if Y<0

               GOTO END

           SET NAOU=+Y

           SET NAOUN=$PIECE(Y,"^",2)

 +5        IF '$DATA(^PSD(58.8,NAOU,0))

               SET MSG=1

               DO MSG

               GOTO END

 +6        IF '$ORDER(^PSD(58.8,NAOU,1,0))

               SET MSG=1

               SET MSG1=2

               DO MSG

               GOTO END

 +7        IF '$PIECE(^PSD(58.8,NAOU,0),U,4)

               SET MSG=2

               DO MSG

               GOTO END

 +8        SET PSDS=+$PIECE(^PSD(58.8,NAOU,0),"^",4)

           SET PSDS=PSDS_"^"_+$PIECE(^PSD(58.8,+PSDS,0),"^",5)

           IF '+PSDS

               SET (MSG,MSG1)=1

               DO MSG

               GOTO END

 +9        IF '$DATA(^PSD(58.8,+PSDS,0))

               SET MSG=2

               DO MSG

               GOTO END

 +10       IF '$ORDER(^PSD(58.8,+PSDS,1,0))

               SET MSG=2

               SET MSG1=2

               DO MSG

               GOTO END

 +11      ;S TYPE=$P(^PSD(58.8,+PSDS,0),"^",2),OKTYP=$S(TYPE="M":1,TYPE="S":1,1:0) I 'OKTYP W !!,"Contact your Pharmacy Coordinator.",!,"The Pharmacy Dispensing Site is invalid for this NAOU." G END

 +12      ;check to see if NAOU is keeping perpetual inventory

 +13       IF '$PIECE($GET(^PSD(58.8,NAOU,2)),U,5)

               WRITE !!,"Sorry, Pharmacy has not set up ",$GET(NAOUN)," to keep a perpetual inventory."

               SET XQUIT=1

END        if $GET(PSDOUT)

               WRITE !!,"No dose signed out.",$CHAR(7),!!

           KILL %,%DT,%H,%I,CNT,CNT1,DA,DIC,DIE,DINUM,DIR,DIROUT,DIRUT,DIWF,DIWL,DIWR,DR,DTOUT,DUOUT,LN,MSG,MSG1

 +1        KILL NBKU,NPKG,OK,OKTYP,ORD,PSDA,PSDEM,PSDOUT,PSDQTY,PSDRD,PSDR,PSDRN,PSDS,PSDT,PSDUZ,PSDUZN,REQD,TEXT,TYPE,WORD,X,Y

 +2        if '$GET(NAOU)

               SET XQUIT=1

           QUIT 

MSG       ;display error message

 +1        WRITE $CHAR(7),!!,?10,"Contact your Pharmacy Coordinator.",!,?10,"This "_$SELECT(MSG=2:"Dispensing Site",MSG=1:"NAOU",1:"Drug")_" is missing "

 +2        WRITE $SELECT(MSG1=1:"Primary Disp. Site",MSG1=2:"stocked drugs",MSG1=3:"narcotic breakdown unit",MSG1=4:"narcotic package size",1:"data")_".",!

 +3        SET XQUIT=1

           QUIT