SDESPROVSEARCH ;BAYPINES/KML,MGD,JAS,LAB - Get Provider based on Search String ;Apr 17, 2025
;;5.3;Scheduling;**819,826,877,906**;Aug 13, 1993;Build 5
;;Per VHA Directive 6402, this routine should not be modified
;
;External References
;-------------------
; Reference to $$ACTIVPRV^PXAPI is supported by IA #2349
; Reference to $$ACTIVE^XUSER is supported by IA #2343
Q
; rpc = SDES SEARCH PROVIDERS
; rewrote much of the RPC logic to loop through DUZ only once and to remove extra function calls.
; removed the $$FIND with the "B" cross reference loop as the $$FIND was increasing response times dramatically
PROVIDERSEARCH(JSONRETURN,SEARCHSTRING) ;Search for Healthcare Providers and provide return of providers in JSON STRING
;INPUT - SEARCHSTRING = free text string that represents the provider name that will be searched
;OUTPUT - JSONRETURN
; List of Providers from NEW PERSON (#200) File.
; Field List:
; (1) Provider Name
; (2) Provider IEN
; (3) Office Phone
; (4) Email Address
; (5) Title
; (6) Provider Class
; (7) Security ID (SECID)
; (8) Fax
; (9) Home Phone
; (10) Commercial Phone
; (11) Digital Pager
; (12) Voice Pager
; (13) Person Class
; (14) Provider Class
; (15) User Class
;
;
N USERLIST,ERROREXISTS,ERRORS,PROVIDERETURN,PROVIDERLIST
K JSONRETURN
S SEARCHSTRING=$G(SEARCHSTRING)
S SEARCHSTRING=$TR(SEARCHSTRING,$C(13)_$C(10)_$C(9),"")
D VALIDATE(.ERRORS,SEARCHSTRING)
I $D(ERRORS) S ERRORS("Provider",1)="" D BUILDJSON^SDES2JSON(.JSONRETURN,.ERRORS) Q
D NEWPROVLIST(SEARCHSTRING,.PROVIDERLIST)
D BUILDRETURN(.PROVIDERLIST,.PROVIDERETURN)
D BUILDJSON^SDESBUILDJSON(.JSONRETURN,.PROVIDERETURN)
Q
;
VALIDATE(ERRORS,SEARCHSTRING) ; validate incoming parameters
; input - ERRORS = passed in by reference, represents the errors that could be generated when validating the searchstring
; SEARCHSTRING = represents the name or partial name of the provider
; returns 0 or 1
; 0 = no validation errors
; 1 = validation errors
I ($L(SEARCHSTRING)<3)!($L(SEARCHSTRING)>35) D Q 1
. D ERRLOG^SDESJSON(.ERRORS,230)
Q
;
BUILDRETURN(PROVIDERLIST,PROVIDERETURN) ;Build return array with provider data
; input - PROVIDERLIST = array of active providers
; PROVIDERETURN = passed by reference, represents the array of providers and associated data that will be returned to the client
; output - PROVIDERETURN = provider array and their associated data to be sent back to the client
;
N PROVIDERDATA,IEN,IENS,RECORDNUMBER,INFO
K INFO
S (RECORDNUMBER,IEN)=0
F S IEN=$O(PROVIDERLIST(IEN)) Q:'IEN D GETS^DIQ(200,IEN_",",".01;.131:.138;.151;8;53.5;205.1","IE","INFO") D
. S RECORDNUMBER=RECORDNUMBER+1
. S PROVIDERETURN("Provider",RECORDNUMBER,"IEN")=IEN
. S PROVIDERETURN("Provider",RECORDNUMBER,"Name")=INFO(200,IEN_",",.01,"E")
. S PROVIDERETURN("Provider",RECORDNUMBER,"Homephone")=INFO(200,IEN_",",.131,"E")
. S PROVIDERETURN("Provider",RECORDNUMBER,"Officephone")=INFO(200,IEN_",",.132,"E")
. S PROVIDERETURN("Provider",RECORDNUMBER,"Phone3")=INFO(200,IEN_",",.133,"E")
. S PROVIDERETURN("Provider",RECORDNUMBER,"Phone4")=INFO(200,IEN_",",.134,"E")
. S PROVIDERETURN("Provider",RECORDNUMBER,"CommercialPhone")=INFO(200,IEN_",",.135,"E")
. S PROVIDERETURN("Provider",RECORDNUMBER,"Fax")=INFO(200,IEN_",",.136,"E")
. S PROVIDERETURN("Provider",RECORDNUMBER,"VoicePager")=INFO(200,IEN_",",.137,"E")
. S PROVIDERETURN("Provider",RECORDNUMBER,"DigitalPager")=INFO(200,IEN_",",.138,"E")
. S PROVIDERETURN("Provider",RECORDNUMBER,"Email")=INFO(200,IEN_",",.151,"E")
. S PROVIDERETURN("Provider",RECORDNUMBER,"Title")=INFO(200,IEN_",",8,"E")
. S PROVIDERETURN("Provider",RECORDNUMBER,"ProviderClass")=INFO(200,IEN_",",53.5,"E")
. S PROVIDERETURN("Provider",RECORDNUMBER,"ProviderSecID")=INFO(200,IEN_",",205.1,"E")
. S PROVIDERETURN("Provider",RECORDNUMBER,"PersonClass",1)=""
. S PROVIDERETURN("Provider",RECORDNUMBER,"UserClass",1)=""
. S IENS=0 F S IENS=$O(^VA(200,IEN,"USC1",IENS)) Q:'IENS D
. . S PROVIDERETURN("Provider",RECORDNUMBER,"PersonClass",IENS)=$$GET1^DIQ(200.05,IENS_","_IEN_",",.01)
. S IENS=0 F S IENS=$O(^VA(200,IEN,"USC3",IENS)) Q:'IENS D
. . S PROVIDERETURN("Provider",RECORDNUMBER,"UserClass",IENS)=$$GET1^DIQ(200.07,IENS_","_IEN_",",.01)
I '$D(PROVIDERETURN("Provider")) S PROVIDERETURN("Provider",1)=""
Q
;
NEWPROVLIST(SEARCHSTRING,PROVIDERLIST) ;Loop through "B" cross reference for providers
N USERDUZ,PROVIDERNAME,STRINGLENGTH,DATE
S USERDUZ=""
S DATE=$P(DT,".")
S STRINGLENGTH=$L(SEARCHSTRING)
S PROVIDERNAME=$O(^VA(200,"B",SEARCHSTRING),-1)
I $E(PROVIDERNAME,1,STRINGLENGTH)=SEARCHSTRING D
. S PROVIDERNAME=$O(^VA(200,"B",PROVIDERNAME),-1)
F S PROVIDERNAME=$O(^VA(200,"B",PROVIDERNAME)) Q:PROVIDERNAME=""!($E(PROVIDERNAME,1,STRINGLENGTH)'=SEARCHSTRING) D
. S USERDUZ=""
. F S USERDUZ=$O(^VA(200,"B",PROVIDERNAME,USERDUZ)) Q:USERDUZ="" D
. . I $$ACTIVPRV^PXAPI(USERDUZ,DATE)&($$ACTIVE^XUSER(USERDUZ)) S PROVIDERLIST(USERDUZ)=""
Q
;
--- Routine Detail --- with STRUCTURED ROUTINE LISTING ---[H[J[2J[HSDESPROVSEARCH 5140 printed Sep 23, 2025@20:34:25 Page 2
SDESPROVSEARCH ;BAYPINES/KML,MGD,JAS,LAB - Get Provider based on Search String ;Apr 17, 2025
+1 ;;5.3;Scheduling;**819,826,877,906**;Aug 13, 1993;Build 5
+2 ;;Per VHA Directive 6402, this routine should not be modified
+3 ;
+4 ;External References
+5 ;-------------------
+6 ; Reference to $$ACTIVPRV^PXAPI is supported by IA #2349
+7 ; Reference to $$ACTIVE^XUSER is supported by IA #2343
+8 QUIT
+9 ; rpc = SDES SEARCH PROVIDERS
+10 ; rewrote much of the RPC logic to loop through DUZ only once and to remove extra function calls.
+11 ; removed the $$FIND with the "B" cross reference loop as the $$FIND was increasing response times dramatically
PROVIDERSEARCH(JSONRETURN,SEARCHSTRING) ;Search for Healthcare Providers and provide return of providers in JSON STRING
+1 ;INPUT - SEARCHSTRING = free text string that represents the provider name that will be searched
+2 ;OUTPUT - JSONRETURN
+3 ; List of Providers from NEW PERSON (#200) File.
+4 ; Field List:
+5 ; (1) Provider Name
+6 ; (2) Provider IEN
+7 ; (3) Office Phone
+8 ; (4) Email Address
+9 ; (5) Title
+10 ; (6) Provider Class
+11 ; (7) Security ID (SECID)
+12 ; (8) Fax
+13 ; (9) Home Phone
+14 ; (10) Commercial Phone
+15 ; (11) Digital Pager
+16 ; (12) Voice Pager
+17 ; (13) Person Class
+18 ; (14) Provider Class
+19 ; (15) User Class
+20 ;
+21 ;
+22 NEW USERLIST,ERROREXISTS,ERRORS,PROVIDERETURN,PROVIDERLIST
+23 KILL JSONRETURN
+24 SET SEARCHSTRING=$GET(SEARCHSTRING)
+25 SET SEARCHSTRING=$TRANSLATE(SEARCHSTRING,$CHAR(13)_$CHAR(10)_$CHAR(9),"")
+26 DO VALIDATE(.ERRORS,SEARCHSTRING)
+27 IF $DATA(ERRORS)
SET ERRORS("Provider",1)=""
DO BUILDJSON^SDES2JSON(.JSONRETURN,.ERRORS)
QUIT
+28 DO NEWPROVLIST(SEARCHSTRING,.PROVIDERLIST)
+29 DO BUILDRETURN(.PROVIDERLIST,.PROVIDERETURN)
+30 DO BUILDJSON^SDESBUILDJSON(.JSONRETURN,.PROVIDERETURN)
+31 QUIT
+32 ;
VALIDATE(ERRORS,SEARCHSTRING) ; validate incoming parameters
+1 ; input - ERRORS = passed in by reference, represents the errors that could be generated when validating the searchstring
+2 ; SEARCHSTRING = represents the name or partial name of the provider
+3 ; returns 0 or 1
+4 ; 0 = no validation errors
+5 ; 1 = validation errors
+6 IF ($LENGTH(SEARCHSTRING)<3)!($LENGTH(SEARCHSTRING)>35)
Begin DoDot:1
+7 DO ERRLOG^SDESJSON(.ERRORS,230)
End DoDot:1
QUIT 1
+8 QUIT
+9 ;
BUILDRETURN(PROVIDERLIST,PROVIDERETURN) ;Build return array with provider data
+1 ; input - PROVIDERLIST = array of active providers
+2 ; PROVIDERETURN = passed by reference, represents the array of providers and associated data that will be returned to the client
+3 ; output - PROVIDERETURN = provider array and their associated data to be sent back to the client
+4 ;
+5 NEW PROVIDERDATA,IEN,IENS,RECORDNUMBER,INFO
+6 KILL INFO
+7 SET (RECORDNUMBER,IEN)=0
+8 FOR
SET IEN=$ORDER(PROVIDERLIST(IEN))
if 'IEN
QUIT
DO GETS^DIQ(200,IEN_",",".01;.131:.138;.151;8;53.5;205.1","IE","INFO")
Begin DoDot:1
+9 SET RECORDNUMBER=RECORDNUMBER+1
+10 SET PROVIDERETURN("Provider",RECORDNUMBER,"IEN")=IEN
+11 SET PROVIDERETURN("Provider",RECORDNUMBER,"Name")=INFO(200,IEN_",",.01,"E")
+12 SET PROVIDERETURN("Provider",RECORDNUMBER,"Homephone")=INFO(200,IEN_",",.131,"E")
+13 SET PROVIDERETURN("Provider",RECORDNUMBER,"Officephone")=INFO(200,IEN_",",.132,"E")
+14 SET PROVIDERETURN("Provider",RECORDNUMBER,"Phone3")=INFO(200,IEN_",",.133,"E")
+15 SET PROVIDERETURN("Provider",RECORDNUMBER,"Phone4")=INFO(200,IEN_",",.134,"E")
+16 SET PROVIDERETURN("Provider",RECORDNUMBER,"CommercialPhone")=INFO(200,IEN_",",.135,"E")
+17 SET PROVIDERETURN("Provider",RECORDNUMBER,"Fax")=INFO(200,IEN_",",.136,"E")
+18 SET PROVIDERETURN("Provider",RECORDNUMBER,"VoicePager")=INFO(200,IEN_",",.137,"E")
+19 SET PROVIDERETURN("Provider",RECORDNUMBER,"DigitalPager")=INFO(200,IEN_",",.138,"E")
+20 SET PROVIDERETURN("Provider",RECORDNUMBER,"Email")=INFO(200,IEN_",",.151,"E")
+21 SET PROVIDERETURN("Provider",RECORDNUMBER,"Title")=INFO(200,IEN_",",8,"E")
+22 SET PROVIDERETURN("Provider",RECORDNUMBER,"ProviderClass")=INFO(200,IEN_",",53.5,"E")
+23 SET PROVIDERETURN("Provider",RECORDNUMBER,"ProviderSecID")=INFO(200,IEN_",",205.1,"E")
+24 SET PROVIDERETURN("Provider",RECORDNUMBER,"PersonClass",1)=""
+25 SET PROVIDERETURN("Provider",RECORDNUMBER,"UserClass",1)=""
+26 SET IENS=0
FOR
SET IENS=$ORDER(^VA(200,IEN,"USC1",IENS))
if 'IENS
QUIT
Begin DoDot:2
+27 SET PROVIDERETURN("Provider",RECORDNUMBER,"PersonClass",IENS)=$$GET1^DIQ(200.05,IENS_","_IEN_",",.01)
End DoDot:2
+28 SET IENS=0
FOR
SET IENS=$ORDER(^VA(200,IEN,"USC3",IENS))
if 'IENS
QUIT
Begin DoDot:2
+29 SET PROVIDERETURN("Provider",RECORDNUMBER,"UserClass",IENS)=$$GET1^DIQ(200.07,IENS_","_IEN_",",.01)
End DoDot:2
End DoDot:1
+30 IF '$DATA(PROVIDERETURN("Provider"))
SET PROVIDERETURN("Provider",1)=""
+31 QUIT
+32 ;
NEWPROVLIST(SEARCHSTRING,PROVIDERLIST) ;Loop through "B" cross reference for providers
+1 NEW USERDUZ,PROVIDERNAME,STRINGLENGTH,DATE
+2 SET USERDUZ=""
+3 SET DATE=$PIECE(DT,".")
+4 SET STRINGLENGTH=$LENGTH(SEARCHSTRING)
+5 SET PROVIDERNAME=$ORDER(^VA(200,"B",SEARCHSTRING),-1)
+6 IF $EXTRACT(PROVIDERNAME,1,STRINGLENGTH)=SEARCHSTRING
Begin DoDot:1
+7 SET PROVIDERNAME=$ORDER(^VA(200,"B",PROVIDERNAME),-1)
End DoDot:1
+8 FOR
SET PROVIDERNAME=$ORDER(^VA(200,"B",PROVIDERNAME))
if PROVIDERNAME=""!($EXTRACT(PROVIDERNAME,1,STRINGLENGTH)'=SEARCHSTRING)
QUIT
Begin DoDot:1
+9 SET USERDUZ=""
+10 FOR
SET USERDUZ=$ORDER(^VA(200,"B",PROVIDERNAME,USERDUZ))
if USERDUZ=""
QUIT
Begin DoDot:2
+11 IF $$ACTIVPRV^PXAPI(USERDUZ,DATE)&($$ACTIVE^XUSER(USERDUZ))
SET PROVIDERLIST(USERDUZ)=""
End DoDot:2
End DoDot:1
+12 QUIT
+13 ;
