Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: SCMCPAT

SCMCPAT.m

Go to the documentation of this file. 
  1. SCMCPAT ;ALB/ART - PCMMR-RPC to Get Patient Data ;02/05/2015
  1.  ;;5.3;Scheduling;**603**;Aug 13, 1993;Build 79
  1.  ;
  1.  QUIT
  1.  ;
  1.  ;Public, Supported ICRs
  1.  ; #2056 - Data Base Server API: Data Retriever Utilities (DIQ)
  1.  ; #2701 - MPIF001 - ICN
  1.  ; #10035 - PATIENT FILE
  1.  ; #10061 - VADPT - Patient file data
  1.  ;
  1. DIEDON(SCRET,SCDFN) ; Check for patient date of death
  1.  ;Inputs: SCRET - String for patient DoD - passed by reference
  1.  ;        SCDFN - Patient DFN
  1.  ;Output: populated SCRET
  1.  ; #2056 - Data Base Server API: Data Retriever Utilities (DIQ)
  1.  ;
  1.  IF $GET(SCDFN)="" DO  QUIT
  1.  . SET SCRET="-1^Missing DFN parameter."
  1.  IF $$GET1^DIQ(2,SCDFN_",",.01)="" DO  QUIT
  1.  . SET SCRET="-1^Patient was not found."
  1.  SET SCRET=+$$GET1^DIQ(2,SCDFN_",",.351,"I")
  1.  QUIT
  1.  ;
  1. PATIENT(SCRET,SCDFN) ; Patient Information
  1.  ;Inputs: SCRET - String for patient Data - passed by reference
  1.  ;        SCDFN - Patient DFN
  1.  ;Output: populated SCRET
  1.  ; 1      2         3   4   5   6      7             8          9        10       11      12   13   14    15      16       17       18
  1.  ;DFN^PATIENT NAME^SSN^DOB^AGE^SEX^MARITAL STATUS^ACTIVE DUTY^ADDRESS1^ADDRESS2^ADDRESS3^CITY^STATE^ZIP^COUNTY^TELEPHONE^SENSITIVE^ICN
  1.  ;
  1.  ; #10061 - VADPT - Patient file data
  1.  ; #2701 - MPIF001 - ICN
  1.  ;
  1.  IF $GET(SCDFN)="" DO  QUIT
  1.  . SET SCRET="-1^Missing DFN parameter"
  1.  IF $$GET1^DIQ(2,SCDFN_",",.01)="" DO  QUIT
  1.  . SET SCRET="-1^Patient was not found."
  1.  SET SCRET="-1^Error retrieving patient data"
  1.  ;
  1.  NEW DFN,I,VA,VADM,VAEL,VAERR,VAPA,SCTMP,SCPAT,SCICN
  1.  SET DFN=SCDFN
  1.  DO DEM^VADPT QUIT:VAERR
  1.  DO ADD^VADPT QUIT:VAERR
  1.  DO ELIG^VADPT QUIT:VAERR
  1.  MERGE SCTMP=VADM
  1.  SET SCTMP(10)=$PIECE(SCTMP(10),U,2)
  1.  SET SCPAT=SCDFN
  1.  FOR I=1,2,3,4,5,10 SET SCPAT=SCPAT_U_$PIECE(SCTMP(I),U)
  1.  SET SCPAT=SCPAT_U_$SELECT($PIECE(VAEL(6),U,2)="ACTIVE DUTY":"A",1:"N")
  1.  NEW SCTMP
  1.  MERGE SCTMP=VAPA
  1.  FOR I=5,7 SET SCTMP(I)=$PIECE(SCTMP(I),U,2)
  1.  FOR I=1,2,3,4,5,6,7,8 SET SCPAT=SCPAT_U_$PIECE(SCTMP(I),U)
  1.  SET SCPAT=SCPAT_U_$$SENSITIV(SCDFN)
  1.  SET SCICN=+$$GETICN^MPIF001(SCDFN)
  1.  SET SCPAT=SCPAT_U_$SELECT(SCICN>0:SCICN,1:"")
  1.  SET SCRET=SCPAT
  1.  QUIT
  1.  ;
  1. SENSITIV(SCDFN) ; Sensitive Patient record check
  1.  ;Input: SCDFN = Pointer to the Patient file (#2)
  1.  ;Returns:
  1.  ;   0 - Patient record IS NOT sensitive
  1.  ;   1 - Patient record IS sensitive
  1.  ; #2056 - Data Base Server API: Data Retriever Utilities (DIQ)
  1.  ;
  1.  QUIT ''$$GET1^DIQ(38.1,+$GET(SCDFN),2,"I")
  1.  ;
  1. MAKEOUT(SCRET,SCDFN,SCASSIGN) ;create/update an outpatient profile entry
  1.  ;Called by RPC - ?????????????????????????
  1.  ;Input: SCRET    - return code - passed by reference
  1.  ;       SCDFN    - patient DFN
  1.  ;       SCASSIGN - assignment type
  1.  ;Output: populated SCRET
  1.  ;
  1.  IF $GET(SCDFN)="" DO  QUIT
  1.  . SET SCRET="-1^Missing DFN parameter."
  1.  IF $GET(SCASSIGN)="" DO  QUIT
  1.  . SET SCRET="-1^Missing assignment type parameter."
  1.  ;
  1.  NEW SCX,SCOUTFLD,SCBADOUT
  1.  SET SCOUTFLD(.04)=$SELECT(SCASSIGN=1:"Y",SCASSIGN=98:"Y",SCASSIGN=99:"N",1:"N")
  1.  SET SCRET=$$ACOUTPT^SCAPMC20(SCDFN,"SCOUTFLD","SCBADOUT")
  1.  QUIT
  1.  ;