TIUPRPN8 ;SLC/MAM - Print SF 509-Progress Notes, Cont ;11/10/04 [1/4/05 12:17pm]
;;1.0;TEXT INTEGRATION UTILITIES;**100,176,157,182,224**;Jun 20, 1997;Build 7
;
SIGBLK(TIUFOOT,TIUMISC,TIUCONT1,TIUCONT,TIUSIG,TIUROOT) ; Print signature block info
; Requires array TIUFOOT, requires TIUMISC
; Requires TIUCONT1
; Receives TIUCONT by ref (req'd)
; Receives array TIUSIG by ref, required.
; Requires TIUROOT
N TIUDA,TIUFLAG
S TIUCONT=1,TIUDA=$P(TIUMISC,U,3),TIUFLAG=$P(TIUMISC,U)
;S TIUGROOT=$NA(^TMP("TIULQ",$J,TIUDA))
; -- P182 Don't marked admin signed notes as draft:
I '+TIUSIG("SIGNDATE"),'+TIUSIG("ADMINCDT") D Q:'TIUCONT
. W "**DRAFT COPY - DRAFT COPY -- ABOVE NOTE IS UNSIGNED--"
. W " DRAFT COPY - DRAFT COPY**",!
. S TIUCONT=$$SETCONT^TIUPRPN1(.TIUFOOT,TIUMISC,TIUCONT1,0,$G(TIUROOT))
;I TIUSIG("SIGNEDBY")]"",(+TIUSIG("SIGNEDBY")'=+TIUSIG("AUTHOR")) D
;. W ?21,"Author: ",$P(TIUSIG("AUTHOR"),";",2),!
I +TIUSIG("SIGNDATE") D Q:'TIUCONT
. S TIUCONT=$$SETCONT^TIUPRPN1(.TIUFOOT,TIUMISC,TIUCONT1,0,$G(TIUROOT)) Q:'TIUCONT
. W ?18,"Signed by:",$S($P(TIUSIG("SIGNMODE"),";")="C":" /s/ ",1:" /es/ "),?34,$S(TIUSIG("SIGNNAME")]"":TIUSIG("SIGNNAME"),1:$P(TIUSIG("SIGNEDBY"),";",2))
. I $L(TIUSIG("SIGTITL"))>45 D
. . N TIUFT
. . D WRAP^TIUFLD(TIUSIG("SIGTITL"),45)
. . W !?34,$G(TIUFT(1))
. . W !?39,$G(TIUFT(2))
. I $L(TIUSIG("SIGTITL"))<46,TIUSIG("SIGTITL")]"" W !?34,TIUSIG("SIGTITL")
. W !?34,$$DATE^TIULS(+TIUSIG("SIGNDATE"),"MM/DD/CCYY HR:MIN")
. I '+$G(TIUFLAG)!($E(IOST)="C-") D
. . I $P($$BEEP^TIULC1(+TIUSIG("SIGNEDBY")),U) W !?34,"Analog Pager: ",$P($$BEEP^TIULC1(+TIUSIG("SIGNEDBY")),U)
. . I $P($$BEEP^TIULC1(+TIUSIG("SIGNEDBY")),U,2) W !?34,"Digital Pager: ",$P($$BEEP^TIULC1(+TIUSIG("SIGNEDBY")),U,2)
I $P(TIUSIG("SIGNMODE"),";")="C" D Q:'TIUCONT
. S TIUCONT=$$SETCONT^TIUPRPN1(.TIUFOOT,TIUMISC,TIUCONT1,0,$G(TIUROOT)) Q:'TIUCONT
. N TIUONCH
. S TIUONCH=$P(TIUSIG("SIGCHRT"),";",2)
. I TIUONCH']"" S TIUONCH=$P(TIUSIG("COSCHRT"),";",2)
. W !?2,"Marked signed on chart by:",?34,$G(TIUONCH)
; -- If signer is not author, write "for the author":
; P182 SIGNEDBY may =";" and follow null even when no signer:
;I TIUSIG("SIGNEDBY")]"",(+TIUSIG("SIGNEDBY")'=+TIUSIG("AUTHOR")) D
I TIUSIG("SIGNEDBY")]"",(TIUSIG("SIGNEDBY")'=";"),(+TIUSIG("SIGNEDBY")'=+TIUSIG("AUTHOR")) D
. N TIUSIGTL
. W !?34,"for ",$P(TIUSIG("AUTHOR"),";",2)
. S TIUSIGTL=$$GET1^DIQ(200,$P(TIUSIG("AUTHOR"),";",1),20.3)
. I $D(TIUSIGTL) D
. . N TIUFT
. . D WRAP^TIUFLD(TIUSIGTL,45)
. . W !?34,$G(TIUFT(1))
. . W !?39,$G(TIUFT(2))
I $G(@TIUROOT@(.05,"E"))="UNCOSIGNED" D
. W !?34,"**REQUIRES COSIGNATURE**",!
;I +$G(TIUADD) S TIUGROOT=$NA(^TMP("TIULQ",$J,TIUDA,"ZADD",TIUADD))
I +$D(@TIUROOT@("EXTRASGNR")) D Q:'TIUCONT ;**100** added the quit
. N TIUI S TIUI=0
. S TIUCONT=$$SETCONT^TIUPRPN1(.TIUFOOT,TIUMISC,TIUCONT1,0,$G(TIUROOT)) Q:'TIUCONT
. F S TIUI=$O(@TIUROOT@("EXTRASGNR",TIUI)) Q:'TIUI D
. . W !!?4,"Receipt Acknowledged By:"
. . ;VMP/ELR P224 ADDED code to print awaiting signature and expected additional signer name
. . I +$G(@TIUROOT@("EXTRASGNR",TIUI,"DATE"))'>0 D Q
. . . W !,?4,"* AWAITING SIGNATURE *",?30,$G(@TIUROOT@("EXTRASGNR",TIUI,"EXPNAME"))
. . I TIUI>1 S TIUCONT=$$SETCONT^TIUPRPN1(.TIUFOOT,TIUMISC,TIUCONT1,0,$G(TIUROOT)) Q:'TIUCONT
. . W !?29,"/es/ ",$G(@TIUROOT@("EXTRASGNR",TIUI,"NAME"))
. . I $L($G(@TIUROOT@("EXTRASGNR",TIUI,"TITLE")))>45 D
. . . N TIUFT
. . . D WRAP^TIUFLD($G(@TIUROOT@("EXTRASGNR",TIUI,"TITLE")),45)
. . . W !?34,$G(TIUFT(1))
. . . W !?39,$G(TIUFT(2))
. . I $L($G(@TIUROOT@("EXTRASGNR",TIUI,"TITLE")))<46 W !?34,$G(@TIUROOT@("EXTRASGNR",TIUI,"TITLE"))
. . I $G(@TIUROOT@("EXTRASGNR",TIUI,"EXTRA")),$G(@TIUROOT@("EXTRASGNR",TIUI,"EXPIEN"))'=$G(@TIUROOT@("EXTRASGNR",TIUI,"EXTRA")) D
. . . W !?30,"for ",$P($G(@TIUROOT@("EXTRASGNR",TIUI,"EXPNAME")),",",2)
. . . W " ",$P($G(@TIUROOT@("EXTRASGNR",TIUI,"EXPNAME")),",")
. . W !?34,$$DATE^TIULS($G(@TIUROOT@("EXTRASGNR",TIUI,"DATE")),"MM/DD/CCYY HR:MIN")
. . I '+$G(TIUFLAG)!($E(IOST)="C-") D
. . . N BEEP
. . . S BEEP=$$BEEP^TIULC1(+$G(@TIUROOT@("EXTRASGNR",TIUI,"EXTRA")))
. . . I +BEEP W !?34,"Analog Pager: ",$P(BEEP,U)
. . . I +$P(BEEP,U,2) W !?34,"Digital Pager: ",$P(BEEP,U,2)
. ;K @TIUROOT@("EXTRASGNR") ;**100** commented out
;I +TIUSIG("COSGDATE"),(+TIUSIG("COSGEDBY")'=+TIUSIG("SIGNEDBY")) D Q:'TIUCONT
I +TIUSIG("COSGDATE") D Q:'TIUCONT
. S TIUCONT=$$SETCONT^TIUPRPN1(.TIUFOOT,TIUMISC,TIUCONT1,0,$G(TIUROOT)) Q:'TIUCONT
. W !!?16,"Cosigned by:",$S($P(TIUSIG("COSGMODE"),";")="C":" /s/ ",1:" /es/ "),?34,$S(TIUSIG("COSGNAME")]"":TIUSIG("COSGNAME"),1:$P(TIUSIG("COSGEDBY"),";",2))
. I $L(TIUSIG("COSGTITL"))>45 D
. . N TIUFT
. . D WRAP^TIUFLD(TIUSIG("COSGTITL"),45)
. . W !?34,$G(TIUFT(1))
. . W !?39,$G(TIUFT(2))
. I $L(TIUSIG("COSGTITL"))<46 W !?34,TIUSIG("COSGTITL")
. W !?34,$$DATE^TIULS(+TIUSIG("COSGDATE"),"MM/DD/CCYY HR:MIN")
. I '+$G(TIUFLAG)!($E(IOST)="C-") D
. . I $P($$BEEP^TIULC1(+TIUSIG("COSGEDBY")),U) W !?34,"Analog Pager: ",$P($$BEEP^TIULC1(+TIUSIG("COSGEDBY")),U)
. . I $P($$BEEP^TIULC1(+TIUSIG("COSGEDBY")),U,2) W !?34,"Digital Pager: ",$P($$BEEP^TIULC1(+TIUSIG("COSGEDBY")),U,2)
;I +TIUSIG("COSCHRT"),$P(TIUSIG("COSGMODE"),";")="C" D Q:'TIUCONT
I $P(TIUSIG("COSGMODE"),";")="C" D Q:'TIUCONT
. S TIUCONT=$$SETCONT^TIUPRPN1(.TIUFOOT,TIUMISC,TIUCONT1,0,$G(TIUROOT)) Q:'TIUCONT
. W !,"Marked cosigned on chart by:",?34,$P(TIUSIG("COSCHRT"),";",2)
W !
;K TIUCONT1 ; kills the cont on next page msgs since no longer in middle
;of a note. **100** moved down to amend code
AMEND ; signature blocks of amender
;N TIUY S TIUY=4 ;I don't think we need TIUY anymore **100**
I '$G(@TIUROOT@(1601,"I")) K TIUCONT1 Q
S TIUCONT=$$SETCONT^TIUPRPN1(.TIUFOOT,TIUMISC,TIUCONT1,0,$G(TIUROOT))
K TIUCONT1 Q:'TIUCONT
I +$G(@TIUROOT@(1601,"I")) D
. W !!?12,"Amendment Filed:",?34,$$DATE^TIULS(@TIUROOT@(1601,"I"),"MM/DD/CCYY HR:MIN")
. I $G(@TIUROOT@(1603,"E"))']"" D
. . W !!?29 F TIUI=1:1:40 W "_"
. . W !?29,$$SIGNAME^TIULS(@TIUROOT@(1602,"I"))
. . W !?29,$$SIGTITL^TIULS(@TIUROOT@(1602,"I"))
. I $G(@TIUROOT@(1604,"E"))]"" D
. . W !?29,"/es/",?34,@TIUROOT@(1604,"E")
. . W !?34,@TIUROOT@(1605,"E")
Q
;
--- Routine Detail --- with STRUCTURED ROUTINE LISTING ---[H[J[2J[HTIUPRPN8 6340 printed Nov 22, 2024@17:53:48 Page 2
TIUPRPN8 ;SLC/MAM - Print SF 509-Progress Notes, Cont ;11/10/04 [1/4/05 12:17pm]
+1 ;;1.0;TEXT INTEGRATION UTILITIES;**100,176,157,182,224**;Jun 20, 1997;Build 7
+2 ;
SIGBLK(TIUFOOT,TIUMISC,TIUCONT1,TIUCONT,TIUSIG,TIUROOT) ; Print signature block info
+1 ; Requires array TIUFOOT, requires TIUMISC
+2 ; Requires TIUCONT1
+3 ; Receives TIUCONT by ref (req'd)
+4 ; Receives array TIUSIG by ref, required.
+5 ; Requires TIUROOT
+6 NEW TIUDA,TIUFLAG
+7 SET TIUCONT=1
SET TIUDA=$PIECE(TIUMISC,U,3)
SET TIUFLAG=$PIECE(TIUMISC,U)
+8 ;S TIUGROOT=$NA(^TMP("TIULQ",$J,TIUDA))
+9 ; -- P182 Don't marked admin signed notes as draft:
+10 IF '+TIUSIG("SIGNDATE")
IF '+TIUSIG("ADMINCDT")
Begin DoDot:1
+11 WRITE "**DRAFT COPY - DRAFT COPY -- ABOVE NOTE IS UNSIGNED--"
+12 WRITE " DRAFT COPY - DRAFT COPY**",!
+13 SET TIUCONT=$$SETCONT^TIUPRPN1(.TIUFOOT,TIUMISC,TIUCONT1,0,$GET(TIUROOT))
End DoDot:1
if 'TIUCONT
QUIT
+14 ;I TIUSIG("SIGNEDBY")]"",(+TIUSIG("SIGNEDBY")'=+TIUSIG("AUTHOR")) D
+15 ;. W ?21,"Author: ",$P(TIUSIG("AUTHOR"),";",2),!
+16 IF +TIUSIG("SIGNDATE")
Begin DoDot:1
+17 SET TIUCONT=$$SETCONT^TIUPRPN1(.TIUFOOT,TIUMISC,TIUCONT1,0,$GET(TIUROOT))
if 'TIUCONT
QUIT
+18 WRITE ?18,"Signed by:",$SELECT($PIECE(TIUSIG("SIGNMODE"),";")="C":" /s/ ",1:" /es/ "),?34,$SELECT(TIUSIG("SIGNNAME")]"":TIUSIG("SIGNNAME"),1:$PIECE(TIUSIG("SIGNEDBY"),";",2))
+19 IF $LENGTH(TIUSIG("SIGTITL"))>45
Begin DoDot:2
+20 NEW TIUFT
+21 DO WRAP^TIUFLD(TIUSIG("SIGTITL"),45)
+22 WRITE !?34,$GET(TIUFT(1))
+23 WRITE !?39,$GET(TIUFT(2))
End DoDot:2
+24 IF $LENGTH(TIUSIG("SIGTITL"))<46
IF TIUSIG("SIGTITL")]""
WRITE !?34,TIUSIG("SIGTITL")
+25 WRITE !?34,$$DATE^TIULS(+TIUSIG("SIGNDATE"),"MM/DD/CCYY HR:MIN")
+26 IF '+$GET(TIUFLAG)!($EXTRACT(IOST)="C-")
Begin DoDot:2
+27 IF $PIECE($$BEEP^TIULC1(+TIUSIG("SIGNEDBY")),U)
WRITE !?34,"Analog Pager: ",$PIECE($$BEEP^TIULC1(+TIUSIG("SIGNEDBY")),U)
+28 IF $PIECE($$BEEP^TIULC1(+TIUSIG("SIGNEDBY")),U,2)
WRITE !?34,"Digital Pager: ",$PIECE($$BEEP^TIULC1(+TIUSIG("SIGNEDBY")),U,2)
End DoDot:2
End DoDot:1
if 'TIUCONT
QUIT
+29 IF $PIECE(TIUSIG("SIGNMODE"),";")="C"
Begin DoDot:1
+30 SET TIUCONT=$$SETCONT^TIUPRPN1(.TIUFOOT,TIUMISC,TIUCONT1,0,$GET(TIUROOT))
if 'TIUCONT
QUIT
+31 NEW TIUONCH
+32 SET TIUONCH=$PIECE(TIUSIG("SIGCHRT"),";",2)
+33 IF TIUONCH']""
SET TIUONCH=$PIECE(TIUSIG("COSCHRT"),";",2)
+34 WRITE !?2,"Marked signed on chart by:",?34,$GET(TIUONCH)
End DoDot:1
if 'TIUCONT
QUIT
+35 ; -- If signer is not author, write "for the author":
+36 ; P182 SIGNEDBY may =";" and follow null even when no signer:
+37 ;I TIUSIG("SIGNEDBY")]"",(+TIUSIG("SIGNEDBY")'=+TIUSIG("AUTHOR")) D
+38 IF TIUSIG("SIGNEDBY")]""
IF (TIUSIG("SIGNEDBY")'=";")
IF (+TIUSIG("SIGNEDBY")'=+TIUSIG("AUTHOR"))
Begin DoDot:1
+39 NEW TIUSIGTL
+40 WRITE !?34,"for ",$PIECE(TIUSIG("AUTHOR"),";",2)
+41 SET TIUSIGTL=$$GET1^DIQ(200,$PIECE(TIUSIG("AUTHOR"),";",1),20.3)
+42 IF $DATA(TIUSIGTL)
Begin DoDot:2
+43 NEW TIUFT
+44 DO WRAP^TIUFLD(TIUSIGTL,45)
+45 WRITE !?34,$GET(TIUFT(1))
+46 WRITE !?39,$GET(TIUFT(2))
End DoDot:2
End DoDot:1
+47 IF $GET(@TIUROOT@(.05,"E"))="UNCOSIGNED"
Begin DoDot:1
+48 WRITE !?34,"**REQUIRES COSIGNATURE**",!
End DoDot:1
+49 ;I +$G(TIUADD) S TIUGROOT=$NA(^TMP("TIULQ",$J,TIUDA,"ZADD",TIUADD))
+50 ;**100** added the quit
IF +$DATA(@TIUROOT@("EXTRASGNR"))
Begin DoDot:1
+51 NEW TIUI
SET TIUI=0
+52 SET TIUCONT=$$SETCONT^TIUPRPN1(.TIUFOOT,TIUMISC,TIUCONT1,0,$GET(TIUROOT))
if 'TIUCONT
QUIT
+53 FOR
SET TIUI=$ORDER(@TIUROOT@("EXTRASGNR",TIUI))
if 'TIUI
QUIT
Begin DoDot:2
+54 WRITE !!?4,"Receipt Acknowledged By:"
+55 ;VMP/ELR P224 ADDED code to print awaiting signature and expected additional signer name
+56 IF +$GET(@TIUROOT@("EXTRASGNR",TIUI,"DATE"))'>0
Begin DoDot:3
+57 WRITE !,?4,"* AWAITING SIGNATURE *",?30,$GET(@TIUROOT@("EXTRASGNR",TIUI,"EXPNAME"))
End DoDot:3
QUIT
+58 IF TIUI>1
SET TIUCONT=$$SETCONT^TIUPRPN1(.TIUFOOT,TIUMISC,TIUCONT1,0,$GET(TIUROOT))
if 'TIUCONT
QUIT
+59 WRITE !?29,"/es/ ",$GET(@TIUROOT@("EXTRASGNR",TIUI,"NAME"))
+60 IF $LENGTH($GET(@TIUROOT@("EXTRASGNR",TIUI,"TITLE")))>45
Begin DoDot:3
+61 NEW TIUFT
+62 DO WRAP^TIUFLD($GET(@TIUROOT@("EXTRASGNR",TIUI,"TITLE")),45)
+63 WRITE !?34,$GET(TIUFT(1))
+64 WRITE !?39,$GET(TIUFT(2))
End DoDot:3
+65 IF $LENGTH($GET(@TIUROOT@("EXTRASGNR",TIUI,"TITLE")))<46
WRITE !?34,$GET(@TIUROOT@("EXTRASGNR",TIUI,"TITLE"))
+66 IF $GET(@TIUROOT@("EXTRASGNR",TIUI,"EXTRA"))
IF $GET(@TIUROOT@("EXTRASGNR",TIUI,"EXPIEN"))'=$GET(@TIUROOT@("EXTRASGNR",TIUI,"EXTRA"))
Begin DoDot:3
+67 WRITE !?30,"for ",$PIECE($GET(@TIUROOT@("EXTRASGNR",TIUI,"EXPNAME")),",",2)
+68 WRITE " ",$PIECE($GET(@TIUROOT@("EXTRASGNR",TIUI,"EXPNAME")),",")
End DoDot:3
+69 WRITE !?34,$$DATE^TIULS($GET(@TIUROOT@("EXTRASGNR",TIUI,"DATE")),"MM/DD/CCYY HR:MIN")
+70 IF '+$GET(TIUFLAG)!($EXTRACT(IOST)="C-")
Begin DoDot:3
+71 NEW BEEP
+72 SET BEEP=$$BEEP^TIULC1(+$GET(@TIUROOT@("EXTRASGNR",TIUI,"EXTRA")))
+73 IF +BEEP
WRITE !?34,"Analog Pager: ",$PIECE(BEEP,U)
+74 IF +$PIECE(BEEP,U,2)
WRITE !?34,"Digital Pager: ",$PIECE(BEEP,U,2)
End DoDot:3
End DoDot:2
+75 ;K @TIUROOT@("EXTRASGNR") ;**100** commented out
End DoDot:1
if 'TIUCONT
QUIT
+76 ;I +TIUSIG("COSGDATE"),(+TIUSIG("COSGEDBY")'=+TIUSIG("SIGNEDBY")) D Q:'TIUCONT
+77 IF +TIUSIG("COSGDATE")
Begin DoDot:1
+78 SET TIUCONT=$$SETCONT^TIUPRPN1(.TIUFOOT,TIUMISC,TIUCONT1,0,$GET(TIUROOT))
if 'TIUCONT
QUIT
+79 WRITE !!?16,"Cosigned by:",$SELECT($PIECE(TIUSIG("COSGMODE"),";")="C":" /s/ ",1:" /es/ "),?34,$SELECT(TIUSIG("COSGNAME")]"":TIUSIG("COSGNAME"),1:$PIECE(TIUSIG("COSGEDBY"),";",2))
+80 IF $LENGTH(TIUSIG("COSGTITL"))>45
Begin DoDot:2
+81 NEW TIUFT
+82 DO WRAP^TIUFLD(TIUSIG("COSGTITL"),45)
+83 WRITE !?34,$GET(TIUFT(1))
+84 WRITE !?39,$GET(TIUFT(2))
End DoDot:2
+85 IF $LENGTH(TIUSIG("COSGTITL"))<46
WRITE !?34,TIUSIG("COSGTITL")
+86 WRITE !?34,$$DATE^TIULS(+TIUSIG("COSGDATE"),"MM/DD/CCYY HR:MIN")
+87 IF '+$GET(TIUFLAG)!($EXTRACT(IOST)="C-")
Begin DoDot:2
+88 IF $PIECE($$BEEP^TIULC1(+TIUSIG("COSGEDBY")),U)
WRITE !?34,"Analog Pager: ",$PIECE($$BEEP^TIULC1(+TIUSIG("COSGEDBY")),U)
+89 IF $PIECE($$BEEP^TIULC1(+TIUSIG("COSGEDBY")),U,2)
WRITE !?34,"Digital Pager: ",$PIECE($$BEEP^TIULC1(+TIUSIG("COSGEDBY")),U,2)
End DoDot:2
End DoDot:1
if 'TIUCONT
QUIT
+90 ;I +TIUSIG("COSCHRT"),$P(TIUSIG("COSGMODE"),";")="C" D Q:'TIUCONT
+91 IF $PIECE(TIUSIG("COSGMODE"),";")="C"
Begin DoDot:1
+92 SET TIUCONT=$$SETCONT^TIUPRPN1(.TIUFOOT,TIUMISC,TIUCONT1,0,$GET(TIUROOT))
if 'TIUCONT
QUIT
+93 WRITE !,"Marked cosigned on chart by:",?34,$PIECE(TIUSIG("COSCHRT"),";",2)
End DoDot:1
if 'TIUCONT
QUIT
+94 WRITE !
+95 ;K TIUCONT1 ; kills the cont on next page msgs since no longer in middle
+96 ;of a note. **100** moved down to amend code
AMEND ; signature blocks of amender
+1 ;N TIUY S TIUY=4 ;I don't think we need TIUY anymore **100**
+2 IF '$GET(@TIUROOT@(1601,"I"))
KILL TIUCONT1
QUIT
+3 SET TIUCONT=$$SETCONT^TIUPRPN1(.TIUFOOT,TIUMISC,TIUCONT1,0,$GET(TIUROOT))
+4 KILL TIUCONT1
if 'TIUCONT
QUIT
+5 IF +$GET(@TIUROOT@(1601,"I"))
Begin DoDot:1
+6 WRITE !!?12,"Amendment Filed:",?34,$$DATE^TIULS(@TIUROOT@(1601,"I"),"MM/DD/CCYY HR:MIN")
+7 IF $GET(@TIUROOT@(1603,"E"))']""
Begin DoDot:2
+8 WRITE !!?29
FOR TIUI=1:1:40
WRITE "_"
+9 WRITE !?29,$$SIGNAME^TIULS(@TIUROOT@(1602,"I"))
+10 WRITE !?29,$$SIGTITL^TIULS(@TIUROOT@(1602,"I"))
End DoDot:2
+11 IF $GET(@TIUROOT@(1604,"E"))]""
Begin DoDot:2
+12 WRITE !?29,"/es/",?34,@TIUROOT@(1604,"E")
+13 WRITE !?34,@TIUROOT@(1605,"E")
End DoDot:2
End DoDot:1
+14 QUIT
+15 ;
