Home   Package List   Routine Alphabetical List   Global Alphabetical List   FileMan Files List   FileMan Sub-Files List   Package Component Lists   Package-Namespace Mapping  
Routine: ENWO2

ENWO2.m

Go to the documentation of this file. 
  1. ENWO2 ;WIRMFO/DH,SAB-Disapprove Work Order ;2/3/97
  1.  ;;7.0;ENGINEERING;**35**;Aug 17, 1993
  1. DISAP ;Disapprove work order
  1. EN S DIC("S")="I $P($G(^(5)),U,2)=""""" D WO^ENWOUTL K DIC
  1.  G:Y'>0 EXIT S DA=+Y
  1.  S DIE="^ENG(6920,"
  1. EN1 ;
  1.  I $D(^ENG(6920,DA,5)),$P(^(5),U,2)]"" W !,*7,"NOTE: This Work Order has already been closed out." W:$D(^XUSEC("ENEDCLWO",DUZ)) !,"Use the Work Order EDIT or DISPLAY option if you need to edit." G EXIT
  1.  S ENDA(0)=DA,DR=$S($D(^DIE("B","ENZWODISAP")):"[ENZWODISAP]",1:"[ENWODISAP]") D ^DIE W !!
  1.  S DA=ENDA(0)
  1.  K ENDA(0) G EXIT
  1. EXIT Q
  1.  ;
  1. MSG ; Notify Requestor of W.O. Status Change
  1.  ; File 6920 Field 32 "AH" mumps x-ref
  1.  ; Expects DA (ien of w.o.)
  1.  N ENABBR,ENDAS,ENELWO,ENI,ENQ,ENSEND,ENSO,ENX,ENY
  1.  S ENSEND="" ; flag: =1 send msg, =0 no msg, =NULL don't know yet
  1.  S ENDAS=DA_","
  1.  D GETS^DIQ(6920,ENDAS,".01;.05;2;32","E","ENQ")
  1.  D GETS^DIQ(6920,ENDAS,"7.5;32;32.1","I","ENQ")
  1.  S:$E(ENQ(6920,ENDAS,.01,"E"),1,3)="PM-" ENSEND=0 ; ignore PM W.O.s
  1.  S:ENQ(6920,ENDAS,7.5,"I")'?1.N ENSEND=0 ; no requestor
  1.  S:ENQ(6920,ENDAS,7.5,"I")=DUZ ENSEND=0 ; don't send msg to self
  1.  ; if disapproved
  1.  I ENSEND="",ENQ(6920,ENDAS,32,"E")="DISAPPROVED" D  S:ENSEND="" ENSEND=0
  1.  . I ENQ(6920,ENDAS,2,"E")["COMPUTER" S ENSEND=1
  1.  ; else if existing notification preference
  1.  I ENSEND="",ENQ(6920,ENDAS,32.1,"I")]"" D  S:ENSEND="" ENSEND=0
  1.  . I ENQ(6920,ENDAS,32.1,"I")="S" S ENSEND=1
  1.  . I ENQ(6920,ENDAS,32.1,"I")="C",ENQ(6920,ENDAS,32,"E")="COMPLETED" S ENSEND=1
  1.  ; else if existing software option
  1.  I ENSEND="" D  S:ENSEND="" ENSEND=0
  1.  . S ENI=$O(^ENG(6910.2,"B","NOTIFY W.O. REQUESTOR",0))
  1.  . S ENSO=$S(ENI?1.N:$P($G(^ENG(6910.2,ENI,0)),U,2),1:"")
  1.  . I ENSO]"" D
  1.  . . ; check if electronic w.o.
  1.  . . S ENELWO=0
  1.  . . F ENI=1:1 Q:$E(ENQ(6920,ENDAS,.05,"E"),ENI)'?1U
  1.  . . S ENABBR=$E(ENQ(6920,ENDAS,.05,"E"),1,ENI-1)
  1.  . . Q:ENABBR=""
  1.  . . S ENI=89
  1.  . . F  S ENI=$O(^DIC(6922,ENI)) Q:'ENI  D:ENI#100>89  Q:ENELWO
  1.  . . . I $P($G(^(ENI,0)),U,2)=ENABBR S ENELWO=1
  1.  . . Q:'ENELWO
  1.  . . I ENSO="S" S ENSEND=1
  1.  . . I ENSO="C",ENQ(6920,ENDAS,32,"E")="COMPLETED" S ENSEND=1
  1.  D:ENSEND=1
  1.  . ; send mail message to requestor
  1.  . N ENL,ENTEXT,XMCHAN,XMDUZ,XMSUB,XMTEXT,XMY
  1.  . S ENTEXT(1)="A work request which you entered on "_$$GET1^DIQ(6920,ENDAS,1)
  1.  . S ENTEXT(2)="   Original Work Order #: "_ENQ(6920,ENDAS,.05,"E")
  1.  . S ENTEXT(3)="   Task Description: "_$$GET1^DIQ(6920,ENDAS,6)
  1.  . S ENTEXT(4)="   Contact Person: "_$$GET1^DIQ(6920,ENDAS,7)
  1.  . S ENTEXT(4)=ENTEXT(4)_"   Phone: "_$$GET1^DIQ(6920,ENDAS,8)
  1.  . S ENTEXT(5)=$S(ENQ(6920,ENDAS,32,"I")<5:"is ",1:"has been ")
  1.  . S ENTEXT(5)=ENTEXT(5)_ENQ(6920,ENDAS,32,"E")
  1.  . S:ENQ(6920,ENDAS,32,"I")>4 ENTEXT(5)=ENTEXT(5)_" on "_$$GET1^DIQ(6920,ENDAS,36)
  1.  . S ENTEXT(5)=ENTEXT(5)_"."
  1.  . S ENL=5
  1.  . I ENQ(6920,ENDAS,32,"E")="COMPLETED" D
  1.  . . S ENL=ENL+1,ENTEXT(ENL)=" "
  1.  . . ;
  1.  . . S ENX("DIMSG",1)="Work Perf: "_$P($G(^ENG(6920,DA,5)),U,7)
  1.  . . K ENY D MSG^DIALOG("AM",.ENY,70,"","ENX")
  1.  . . F ENI=1:1 Q:'$D(ENY(ENI))  S ENL=ENL+1,ENTEXT(ENL)=ENY(ENI)
  1.  . . ;
  1.  . I $O(^ENG(6920,DA,6,0)) D
  1.  . . S ENL=ENL+1,ENTEXT(ENL)=" "
  1.  . . S ENL=ENL+1,ENTEXT(ENL)="COMMENTS:"
  1.  . . S ENI=0
  1.  . . F  S ENI=$O(^ENG(6920,DA,6,ENI)) Q:'ENI  S ENL=ENL+1,ENTEXT(ENL)=$G(^(ENI,0))
  1.  . I $O(^DIC(6910,1,5,0)) D
  1.  . . ; add WORK ORDER MESSAGE TEXT if any
  1.  . . S ENL=ENL+1,ENTEXT(ENL)=" "
  1.  . . S ENI=0
  1.  . . F  S ENI=$O(^DIC(6910,1,5,ENI)) Q:'ENI  S ENL=ENL+1,ENTEXT(ENL)=$G(^(ENI,0))
  1.  . S XMSUB="Work Order "_ENQ(6920,ENDAS,.01,"E")_" STATUS"
  1.  . ;_" "_ENQ(6920,ENDAS,32,"E")
  1.  . S XMCHAN=1,XMTEXT="ENTEXT(",XMDUZ="AEMS/MERS"
  1.  . S XMZ=$P($G(^ENG(6920,DA,4)),U,6)
  1.  . I XMZ,$$SUBGET^XMGAPI0(XMZ)]"" D  I ENI>0 Q
  1.  . . ; send message as response
  1.  . . S ENI=$$ENT^XMA2R(XMZ,XMSUB,.ENTEXT,"",DUZ)
  1.  . ; create new message
  1.  . K XMZ D XMZ^XMA2 I XMZ'>0 Q  ; could not create new message
  1.  . ; save message number in w.o.
  1.  . S $P(^ENG(6920,DA,4),U,6)=XMZ
  1.  . ; add text to message
  1.  . S (ENI,ENL)=0 F  S ENI=$O(ENTEXT(ENI)) Q:'ENI  D
  1.  . . S ^XMB(3.9,XMZ,2,ENI,0)=ENTEXT(ENI),ENL=ENL+1
  1.  . I ENL S ^XMB(3.9,XMZ,2,0)="^3.92^"_ENL_U_ENL_U_DT
  1.  . ; make information only
  1.  . K ENL
  1.  . S ENL(3.9,XMZ_",",1.97)="Y"
  1.  . D FILE^DIE("E","ENL")
  1.  . ; forward to user
  1.  . S XMY(ENQ(6920,ENDAS,7.5,"I"))=""
  1.  . D ENT1^XMD
  1.  Q
  1.  ;ENWO2